games-server/crossfire-server/crossfire-server-1.71.0-r2.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 MY_P="${P/-server/}"
   7 DESCRIPTION="Server for the crossfire clients"
   8 HOMEPAGE="http://crossfire.real-time.com/"
   9 SRC_URI="https://downloads.sourceforge.net/crossfire/${PN}/${PV}/${MY_P}.tar.bz2
  10         https://downloads.sourceforge.net/crossfire/${PN}/${PV}/${MY_P}.maps.tar.bz2
  11         https://downloads.sourceforge.net/crossfire/${PN}/${PV}/${MY_P}.arch.tar.bz2"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="X"
  17 RESTRICT="test"
  18
  19 RDEPEND="
  20         net-misc/curl
  21         sys-libs/zlib
  22         virtual/libcrypt:=
  23         X? (
  24                 x11-libs/libXaw
  25                 media-libs/libpng:0=
  26         )
  27 "
  28 DEPEND="${RDEPEND}"
  29
  30 src_prepare() {
  31         default
  32
  33         # bug #236205
  34         rm -f "${WORKDIR}"/maps/Info/combine.pl || die
  35         ln -s "${WORKDIR}"/arch "${S}"/lib || die
  36
  37         eapply "${FILESDIR}"/${P}-format.patch
  38 }
  39
  40 src_configure() {
  41         econf --disable-static
  42 }
  43
  44 src_compile() {
  45         # work around the collect.pl locking
  46         emake -j1 -C lib
  47         emake
  48 }
  49
  50 src_install() {
  51         default
  52
  53         keepdir /var/lib/crossfire/{account,datafiles,maps,players,template-maps,unique-items}
  54
  55         insinto /usr/share/crossfire
  56         doins -r "${WORKDIR}"/maps
  57
  58         find "${ED}" -name '*.la' -delete || die
  59 }