dev-cpp/gflags/gflags-9999.ebuild

   1 # Copyright 1999-2023 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit cmake-multilib flag-o-matic
   7
   8 if [[ ${PV} == *9999* ]]; then
   9         inherit git-r3
  10         EGIT_REPO_URI="https://github.com/gflags/gflags"
  11 else
  12         SRC_URI="https://github.com/gflags/gflags/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  13         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
  14 fi
  15
  16 DESCRIPTION="Google's C++ argument parsing library"
  17 HOMEPAGE="https://gflags.github.io/gflags/"
  18
  19 LICENSE="BSD"
  20 SLOT="0/2.2"
  21 IUSE="static-libs test"
  22 RESTRICT="!test? ( test )"
  23
  24 # AUTHORS.txt only links the google group
  25 DOCS=( ChangeLog.txt README.md )
  26
  27 multilib_src_configure() {
  28         append-lfs-flags
  29
  30         local mycmakeargs=(
  31                 -DBUILD_STATIC_LIBS=$(usex static-libs)
  32                 -DBUILD_TESTING=$(usex test)
  33                 # avoid installing .cmake/packages, e.g.:
  34                 # >>> /tmp/portage/dev-cpp/gflags-9999/homedir/.cmake/packages/gflags/a7fca4708532331c2d656af0fdc8b8b9
  35                 -DREGISTER_INSTALL_PREFIX=OFF
  36         )
  37         cmake_src_configure
  38 }