media-libs/gstreamer-editing-services/gstreamer-editing-services-1.24.10.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5 PYTHON_COMPAT=( python3_{10..12} )
   6
   7 inherit meson python-r1
   8
   9 DESCRIPTION="SDK for making video editors and more"
  10 HOMEPAGE="http://wiki.pitivi.org/wiki/GES"
  11 SRC_URI="https://gstreamer.freedesktop.org/src/${PN}/${P/gstreamer/gst}.tar.xz"
  12 S="${WORKDIR}"/${P/gstreamer/gst}
  13
  14 LICENSE="LGPL-2+"
  15 SLOT="1.0"
  16 KEYWORDS="~amd64 ~arm64 ~x86"
  17
  18 IUSE="+introspection test"
  19 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  20 # Some tests are failing
  21 RESTRICT="test"
  22
  23 RDEPEND="
  24         ${PYTHON_DEPS}
  25         >=dev-libs/glib-2.40.0:2
  26         dev-libs/libxml2:2
  27         >=media-libs/gstreamer-${PV}:1.0[introspection?]
  28         >=media-libs/gst-plugins-base-${PV}:1.0[introspection?]
  29         >=media-libs/gst-plugins-bad-${PV}:1.0[introspection?]
  30         introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
  31 "
  32 DEPEND="${RDEPEND}"
  33 BDEPEND="virtual/pkgconfig"
  34
  35 src_configure() {
  36         python_setup
  37
  38         local emesonargs=(
  39                 -Ddoc=disabled # hotdoc not packaged
  40                 $(meson_feature introspection)
  41                 $(meson_feature test tests)
  42                 -Dbash-completion=disabled
  43                 -Dxptv=disabled
  44                 -Dpython=enabled
  45                 -Dvalidate=disabled
  46                 -Dexamples=disabled
  47         )
  48         meson_src_configure
  49 }
  50
  51 src_install() {
  52         meson_src_install
  53         python_moduleinto gi.overrides
  54         python_foreach_impl python_domodule bindings/python/gi/overrides/GES.py
  55 }