dev-vcs/kdesvn/kdesvn-2.1.0-r1.ebuild

   1 # Copyright 1999-2022 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 ECM_HANDBOOK="forceoptional"
   7 KFMIN=5.82.0
   8 QTMIN=5.15.2
   9 inherit ecm kde.org
  10
  11 DESCRIPTION="Frontend to the subversion vcs"
  12 HOMEPAGE="https://apps.kde.org/kdesvn/"
  13
  14 if [[ ${PV} != 9999* ]]; then
  15         SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz
  16                 https://dev.gentoo.org/~asturm/distfiles/${P}-patchset-1.tar.xz"
  17         KEYWORDS="amd64 x86"
  18 fi
  19
  20 LICENSE="GPL-2"
  21 SLOT="5"
  22 IUSE="+man"
  23
  24 DEPEND="
  25         dev-libs/apr:1
  26         dev-libs/apr-util:1
  27         >=dev-qt/qtdbus-${QTMIN}:5
  28         >=dev-qt/qtgui-${QTMIN}:5
  29         >=dev-qt/qtsql-${QTMIN}:5[sqlite]
  30         >=dev-qt/qtwidgets-${QTMIN}:5
  31         >=dev-qt/qtxml-${QTMIN}:5
  32         dev-vcs/subversion
  33         >=kde-frameworks/kbookmarks-${KFMIN}:5
  34         >=kde-frameworks/kcodecs-${KFMIN}:5
  35         >=kde-frameworks/kcompletion-${KFMIN}:5
  36         >=kde-frameworks/kconfig-${KFMIN}:5
  37         >=kde-frameworks/kconfigwidgets-${KFMIN}:5
  38         >=kde-frameworks/kcoreaddons-${KFMIN}:5
  39         >=kde-frameworks/kdbusaddons-${KFMIN}:5
  40         >=kde-frameworks/ki18n-${KFMIN}:5
  41         >=kde-frameworks/kiconthemes-${KFMIN}:5
  42         >=kde-frameworks/kio-${KFMIN}:5
  43         >=kde-frameworks/kitemviews-${KFMIN}:5
  44         >=kde-frameworks/kjobwidgets-${KFMIN}:5
  45         >=kde-frameworks/knotifications-${KFMIN}:5
  46         >=kde-frameworks/kparts-${KFMIN}:5
  47         >=kde-frameworks/kservice-${KFMIN}:5
  48         >=kde-frameworks/ktextwidgets-${KFMIN}:5
  49         >=kde-frameworks/kwallet-${KFMIN}:5
  50         >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
  51         >=kde-frameworks/kxmlgui-${KFMIN}:5
  52 "
  53 RDEPEND="${DEPEND}"
  54 BDEPEND="
  55         man? ( >=kde-frameworks/kdoctools-${KFMIN}:5 )
  56 "
  57
  58 PATCHES=(
  59         "${WORKDIR}"/${P}-remove-help-button.patch # KDE-bug 410566
  60         "${WORKDIR}"/${P}-fix-openwith-context-menu.patch # KDE-bug 410585
  61         "${WORKDIR}"/${P}-fix-dupl-cli-options.patch
  62         "${WORKDIR}"/${P}-crashfix-w-o-local-checkout-path.patch # KDE-bug 419906
  63         "${WORKDIR}"/${P}-crashfix-closing-repo.patch # KDE-bug 437948
  64         "${WORKDIR}"/${P}-hidpi-{1,2}.patch
  65         "${WORKDIR}"/${P}-fix-deprecated.patch
  66 )
  67
  68 src_prepare(){
  69         ecm_src_prepare
  70
  71         if ! use man ; then
  72                 sed -i -e "/kdoctools_create_manpage/ s/^/#/" doc/CMakeLists.txt || die
  73         fi
  74 }