dev-lang/lfe/lfe-2.0.1.ebuild

   1 # Copyright 1999-2023 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit elisp-common toolchain-funcs
   7
   8 DESCRIPTION="Lisp-flavoured Erlang"
   9 HOMEPAGE="http://lfe.github.io/"
  10
  11 if [[ "${PV}" == *9999* ]]; then
  12         inherit git-r3
  13         EGIT_BRANCH="develop"
  14         EGIT_REPO_URI="https://github.com/rvirding/${PN}.git"
  15 else
  16         SRC_URI="https://github.com/rvirding/${PN}/archive/refs/tags/${PV}.tar.gz
  17                 -> ${P}.tar.gz"
  18         KEYWORDS="~amd64 ~x86"
  19 fi
  20
  21 RESTRICT="mirror test"
  22 LICENSE="Apache-2.0"
  23 SLOT="0"
  24 IUSE="doc emacs"
  25
  26 RDEPEND="
  27         dev-lang/erlang
  28 "
  29 DEPEND="
  30         ${RDEPEND}
  31         doc? ( virtual/pandoc )
  32 "
  33
  34 SITEFILE="70${PN}-gentoo.el"
  35
  36 src_prepare() {
  37         default
  38
  39         sed -i "s|cc |$(tc-getCC) ${CFLAGS} |g" ./Makefile \
  40                 || die "Failed to fix the makefile"
  41 }
  42
  43 src_compile() {
  44         emake compile
  45
  46         use doc && emake docs
  47         use emacs && emake emacs
  48 }
  49
  50 src_install() {
  51         dodir "/usr/$(get_libdir)/erlang/lib/lfe/ebin/"
  52         cp -R ./ebin "${D}/usr/$(get_libdir)/erlang/lib/lfe/"
  53         dobin ./bin/*
  54
  55         if use doc; then
  56                 dodoc ./doc/*.txt
  57                 doman ./doc/man/*
  58         fi
  59
  60         if use emacs; then
  61                 elisp-install lfe emacs/* \
  62                         || die "elisp-install failed"
  63                 elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  64         fi
  65 }
  66
  67 pkg_postinst() {
  68         use emacs && elisp-site-regen
  69 }
  70
  71 pkg_postrm() {
  72         use emacs && elisp-site-regen
  73 }