sci-mathematics/ginac/ginac-1.8.7-r3.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 PYTHON_COMPAT=( python3_{9..12} )
   7
   8 inherit python-any-r1
   9
  10 DESCRIPTION="C++ library and tools for symbolic calculations"
  11 HOMEPAGE="https://www.ginac.de/"
  12 SRC_URI="http://www.ginac.de/${P}.tar.bz2"
  13
  14 LICENSE="GPL-2+"
  15 SLOT="0"
  16 KEYWORDS="amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
  17 IUSE="doc examples"
  18
  19 RDEPEND=">=sci-libs/cln-1.2.2"
  20 DEPEND="${RDEPEND}"
  21 BDEPEND="
  22         ${PYTHON_DEPS}
  23         virtual/pkgconfig
  24         doc? (
  25                 app-text/doxygen
  26                 dev-texlive/texlive-fontsrecommended
  27                 >=media-gfx/fig2dev-3.2.9-r3[ghostscript]
  28                 dev-texlive/texlive-latexextra
  29                 virtual/texi2dvi
  30         )"
  31
  32 PATCHES=( "${FILESDIR}"/${PN}-1.8.2-pkgconfig.patch )
  33
  34 src_configure() {
  35         econf \
  36                 --disable-rpath \
  37                 --disable-static
  38 }
  39
  40 src_compile() {
  41         emake
  42
  43         if use doc; then
  44                 local -x VARTEXFONTS="${T}"/fonts
  45                 emake -C doc/reference html pdf
  46                 emake -C doc/tutorial ginac.pdf ginac.html
  47         fi
  48 }
  49
  50 src_install() {
  51         default
  52
  53         if use doc; then
  54                 pushd doc >/dev/null || die
  55                 newdoc tutorial/ginac.pdf tutorial.pdf
  56                 newdoc reference/reference.pdf reference.pdf
  57
  58                 docinto html/reference
  59                 dodoc -r reference/html_files/.
  60
  61                 docinto html
  62                 newdoc tutorial/ginac.html tutorial.html
  63                 popd >/dev/null || die
  64         fi
  65
  66         if use examples; then
  67                 pushd doc >/dev/null || die
  68                 docinto examples
  69                 dodoc examples/*.cpp examples/ginac-examples.*
  70                 docompress -x /usr/share/doc/${PF}/examples
  71                 popd >/dev/null || die
  72         fi
  73
  74         # no static archives
  75         find "${ED}" -name '*.la' -delete || die
  76 }