app-crypt/certbot/certbot-3.1.0.ebuild

   1 # Copyright 1999-2025 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 DISTUTILS_USE_PEP517=setuptools
   7 PYTHON_COMPAT=( python3_{10..13} )
   8
   9 inherit distutils-r1
  10
  11 if [[ "${PV}" == *9999 ]]; then
  12         inherit git-r3
  13
  14         EGIT_REPO_URI="https://github.com/certbot/certbot.git"
  15         EGIT_SUBMODULES=()
  16         EGIT_CHECKOUT_DIR="${WORKDIR}/${P}"
  17 else
  18         SRC_URI="
  19                 https://github.com/certbot/certbot/archive/v${PV}.tar.gz
  20                         -> ${P}.gh.tar.gz
  21         "
  22         KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
  23 fi
  24
  25 DESCRIPTION="Let’s Encrypt client to automate deployment of X.509 certificates"
  26 HOMEPAGE="
  27         https://github.com/certbot/certbot/
  28         https://pypi.org/project/certbot/
  29         https://letsencrypt.org/
  30 "
  31
  32 S="${WORKDIR}/${P}/${PN}"
  33 LICENSE="Apache-2.0"
  34 SLOT="0"
  35
  36 IUSE="selinux"
  37
  38 BDEPEND="
  39         test? (
  40                 dev-python/typing-extensions[${PYTHON_USEDEP}]
  41         )
  42 "
  43
  44 # See certbot/setup.py for acme >= dep
  45 RDEPEND="
  46         >=app-crypt/acme-${PV}[${PYTHON_USEDEP}]
  47         >=dev-python/configargparse-1.5.3[${PYTHON_USEDEP}]
  48         >=dev-python/configobj-5.0.6[${PYTHON_USEDEP}]
  49         >=dev-python/cryptography-3.2.1[${PYTHON_USEDEP}]
  50         >=dev-python/distro-1.0.1[${PYTHON_USEDEP}]
  51         >=dev-python/josepy-1.13.0[${PYTHON_USEDEP}]
  52         <dev-python/josepy-2[${PYTHON_USEDEP}]
  53         >=dev-python/parsedatetime-2.4[${PYTHON_USEDEP}]
  54         dev-python/pyrfc3339[${PYTHON_USEDEP}]
  55         >=dev-python/pytz-2019.3[${PYTHON_USEDEP}]
  56         selinux? ( sec-policy/selinux-certbot )
  57 "
  58
  59 distutils_enable_sphinx docs \
  60         dev-python/sphinx-rtd-theme
  61 distutils_enable_tests pytest
  62
  63 python_test() {
  64         local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
  65         epytest
  66 }