x11-misc/qcomicbook/qcomicbook-0.9.1.ebuild

   1 # Copyright 1999-2021 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_PN="QComicBook"
   7 CMAKE_IN_SOURCE_BUILD=1
   8 PLOCALES="cs_CZ de_DE es_ES fi_FI fr_CA fr_FR it_IT ko_KR nl_NL pl_PL pt_BR ru_RU uk_UA zh_CN"
   9 inherit cmake flag-o-matic plocale xdg
  10
  11 DESCRIPTION="Viewer for comic book archives containing jpeg/png images"
  12 HOMEPAGE="https://github.com/stolowski/QComicBook"
  13 SRC_URI="https://github.com/stolowski/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="amd64 ~ppc x86"
  18 IUSE="debug"
  19
  20 RDEPEND="
  21         app-text/poppler[qt5]
  22         dev-qt/qtcore:5
  23         dev-qt/qtgui:5
  24         dev-qt/qtprintsupport:5
  25         dev-qt/qtwidgets:5
  26         dev-qt/qtx11extras:5"
  27 DEPEND="${RDEPEND}"
  28 BDEPEND="dev-qt/linguist-tools:5"
  29
  30 DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
  31
  32 S="${WORKDIR}/${MY_PN}-${PV}"
  33
  34 src_prepare() {
  35         rm_loc() {
  36                 rm "i18n/${PN}_${1}.ts" || die "removing ${1} locale failed"
  37         }
  38         rm "i18n/${PN}_en_EN.ts" || die 'removing redundant english locale failed'
  39         plocale_find_changes "i18n" "${PN}_" ".ts"
  40         plocale_for_each_disabled_locale rm_loc
  41
  42         # fix desktop file
  43         sed -e '/^Encoding/d' \
  44                 -e '/^Icon/s/.png//' \
  45                 -e '/^Categories/s/Application;//' \
  46                 -i data/${PN}.desktop || die 'sed on desktop file failed'
  47
  48         cmake_src_prepare
  49 }
  50
  51 src_configure() {
  52         use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
  53         cmake_src_configure
  54 }
  55
  56 pkg_postinst() {
  57         xdg_pkg_postinst
  58         elog "For using QComicBook with compressed archives you may want to install:"
  59         elog "    app-arch/p7zip"
  60         elog "    app-arch/unace"
  61         elog "    app-arch/unrar or app-arch/rar"
  62         elog "    app-arch/unzip"
  63 }