x11-misc/xbindkeys/xbindkeys-1.8.7-r100.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 GUILE_REQ_USE="deprecated"
   7 GUILE_COMPAT=( 2-2 3-0 )
   8 inherit autotools guile-single
   9
  10 DESCRIPTION="Tool for launching commands on keystrokes"
  11 SRC_URI="https://www.nongnu.org/${PN}/${P}.tar.gz"
  12 HOMEPAGE="https://www.nongnu.org/xbindkeys/xbindkeys.html"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 ~arm ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
  17 IUSE="guile tk"
  18
  19 REQUIRED_USE="guile? ( ${GUILE_REQUIRED_USE} )"
  20
  21 RDEPEND="
  22         x11-libs/libX11
  23         guile? ( ${GUILE_DEPS} )
  24         tk? ( dev-lang/tk )
  25 "
  26 DEPEND="
  27         ${RDEPEND}
  28         x11-base/xorg-proto
  29 "
  30
  31 DOCS=( AUTHORS BUGS ChangeLog README TODO xbindkeysrc )
  32
  33 pkg_setup() {
  34         use guile && guile-single_pkg_setup
  35 }
  36
  37 src_prepare() {
  38         default
  39
  40         use guile && guile_bump_sources
  41
  42         # Regenerate to pick up newer versions of Guile macros
  43         # bug #828532
  44         eautoreconf
  45 }
  46
  47 src_configure() {
  48         econf \
  49                 $(use_enable guile) \
  50                 $(use_enable tk)
  51 }
  52
  53 src_install() {
  54         default
  55
  56         use guile && guile_unstrip_ccache
  57 }