sci-mathematics/otter/otter-3.3-r4.ebuild

   1 # Copyright 1999-2023 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic toolchain-funcs
   7
   8 DESCRIPTION="An Automated Deduction System"
   9 HOMEPAGE="http://www.cs.unm.edu/~mccune/otter/"
  10 SRC_URI="http://www.cs.unm.edu/~mccune/otter/${P}.tar.gz"
  11
  12 LICENSE="otter"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
  15
  16 RDEPEND="
  17         x11-libs/libX11
  18         x11-libs/libXaw
  19         x11-libs/libXt"
  20 DEPEND="${RDEPEND}"
  21
  22 PATCHES=(
  23         "${FILESDIR}"/${P}-build.patch
  24         "${FILESDIR}"/${P}-gold.patch
  25         "${FILESDIR}"/${P}-clang16.patch
  26 )
  27
  28 src_configure() {
  29         append-cflags -fcommon
  30         append-cflags -std=gnu89 # old codebase, incompatible with c2x
  31         append-cppflags -D_GNU_SOURCE #871423 (gethostname, caddr_t)
  32 }
  33
  34 src_compile() {
  35         tc-export AR CC
  36
  37         emake -C source
  38         emake -C mace2
  39 }
  40
  41 src_install() {
  42         dobin bin/* source/formed/formed
  43
  44         dodoc README* Legal Changelog Contents documents/*.pdf
  45
  46         insinto /usr/share/${PN}
  47         doins -r examples examples-mace2
  48 }