dev-ruby/rubygems/rubygems-3.6.3.ebuild

   1 # Copyright 1999-2025 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 USE_RUBY="ruby31 ruby32 ruby33 ruby34"
   7
   8 inherit ruby-ng prefix
   9
  10 DESCRIPTION="Centralized Ruby extension management system"
  11 HOMEPAGE="https://rubygems.org/"
  12
  13 SRC_URI="https://github.com/rubygems/rubygems/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  14 LICENSE="|| ( Ruby MIT )"
  15
  16 SLOT="0"
  17 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
  18 IUSE="server test"
  19 RESTRICT="!test? ( test )"
  20
  21 PDEPEND="server? ( =dev-ruby/builder-3* )"
  22
  23 ruby_add_depend "virtual/ruby-ssl"
  24
  25 ruby_add_bdepend "
  26         test? (
  27                 dev-ruby/json
  28                 dev-ruby/minitest:5
  29                 dev-ruby/rake
  30                 dev-ruby/rdoc
  31                 dev-ruby/test-unit
  32                 dev-ruby/webrick
  33         )"
  34
  35 all_ruby_prepare() {
  36         # Remove unpackaged automatiek from Rakefile which stops it from working
  37         sed -i -e '/automatiek/ s:^:#:' -e '/Automatiek/,/^end/ s:^:#:' Rakefile || die
  38
  39         mkdir -p lib/rubygems/defaults || die
  40         cp "${FILESDIR}/gentoo-defaults-5.rb" lib/rubygems/defaults/operating_system.rb || die
  41
  42         eprefixify lib/rubygems/defaults/operating_system.rb
  43
  44         # Disable broken tests when changing default values:
  45         sed -i -e '/test_default_path/,/^  end/ s:^:#:' test/rubygems/test_gem.rb || die
  46         sed -e '/test_initialize_\(path_with_defaults\|regexp_path_separator\)/aomit "gentoo"' \
  47                 -i test/rubygems/test_gem_path_support.rb || die
  48         # Avoid test that won't work as json is also installed as plain ruby code
  49         sed -i -e '/test_realworld_\(\|upgraded_\)default_gem/aomit "gentoo"' test/rubygems/test_require.rb || die
  50
  51         # Avoid test that requires additional utility scripts
  52         rm -f test/test_changelog_generator.rb || die
  53
  54         # Avoid tests that require a network connection (for crates.io or other downloads)
  55         rm -f test/rubygems/test_gem_ext_cargo_builder.rb || die
  56         sed -e '/test_gem_exec_gem_uninstall/aomit "requires network"' \
  57                 -i test/rubygems/test_gem_commands_exec_command.rb || die
  58
  59         # Avoid tests with newer rdoc versions. These tests have been disabled upstream.
  60         sed -e '/test_execute_rdoc/aomit "no longer needed with rdoc 6.9.0"' \
  61                 -i test/rubygems/test_gem_commands_{install,update}_command.rb || die
  62
  63         # Update manifest after changing files to avoid a test failure. Set
  64         # RUBYLIB to ensure that we consistently use the new code for
  65         # rubygems and the bundled bundler.
  66         if use test; then
  67                 RUBYLIB=lib rake update_manifest || die
  68         fi
  69 }
  70
  71 each_ruby_compile() {
  72         # Not really a build but...
  73         sed -i -e 's:#!.*:#!'"${RUBY}"':' exe/gem
  74 }
  75
  76 each_ruby_test() {
  77         # Unset RUBYOPT to avoid interferences, bug #158455 et. al.
  78         #unset RUBYOPT
  79
  80         if [[ "${EUID}" -ne "0" ]]; then
  81                 RUBYLIB="$(pwd)/lib${RUBYLIB+:${RUBYLIB}}" ${RUBY} --disable-gems -I.:lib:test:bundler/lib \
  82                         -e 'require "rubygems"; gem "minitest", "~>5.0"; Dir["test/**/test_*.rb"].each { require _1 }' || die "tests failed"
  83         else
  84                 ewarn "The userpriv feature must be enabled to run tests, bug 408951."
  85                 eerror "Testsuite will not be run."
  86         fi
  87 }
  88
  89 each_ruby_install() {
  90         # Unset RUBYOPT to avoid interferences, bug #158455 et. al.
  91         unset RUBYOPT
  92         export RUBYLIB="$(pwd)/lib${RUBYLIB+:${RUBYLIB}}"
  93
  94         pushd lib &>/dev/null
  95         doruby -r *
  96         popd &>/dev/null
  97
  98         local sld=$(ruby_rbconfig_value 'sitelibdir')
  99         insinto "${sld#${EPREFIX}}"  # bug #320813
 100         newins "${FILESDIR}/auto_gem.rb.ruby19" auto_gem.rb
 101
 102         newbin exe/gem $(basename ${RUBY} | sed -e 's:ruby:gem:')
 103 }
 104
 105 all_ruby_install() {
 106         dodoc CHANGELOG.md README.md
 107
 108         if use server; then
 109                 newinitd "${FILESDIR}/init.d-gem_server2" gem_server
 110                 newconfd "${FILESDIR}/conf.d-gem_server" gem_server
 111         fi
 112 }
 113
 114 pkg_postinst() {
 115         if [[ ! -n $(readlink "${ROOT}"/usr/bin/gem) ]] ; then
 116                 eselect ruby set $(eselect --brief --colour=no ruby show | head -n1)
 117         fi
 118
 119         ewarn
 120         ewarn "To switch between available Ruby profiles, execute as root:"
 121         ewarn "\teselect ruby set ruby(30|31|...)"
 122         ewarn
 123 }