sec-keys/openpgp-keys-openssl/openpgp-keys-openssl-20221101.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 DESCRIPTION="OpenPGP keys used by OpenSSL"
   7 HOMEPAGE="https://www.openssl.org/"
   8
   9 # See the following:
  10 # - https://www.openssl.org/source/
  11 # - https://www.openssl.org/community/otc.html
  12 # - https://www.openssl.org/community/omc.html
  13 # Mirrored from https://keyserver.ubuntu.com/pks/lookup?op=get&search=0x8657ABB260F056B1E5190839D9C4D26D0E604491 etc (unstable results)
  14 # ```
  15 # gpg --no-default-keyring --homedir=/tmp/tmp-gpg --keyserver keyserver.ubuntu.com --recv-keys "${OSSL_FINGERPRINTS[@]}" || exit 1
  16 #
  17 # for key in "${OSSL_FINGERPRINTS[@]}" ; do
  18 #  gpg --no-default-keyring --homedir=/tmp/tmp-gpg --export "${key}" > openssl-keys-20221101-${key}.asc
  19 # done
  20 # ```
  21 #
  22 # https://github.com/openssl/openssl/issues/19566
  23 # https://github.com/openssl/openssl/issues/19567
  24
  25 OSSL_FINGERPRINTS=(
  26         # Matt Caswell <matt@openssl.org>
  27         5B2545DAB21995F4088CEFAA36CEE4DEB00CFE33
  28
  29         # Paul Dale <pauli@openssl.org>
  30         8657ABB260F056B1E5190839D9C4D26D0E604491
  31
  32         # Tim Hudson <tjh@openssl.org>
  33         B7C1C14360F353A36862E4D5231C84CDDCC69C45
  34
  35         # Hugo Landau <hlandau@openssl.org>
  36         95A9908DDFA16830BE9FB9003D30A3A9FF1360DC
  37
  38         # Tomas Mraz <tomas@openssl.org>
  39         A21FAB74B0088AA361152586B8EF1A6BA9DA2D5C
  40
  41         # Richard Levitte <levitte@openssl.org>
  42         C1F33DD8CE1D4CC613AF14DA9195C48241FBF7DD
  43
  44         # Kurt Roeckx <kurt@openssl.org>
  45         E5E52560DD91C556DDBDA5D02064C53641C25E5D
  46 )
  47
  48 ossl_key=
  49 for ossl_key in "${OSSL_FINGERPRINTS[@]}" ; do
  50         SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/openssl-keys-${PV}-${ossl_key}.asc"
  51 done
  52 unset ossl_key
  53
  54 S="${WORKDIR}"
  55
  56 LICENSE="public-domain"
  57 SLOT="0"
  58 KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
  59
  60 src_install() {
  61         local files=( ${A} )
  62         insinto /usr/share/openpgp-keys
  63         newins - openssl.org.asc < <(cat "${files[@]/#/${DISTDIR}/}" || die)
  64 }