games-board/eboard/eboard-1.1.1-r2.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit desktop toolchain-funcs
   7
   8 DEB_V=${PV}-4.1
   9 EXTRAS1="eboard-extras-1pl2"
  10 EXTRAS2="eboard-extras-2"
  11 DESCRIPTION="chess interface for POSIX systems"
  12 HOMEPAGE="http://www.bergo.eng.br/eboard/"
  13 SRC_URI="https://downloads.sourceforge.net/${PN}/${P}.tar.bz2
  14         https://downloads.sourceforge.net/${PN}/${EXTRAS1}.tar.gz
  15         https://downloads.sourceforge.net/${PN}/${EXTRAS2}.tar.gz
  16         mirror://debian/pool/main/e/eboard/${PN}_${DEB_V}.diff.gz"
  17
  18 LICENSE="GPL-2"
  19 SLOT="0"
  20 KEYWORDS="~amd64 ~arm64 ~x86"
  21 IUSE="nls"
  22
  23 RDEPEND="
  24         dev-libs/atk
  25         dev-libs/glib
  26         dev-libs/gobject-introspection
  27         media-libs/fontconfig
  28         media-libs/freetype
  29         media-libs/libpng:0=
  30         sys-libs/zlib
  31         x11-libs/cairo
  32         x11-libs/gdk-pixbuf
  33         x11-libs/gtk+:2
  34         x11-libs/pango
  35 "
  36 DEPEND="${RDEPEND}"
  37 BDEPEND="
  38         dev-lang/perl
  39         virtual/pkgconfig
  40 "
  41
  42 PATCHES=(
  43         "${WORKDIR}"/${PN}_${DEB_V}.diff
  44         "${FILESDIR}"/${P}-as-needed.patch
  45         "${FILESDIR}"/${P}-gcc44.patch
  46         "${FILESDIR}"/${P}-ovflfix.patch
  47         "${FILESDIR}"/${P}-libpng15.patch
  48 )
  49
  50 src_prepare() {
  51         default
  52
  53         sed -i \
  54                 -e "s:(\"-O6\"):split(' ', \"${CXXFLAGS}\"):" \
  55                 configure || die
  56 }
  57
  58 src_configure() {
  59         ./configure \
  60                 --compiler="$(tc-getCXX)" \
  61                 --prefix="/usr" \
  62                 --data-prefix="/usr/share" \
  63                 --man-prefix="/usr/share/man" \
  64                 --extra-libs="dl" \
  65                 $(use_enable nls) || die # not an autoconf script
  66 }
  67
  68 src_install() {
  69         default
  70         dodoc Documentation/*.txt
  71
  72         newicon icon-eboard.xpm ${PN}.xpm
  73         make_desktop_entry ${PN} ${PN} ${PN}
  74
  75         cd "${WORKDIR}"/${EXTRAS1} || die
  76         insinto /usr/share/${PN}
  77         doins *.png *.wav
  78         newins extras1.conf themeconf.extras1
  79         newdoc ChangeLog Changelog.extras
  80         newdoc README README.extras
  81         dodoc CREDITS
  82
  83         cd "${WORKDIR}"/${EXTRAS2} || die
  84         doins *.png *.wav
  85         newins extras2.conf themeconf.extras2
  86 }