media-libs/liboggz/liboggz-1.1.1-r1.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit autotools
   7
   8 DESCRIPTION="A simple programming interface for reading and writing Ogg files and streams"
   9 HOMEPAGE="https://www.xiph.org/oggz/"
  10 SRC_URI="https://downloads.xiph.org/releases/${PN}/${P}.tar.gz"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 ~hppa ppc ppc64 sparc x86"
  15 IUSE="doc static-libs test"
  16 RESTRICT="!test? ( test )"
  17
  18 DEPEND=">=media-libs/libogg-1.2.0"
  19 RDEPEND="${DEPEND}"
  20 BDEPEND="
  21         virtual/pkgconfig
  22         doc? ( app-text/doxygen )
  23         test? ( app-text/docbook-sgml-utils )
  24 "
  25
  26 PATCHES=( "${FILESDIR}/${P}-destdir.patch" )
  27
  28 src_prepare() {
  29         default
  30
  31         if ! use doc; then
  32                 sed -e '/AC_CHECK_PROG/s:doxygen:dIsAbLe&:' -i configure.ac || die
  33         fi
  34
  35         AT_M4DIR="m4" eautoreconf
  36 }
  37
  38 src_configure() {
  39         econf \
  40                 $(use_enable static-libs static)
  41 }
  42
  43 src_install() {
  44         default
  45         mv "${ED}"/usr/share/doc/${PN} "${ED}"/usr/share/doc/${PF} || die # bug 808159
  46         find "${D}" -type f -name '*.la' -delete || die
  47 }