media-libs/Field3D/Field3D-1.7.3_p20230509.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit cmake flag-o-matic
   7
   8 DESCRIPTION="A library for storing voxel data"
   9 HOMEPAGE="http://opensource.imageworks.com/?p=field3d"
  10 SRC_COMMIT="b0ff0cd67893a4cbfa322676eb3eef10100d904d"
  11 SRC_URI="https://github.com/imageworks/Field3D/archive/${SRC_COMMIT}.tar.gz -> ${P}.tar.gz"
  12
  13 LICENSE="BSD"
  14 SLOT="0"
  15 KEYWORDS="amd64 ~arm ~arm64 x86"
  16 IUSE="doc mpi test"
  17
  18 RESTRICT="!test? ( test )"
  19
  20 RDEPEND="
  21         dev-libs/boost:=
  22         >=dev-libs/imath-3.1.4-r2:=
  23         >=media-libs/openexr-3:0=
  24         sci-libs/hdf5:=
  25         doc? ( app-text/doxygen )
  26         mpi? ( virtual/mpi )
  27 "
  28 DEPEND="${RDEPEND}"
  29
  30 PATCHES=(
  31         "${FILESDIR}/${PN}-1.7.2-openexr-3-imath.patch"
  32         "${FILESDIR}/${PN}-1.7.2-boost-1.83-timer-header-deprecated.patch"
  33 )
  34
  35 S="${WORKDIR}/${PN}-${SRC_COMMIT}"
  36
  37 src_prepare() {
  38         sed -e "s#auto_ptr#unique_ptr#g" -i include/*.h || die
  39         sed \
  40                 -e "s#DESTINATION \${CMAKE_INSTALL_PREFIX}#DESTINATION \${CMAKE_INSTALL_DOCDIR}#" \
  41                 -e "s#CMAKE_MINIMUM_REQUIRED( VERSION 2.8 )#CMAKE_MINIMUM_REQUIRED( VERSION 3.5 )#" \
  42                 -i CMakeLists.txt || die
  43
  44         cmake_src_prepare
  45 }
  46
  47 src_configure() {
  48         # Needed for now ("fix" compatibility with >=sci-libs/hdf5-1.12)
  49         # bug #808731
  50         append-cppflags -DH5_USE_110_API
  51
  52         local mycmakeargs=(
  53                 -DCMAKE_CXX_STANDARD=11
  54
  55                 -DINSTALL_DOCS="$(usex doc)" # Docs are not finished yet.
  56                 -DCMAKE_DISABLE_FIND_PACKAGE_Doxygen="$(usex !doc)"
  57
  58                 "$(cmake_use_find_package mpi MPI)"
  59         )
  60
  61         cmake_src_configure
  62 }
  63
  64 src_test() {
  65         cd "${BUILD_DIR}" || die
  66         ./unitTest || die
  67 }