kde-frameworks/kcrash/kcrash-5.116.0.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 ECM_TEST="forceoptional"
   7 PVCUT=$(ver_cut 1-2)
   8 QTMIN=5.15.9
   9 inherit ecm frameworks.kde.org
  10
  11 DESCRIPTION="Framework for intercepting and handling application crashes"
  12
  13 LICENSE="LGPL-2+"
  14 KEYWORDS="amd64 ~arm arm64 ~loong ppc64 ~riscv x86"
  15 IUSE="X"
  16
  17 # requires running Plasma environment
  18 RESTRICT="test"
  19
  20 RDEPEND="
  21         >=dev-qt/qtgui-${QTMIN}:5
  22         =kde-frameworks/kcoreaddons-${PVCUT}*:5
  23         X? (
  24                 >=dev-qt/qtx11extras-${QTMIN}:5
  25                 x11-libs/libX11
  26         )
  27 "
  28 DEPEND="${RDEPEND}
  29         X? ( x11-base/xorg-proto )
  30         test? ( >=dev-qt/qtwidgets-${QTMIN}:5 )
  31 "
  32 BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
  33
  34 src_configure() {
  35         local mycmakeargs=(
  36                 -DWITH_X11=$(usex X)
  37         )
  38         ecm_src_configure
  39 }