app-admin/drush/drush-6.7.0-r6.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit bash-completion-r1
   7
   8 DESCRIPTION="Command line shell and scripting interface for Drupal"
   9 HOMEPAGE="https://github.com/drush-ops/drush"
  10 SRC_URI="https://github.com/drush-ops/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15
  16 RDEPEND="dev-lang/php[cli,ctype,json(+),simplexml]
  17         dev-php/PEAR-Console_Table"
  18
  19 PATCHES=(
  20         "${FILESDIR}/update-bash-completion-script-for-2.1.patch"
  21         "${FILESDIR}/array-syntax.patch"
  22         "${FILESDIR}/${P}-php8.0.patch"
  23         "${FILESDIR}/${P}-gzip-mime.patch"
  24         "${FILESDIR}/${P}-dont-pass-null-to-strtoupper.patch"
  25         "${FILESDIR}/${P}-batch-signature-fix.patch"
  26 )
  27
  28 src_prepare() {
  29         default
  30
  31         # dodoc compresses all of the documentation, so we fix the filenames
  32         # in a few places.
  33         #
  34         # First, the README location in bootstrap.inc.
  35         sed -i -e \
  36                 "s!/share/doc/drush!/share/doc/${PF}!" \
  37                 -e "s!README\.md!\0.bz2!g" \
  38                 includes/bootstrap.inc || die
  39
  40         # Next, the list of documentation in docs.drush.inc. Note that
  41         # html files don't get compressed.
  42         sed -i \
  43                 -e "s!\.bashrc'!.bashrc.bz2'!" \
  44                 -e "s!\.inc'!.inc.bz2'!" \
  45                 -e "s!\.ini'!.ini.bz2'!" \
  46                 -e "s!\.md'!.md.bz2'!" \
  47                 -e "s!\.php'!.php.bz2'!" \
  48                 -e "s!\.script'!.script.bz2'!" \
  49                 -e "s!\.txt'!.txt.bz2'!" \
  50                 commands/core/docs.drush.inc || die
  51 }
  52
  53 src_install() {
  54         # Always install the examples; they're referenced within the source
  55         # code and too difficult to exorcise.
  56         dodoc -r README.md docs examples
  57
  58         insinto /usr/share/drush
  59         doins -r classes commands includes lib misc
  60         doins drush_logo-black.png drush.info drush.php
  61
  62         exeinto /usr/share/drush
  63         doexe drush
  64         dosym ../share/drush/drush /usr/bin/drush
  65
  66         keepdir /etc/drush
  67         newbashcomp drush.complete.sh drush
  68 }