gnustep-libs/dbuskit/dbuskit-0.1.1-r2.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit autotools gnustep-2
   7
   8 DESCRIPTION="Framework that interfaces Objective-C applications with the D-Bus IPC service"
   9 HOMEPAGE="https://github.com/gnustep/libs-dbuskit"
  10 SRC_URI="https://github.com/gnustep/libs-dbuskit/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11 S="${WORKDIR}/libs-${P}"
  12
  13 LICENSE="LGPL-2.1+"
  14 SLOT="0"
  15 KEYWORDS="amd64 ppc x86"
  16
  17 DEPEND=">=sys-apps/dbus-1.2.1"
  18 RDEPEND="${DEPEND}"
  19
  20 PATCHES=( "${FILESDIR}"/${P}-remove_gc.patch )
  21
  22 src_prepare() {
  23         default
  24
  25         if ! use doc; then
  26                 # Remove doc target
  27                 sed -i -e "/SUBPROJECTS/s/Documentation//" GNUmakefile \
  28                         || die "doc sed failed"
  29         fi
  30
  31         # Bug 410697
  32         sed -e "s#ObjectiveC2/runtime.h#ObjectiveC2/objc/runtime.h#" \
  33                 -i configure.ac || die "ObjectiveC2 runtime sed failed"
  34
  35         eautoreconf
  36 }