sci-electronics/splat/splat-1.4.2-r1.ebuild

   1 # Copyright 1999-2023 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="RF Signal Propagation, Loss, And Terrain analysis tool"
   9 HOMEPAGE="https://www.qsl.net/kd2bd/splat.html"
  10 SRC_URI="https://www.qsl.net/kd2bd/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~x86"
  15 IUSE="doc hires l10n_es"
  16
  17 DEPEND="
  18         app-arch/bzip2
  19         sys-libs/zlib
  20 "
  21 RDEPEND="${DEPEND}"
  22
  23 PATCHES=(
  24         "${FILESDIR}"/${PN}-1.2.2-gcc43.patch
  25         "${FILESDIR}"/${PN}-1.4.2-drop-register-keyword.patch
  26 )
  27
  28 src_configure() {
  29         # fake resulting file from interactive configuration script
  30         # using default resolution
  31         cat <<- EOF > "${S}/splat.h" || die
  32                 /* Parameters for 3 arc-second standard resolution mode of operation */
  33                 #define MAXPAGES 9
  34                 #define HD_MODE 0
  35         EOF
  36         if use hires; then
  37                 # fake resulting file from interactive configuration script
  38                 # using default resolution
  39                 cat <<- EOF > "${S}/hires.h" || die
  40                         /* Parameters for 3 arc-second hires resolution mode of operation */
  41                         #define MAXPAGES 9
  42                         #define HD_MODE 1
  43         EOF
  44         fi
  45 }
  46
  47 src_compile() {
  48         tc-export CC CXX
  49
  50         cp {splat,rfsplat}.cpp || die
  51         emake LDLIBS="-lm -lbz2" -E "rfsplat: itwom3.0.o"
  52         if use hires; then
  53                 cp {hires,splat}.h || die
  54                 cp {splat,rfsplat-hd}.cpp || die
  55                 emake LDLIBS="-lm -lbz2" -E "rfsplat-hd: itwom3.0.o"
  56         fi
  57
  58         cd utils || die
  59
  60         emake citydecoder usgs2sdf
  61         emake LDLIBS=-lbz2 srtm2sdf
  62         emake LDLIBS=-lm bearing
  63 }
  64
  65 src_install() {
  66         local SPLAT_LANG="english"
  67         use l10n_es && SPLAT_LANG="spanish"
  68         # splat binary
  69         dobin rfsplat
  70
  71         use hires && dobin rfsplat-hd
  72
  73         # utilities
  74         dobin utils/{citydecoder,usgs2sdf,srtm2sdf,postdownload,bearing}
  75         newman docs/${SPLAT_LANG}/man/splat.man rfsplat.1
  76
  77         dodoc CHANGES README utils/fips.txt
  78         newdoc utils/README README.UTILS
  79
  80         use doc && dodoc docs/${SPLAT_LANG}/{pdf/splat.pdf,postscript/splat.ps}
  81
  82         #sample data
  83         docinto sample_data
  84         dodoc -r sample_data/.
  85 }
  86
  87 pkg_postinst() {
  88         elog "The original SPLAT! command got renamed to 'rfsplat' to avoid"
  89         elog "filename collision with app-portage/splat."
  90         elog ""
  91         elog "Be aware that it is still referenced as 'splat' in the documentation."
  92 }