dev-cpp/tbb/tbb-2021.7.0-r1.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit cmake-multilib flag-o-matic
   7
   8 DESCRIPTION="High level abstract threading library"
   9 HOMEPAGE="https://github.com/oneapi-src/oneTBB"
  10 SRC_URI="https://github.com/oneapi-src/oneTBB/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
  11 S="${WORKDIR}/oneTBB-${PV}"
  12
  13 LICENSE="Apache-2.0"
  14 # https://github.com/oneapi-src/oneTBB/blob/master/CMakeLists.txt#L53
  15 # libtbb<SONAME>-libtbbmalloc<SONAME>-libtbbbind<SONAME>
  16 SLOT="0/12.5-2.5-3.5"
  17 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux ~x64-macos"
  18 IUSE="test"
  19 RESTRICT="!test? ( test )"
  20
  21 RDEPEND="!kernel_Darwin? ( sys-apps/hwloc:= )"
  22 DEPEND="${RDEPEND}"
  23 BDEPEND="virtual/pkgconfig"
  24
  25 PATCHES=(
  26         "${FILESDIR}"/${PN}-2021.7.0-pthread-eagain.patch
  27 )
  28
  29 src_configure() {
  30         # Workaround for bug #912210
  31         append-ldflags $(test-flags-CCLD -Wl,--undefined-version)
  32
  33         local mycmakeargs=(
  34                 -DTBB_TEST=$(usex test)
  35                 -DTBB_ENABLE_IPO=OFF
  36                 -DTBB_STRICT=OFF
  37         )
  38
  39         cmake-multilib_src_configure
  40 }