sci-electronics/gnetman/gnetman-0.0.1_pre20110124.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="A GNU Netlist Manipulation Library"
   9 HOMEPAGE="https://sourceforge.net/projects/gnetman/"
  10 #snapshot from http://gnetman.git.sourceforge.net/git/gitweb.cgi?p=gnetman/gnetman;
  11 SRC_URI="mirror://gentoo/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="doc examples"
  17
  18 RDEPEND="
  19         >=dev-lang/tcl-8.6:0
  20         sci-electronics/geda"
  21 DEPEND="${RDEPEND}
  22         dev-db/datadraw"
  23
  24 S="${WORKDIR}/${P}/src/batch"
  25 PATCHES=(
  26         # fix build issues with tcl-8.6, #452034
  27         "${FILESDIR}"/${P}-tcl86.patch
  28         # fix build system, #711354
  29         "${FILESDIR}"/${P}-build-system.patch
  30         # fix -fno-common, #707894
  31         "${FILESDIR}"/${P}-fno-common.patch
  32 )
  33
  34 src_prepare() {
  35         cd ../.. || die
  36         default
  37 }
  38
  39 src_configure() {
  40         tc-export CC
  41         default
  42 }
  43
  44 src_install() {
  45         cd ../.. || die
  46
  47         dobin bin/${PN}
  48
  49         insinto /usr/share/gEDA
  50         doins system-gnetmanrc.tcl
  51
  52         use examples && dodoc -r sym sch test
  53         dodoc README
  54         use doc && dodoc doc/*.{html,jpg}
  55 }