app-crypt/acme-sh/acme-sh-9999.ebuild

   1 # Copyright 1999-2022 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit git-r3 optfeature
   7
   8 DESCRIPTION="A pure Unix shell script implementing ACME client protocol"
   9 HOMEPAGE="https://github.com/acmesh-official/acme.sh"
  10 EGIT_REPO_URI="https://github.com/acmesh-official/${PN/-/.}.git"
  11
  12 LICENSE="GPL-3"
  13 SLOT="0"
  14 KEYWORDS=""
  15
  16 IUSE="selinux"
  17
  18 RDEPEND="
  19         dev-libs/openssl:0
  20         net-misc/curl
  21         net-misc/socat
  22         selinux? ( sec-policy/selinux-certbot )
  23 "
  24
  25 src_install() {
  26         newdoc deploy/README.md README-deploy.md
  27         newdoc dnsapi/README.md README-dnsapi.md
  28         rm {deploy,dnsapi}/README.md || die
  29         einstalldocs
  30
  31         exeinto /usr/share/acme.sh
  32         doexe acme.sh
  33
  34         insinto /usr/share/acme.sh
  35         doins -r deploy dnsapi notify
  36
  37         keepdir /etc/acme-sh
  38         doenvd "${FILESDIR}"/99acme-sh
  39
  40         insinto /etc/bash/bashrc.d
  41         doins "${FILESDIR}"/acme.sh
  42
  43         dosym ../share/acme.sh/acme.sh usr/bin/acme.sh
  44 }
  45
  46 pkg_postinst() {
  47         optfeature_header "For webserver mode, install a supported web server:"
  48         optfeature "using apache2 webserver mode" www-servers/apache
  49         optfeature "using nginx webserver mode" www-servers/nginx
  50 }