media-libs/libcanberra/libcanberra-0.30-r8.ebuild

   1 # Copyright 1999-2025 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit libtool multilib-minimal systemd
   7
   8 DESCRIPTION="Portable sound event library"
   9 HOMEPAGE="https://0pointer.de/lennart/projects/libcanberra/"
  10 SRC_URI="https://0pointer.de/lennart/projects/${PN}/${P}.tar.xz"
  11
  12 LICENSE="LGPL-2.1+"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
  15 IUSE="alsa gstreamer oss pulseaudio tdb udev"
  16
  17 DEPEND="
  18         dev-libs/libltdl:0[${MULTILIB_USEDEP}]
  19         media-libs/libvorbis[${MULTILIB_USEDEP}]
  20         alsa? (
  21                 media-libs/alsa-lib:=[${MULTILIB_USEDEP}]
  22                 udev? ( virtual/libudev:=[${MULTILIB_USEDEP}] ) )
  23         gstreamer? ( media-libs/gstreamer:1.0[${MULTILIB_USEDEP}] )
  24         pulseaudio? ( media-libs/libpulse[${MULTILIB_USEDEP}] )
  25         tdb? ( sys-libs/tdb:=[${MULTILIB_USEDEP}] )
  26 "
  27 RDEPEND="${DEPEND}
  28         x11-themes/sound-theme-freedesktop" # Required for index.theme wrt #323379
  29 BDEPEND="
  30         app-arch/xz-utils
  31         virtual/pkgconfig
  32 "
  33
  34 REQUIRED_USE="udev? ( alsa )"
  35
  36 src_prepare() {
  37         default
  38         elibtoolize
  39 }
  40
  41 multilib_src_configure() {
  42         local myeconfargs=(
  43                 --docdir="${EPREFIX}"/usr/share/doc/${PF}
  44                 $(use_enable alsa)
  45                 $(use_enable oss)
  46                 $(use_enable pulseaudio pulse)
  47                 $(use_enable gstreamer)
  48                 --disable-gtk
  49                 --disable-gtk3
  50                 $(use_enable tdb)
  51                 $(use_enable udev)
  52                 --disable-lynx
  53                 --disable-gtk-doc
  54                 --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
  55         )
  56
  57         ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
  58
  59         if multilib_is_native_abi; then
  60                 ln -s "${S}"/gtkdoc/html gtkdoc/html || die
  61         fi
  62 }
  63
  64 multilib_src_install() {
  65         # Disable parallel installation until bug #253862 is solved
  66         emake DESTDIR="${D}" -j1 install
  67 }
  68
  69 multilib_src_install_all() {
  70         einstalldocs
  71         find "${ED}" -type f -name '*.la' -delete || die
  72 }