sec-keys/openpgp-keys-libmicrohttpd/openpgp-keys-libmicrohttpd-999999.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 DESCRIPTION="OpenPGP keys used to sign GNU libmicrohttpd releases"
   7 HOMEPAGE="https://savannah.gnu.org/projects/libmicrohttpd/"
   8 if [[ ${PV} == 9999* ]] ; then
   9         PROPERTIES="live"
  10
  11         BDEPEND="|| ( net-misc/wget[gnutls] net-misc/wget[ssl] )"
  12 else
  13         KARLSON2K_ID='EA812DBEFA5A7EF17DA8F2C1460A317C3326D2AE'
  14         CHRISTIAN_ID='D8423BCB326C7907033929C7939E6BE1E29FC3CC'
  15         # Technically public keys are not stable.
  16         # While the fingerprint is stable, the contents of the key can be
  17         # changed at any time by an additional user ID (email address),
  18         # an additional signature or updated date of expiration.
  19         SRC_URI="https://keys.openpgp.org/vks/v1/by-fingerprint/${CHRISTIAN_ID} -> christiangrothoff-${CHRISTIAN_ID}.asc
  20                 https://keys.openpgp.org/vks/v1/by-fingerprint/${KARLSON2K_ID} -> karlson2k-${KARLSON2K_ID}.asc"
  21         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
  22 fi
  23
  24 S="${WORKDIR}"
  25
  26 LICENSE="public-domain"
  27 SLOT="${PV}"
  28
  29 src_unpack() {
  30         if [[ ${PV} == 9999* ]] ; then
  31                 # The release keyring can be changed at any moment and should always match the latest release
  32                 wget 'https://savannah.gnu.org/project/release-gpgkeys.php?group=libmicrohttpd&download=1' -O libmicrohttpd-keyring.gpg || die
  33         else
  34                 default
  35         fi
  36 }
  37
  38 src_install() {
  39         local files
  40         local key_file
  41
  42         if [[ ${PV} == 9999* ]] ; then
  43                 files=( "${WORKDIR}/libmicrohttpd-keyring.gpg" )
  44         else
  45                 for key_file in ${A} ; do
  46                         files+=( "${DISTDIR}/${key_file}" )
  47                 done
  48         fi
  49
  50         insinto /usr/share/openpgp-keys
  51         newins - libmicrohttpd-${PV}.asc < <(cat "${files[@]}" || die)
  52 }