kde-frameworks/kio/kio-6.10.0.ebuild

   1 # Copyright 1999-2025 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 ECM_DESIGNERPLUGIN="true"
   7 ECM_HANDBOOK="optional"
   8 ECM_HANDBOOK_DIR="docs"
   9 ECM_TEST="forceoptional"
  10 QTMIN=6.7.2
  11 inherit ecm frameworks.kde.org xdg
  12
  13 DESCRIPTION="Framework providing transparent file and data management"
  14
  15 LICENSE="LGPL-2+"
  16 KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
  17 IUSE="acl +kwallet wayland X"
  18
  19 # tests hang
  20 RESTRICT="test"
  21
  22 # slot op: Uses Qt6::GuiPrivate for qtx11extras_p.h
  23 COMMON_DEPEND="
  24         >=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,ssl,widgets,X?]
  25         >=dev-qt/qtdeclarative-${QTMIN}:6
  26         =kde-frameworks/kauth-${KDE_CATV}*:6
  27         =kde-frameworks/kbookmarks-${KDE_CATV}*:6
  28         =kde-frameworks/kcodecs-${KDE_CATV}*:6
  29         =kde-frameworks/kcolorscheme-${KDE_CATV}*:6
  30         =kde-frameworks/kcompletion-${KDE_CATV}*:6
  31         =kde-frameworks/kconfig-${KDE_CATV}*:6
  32         =kde-frameworks/kcoreaddons-${KDE_CATV}*:6
  33         =kde-frameworks/kcrash-${KDE_CATV}*:6
  34         =kde-frameworks/kdbusaddons-${KDE_CATV}*:6
  35         =kde-frameworks/kguiaddons-${KDE_CATV}*:6
  36         =kde-frameworks/ki18n-${KDE_CATV}*:6
  37         =kde-frameworks/kiconthemes-${KDE_CATV}*:6
  38         =kde-frameworks/kitemviews-${KDE_CATV}*:6
  39         =kde-frameworks/kjobwidgets-${KDE_CATV}*:6
  40         =kde-frameworks/knotifications-${KDE_CATV}*:6
  41         =kde-frameworks/kservice-${KDE_CATV}*:6
  42         =kde-frameworks/ktextwidgets-${KDE_CATV}*:6
  43         =kde-frameworks/kwidgetsaddons-${KDE_CATV}*:6
  44         =kde-frameworks/kwindowsystem-${KDE_CATV}*:6[wayland?,X?]
  45         =kde-frameworks/kxmlgui-${KDE_CATV}*:6
  46         =kde-frameworks/solid-${KDE_CATV}*:6
  47         sys-power/switcheroo-control
  48         acl? (
  49                 sys-apps/attr
  50                 virtual/acl
  51         )
  52         handbook? (
  53                 dev-libs/libxml2
  54                 dev-libs/libxslt
  55                 =kde-frameworks/karchive-${KDE_CATV}*:6
  56                 =kde-frameworks/kdoctools-${KDE_CATV}*:6
  57         )
  58         kwallet? ( =kde-frameworks/kwallet-${KDE_CATV}*:6 )
  59         X? ( >=dev-qt/qtbase-${QTMIN}:6=[gui] )
  60 "
  61 DEPEND="${COMMON_DEPEND}
  62         >=dev-qt/qtbase-${QTMIN}:6[concurrent]
  63 "
  64 RDEPEND="${COMMON_DEPEND}
  65         >=dev-qt/qtbase-${QTMIN}:6[libproxy]
  66         sys-power/switcheroo-control
  67 "
  68 # bug 944812: File Properties is accessible from KFileWidget (KIO); this
  69 # provides access to keditfiletype binary via KWidgetsAddons (Tier1)
  70 # Typical KIO revdeps (dolphin, krusader et al.) can rely on this dep
  71 PDEPEND="
  72         >=kde-frameworks/kded-${KDE_CATV}:6
  73         kde-plasma/keditfiletype
  74 "
  75
  76 src_configure() {
  77         local mycmakeargs=(
  78                 $(cmake_use_find_package acl ACL)
  79                 $(cmake_use_find_package kwallet KF6Wallet)
  80                 -DWITH_WAYLAND=$(usex wayland)
  81                 -DWITH_X11=$(usex X)
  82         )
  83
  84         ecm_src_configure
  85 }