x11-misc/tabbed/tabbed-0.8-r1.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit savedconfig toolchain-funcs
   7
   8 DESCRIPTION="Simple generic tabbed fronted to xembed aware applications"
   9 HOMEPAGE="https://tools.suckless.org/tabbed/"
  10 SRC_URI="https://dl.suckless.org/tools/${P}.tar.gz"
  11
  12 LICENSE="MIT"
  13 SLOT="0"
  14 KEYWORDS="amd64 arm64 ppc64 ~riscv x86"
  15
  16 RDEPEND="
  17         x11-libs/libX11
  18         x11-libs/libXft
  19 "
  20 DEPEND="
  21         ${RDEPEND}
  22         x11-base/xorg-proto
  23 "
  24 BDEPEND="
  25         virtual/pkgconfig
  26 "
  27
  28 src_prepare() {
  29         default
  30         restore_config config.h
  31 }
  32
  33 src_compile() {
  34         tc-export CC PKG_CONFIG
  35
  36         local emakeargs=(
  37                 TABBED_CFLAGS="${CFLAGS} $("${PKG_CONFIG}" --cflags x11 xft)"
  38                 TABBED_LDFLAGS="${LDFLAGS} $("${PKG_CONFIG}" --libs x11 xft)"
  39         )
  40
  41         emake "${emakeargs[@]}"
  42 }
  43
  44 src_install() {
  45         local emakeargs=(
  46                 DESTDIR="${D}"
  47                 PREFIX="${EPREFIX}/usr"
  48                 DOCPREFIX="${EPREFIX}/usr/share/doc/${PF}"
  49         )
  50         emake "${emakeargs[@]}" install
  51
  52         save_config config.h
  53 }