www-apps/kibana-bin/kibana-bin-7.17.25.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit systemd
   7
   8 MY_PN="${PN%-bin}"
   9 MY_P=${MY_PN}-${PV}
  10
  11 DESCRIPTION="Analytics and search dashboard for Elasticsearch"
  12 HOMEPAGE="https://www.elastic.co/products/kibana"
  13 SRC_URI="https://artifacts.elastic.co/downloads/${MY_PN}/${MY_P}-linux-x86_64.tar.gz"
  14
  15 # source: LICENSE.txt and NOTICE.txt
  16 LICENSE="Apache-2.0 Artistic-2 BSD BSD-2 CC-BY-3.0 CC-BY-4.0 Elastic-2.0 icu ISC MIT MPL-2.0 OFL-1.1 openssl public-domain Unlicense WTFPL-2 ZLIB"
  17 SLOT="0"
  18 KEYWORDS="-* ~amd64"
  19
  20 RDEPEND="
  21         acct-group/kibana
  22         acct-user/kibana
  23         dev-libs/expat
  24         dev-libs/nspr
  25         dev-libs/nss
  26         >=net-libs/nodejs-20.15.1
  27         <net-libs/nodejs-22
  28         sys-libs/glibc
  29 "
  30
  31 # Do not complain about CFLAGS etc since we don't use them
  32 QA_FLAGS_IGNORED='.*'
  33 QA_PRESTRIPPED="
  34         opt/kibana/x-pack/plugins/reporting/chromium/headless_shell-linux_x64/headless_shell
  35         opt/kibana/x-pack/plugins/reporting/chromium/headless_shell-linux_x64/swiftshader/libEGL.so
  36         opt/kibana/x-pack/plugins/reporting/chromium/headless_shell-linux_x64/swiftshader/libGLESv2.so
  37         opt/kibana/node_modules/re2/build/Release/re2.node
  38 "
  39
  40 S="${WORKDIR}/${MY_P}-linux-x86_64"
  41
  42 src_prepare() {
  43         default
  44
  45         # remove unused directory
  46         rm -r data || die
  47
  48         # remove bundled nodejs
  49         rm -r node || die
  50         sed -i 's@\(^NODE="\).*@\1/usr/bin/node"@g' \
  51                 bin/kibana || die
  52
  53         # move plugins to /var/lib/kibana
  54         rm -r plugins || die
  55
  56         # handle node.js version with RDEPEND
  57         sed -i /node_version_validator/d \
  58                 src/setup_node_env/no_transpilation_dist.js || die
  59 }
  60
  61 src_install() {
  62         insinto /etc/${MY_PN}
  63         doins -r config/.
  64         rm -r config || die
  65
  66         insinto /etc/logrotate.d
  67         newins "${FILESDIR}"/${MY_PN}.logrotate ${MY_PN}
  68
  69         newconfd "${FILESDIR}"/${MY_PN}.confd ${MY_PN}
  70         newinitd "${FILESDIR}"/${MY_PN}.initd-r1 ${MY_PN}
  71         systemd_dounit "${FILESDIR}"/${MY_PN}.service
  72
  73         insinto /opt/${MY_PN}
  74         doins -r .
  75
  76         fperms -R +x /opt/${MY_PN}/bin
  77
  78         diropts -m 0750 -o ${MY_PN} -g ${MY_PN}
  79         keepdir /var/lib/${MY_PN}/plugins
  80         keepdir /var/log/${MY_PN}
  81
  82         dosym ../../var/lib/kibana/plugins /opt/kibana/plugins
  83 }
  84
  85 pkg_postinst() {
  86         elog "This version of Kibana is compatible with Elasticsearch $(ver_cut 1-2) and"
  87         elog "Node.js 20. Some plugins may fail with other versions of Node.js (Bug #656008)."
  88         elog
  89         elog "To set a customized Elasticsearch instance:"
  90         elog "  OpenRC: set ES_INSTANCE in /etc/conf.d/${MY_PN}"
  91         elog "  systemd: set elasticsearch.url in /etc/${MY_PN}/kibana.yml"
  92         elog
  93         elog "Elasticsearch can run local or remote."
  94 }