app-crypt/monkeysphere/monkeysphere-0.44-r2.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="Leverage the OpenPGP web of trust for OpenSSH and Web authentication"
   9 HOMEPAGE="http://web.monkeysphere.info/"
  10 SRC_URI="
  11         mirror://debian/pool/monkeysphere/m/monkeysphere/monkeysphere_${PV}.orig.tar.gz
  12         http://archive.monkeysphere.info/debian/pool/monkeysphere/m/monkeysphere/monkeysphere_${PV}.orig.tar.gz"
  13
  14 LICENSE="GPL-3"
  15 SLOT="0"
  16 KEYWORDS="amd64 ~arm x86"
  17
  18 DOCS=( README Changelog )
  19
  20 # Tests fail upstream for SSH connection. Issue has been reported.
  21 RESTRICT="test"
  22
  23 DEPEND="
  24         acct-group/monkeysphere
  25         acct-user/monkeysphere
  26         >=app-crypt/gnupg-2.1.17:0=
  27         net-misc/socat:0=
  28         dev-libs/libassuan:=
  29         dev-libs/libgcrypt:=
  30         dev-libs/libgpg-error:=
  31         dev-perl/Crypt-OpenSSL-RSA:0=
  32         dev-perl/Digest-SHA1:0=
  33         app-misc/lockfile-progs:0=
  34 "
  35 RDEPEND="${DEPEND}
  36         virtual/openssh"
  37
  38 PATCHES=(
  39         "${FILESDIR}"/${PN}-0.44-install-uncompressed-man-pages.patch
  40         "${FILESDIR}"/${PN}-0.44-no-werror.patch
  41 )
  42
  43 src_prepare() {
  44         default
  45
  46         sed -i -e "s#share/doc/monkeysphere#share/doc/${PF}#" Makefile || die
  47
  48         tc-export CC
  49 }
  50
  51 pkg_postinst() {
  52         monkeysphere-authentication setup
  53 }