www-apps/radicale/radicale-3.3.1.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 DISTUTILS_USE_PEP517=setuptools
   7 PYTHON_COMPAT=( python3_{10..13} )
   8
   9 inherit distutils-r1 optfeature systemd
  10
  11 MY_P=${P^}
  12 DESCRIPTION="A simple CalDAV calendar server"
  13 HOMEPAGE="https://radicale.org/"
  14 SRC_URI="
  15         https://github.com/Kozea/Radicale/archive/refs/tags/v${PV}.tar.gz
  16                 -> ${MY_P}.gh.tar.gz
  17 "
  18 S=${WORKDIR}/${MY_P}
  19
  20 LICENSE="GPL-3+"
  21 SLOT="0"
  22 KEYWORDS="~amd64 ~arm ~x86"
  23
  24 RDEPEND="
  25         >=acct-user/radicale-0-r2
  26         acct-group/radicale
  27         dev-python/bcrypt[${PYTHON_USEDEP}]
  28         dev-python/defusedxml[${PYTHON_USEDEP}]
  29         dev-python/passlib[${PYTHON_USEDEP}]
  30         dev-python/vobject[${PYTHON_USEDEP}]
  31         sys-apps/util-linux
  32 "
  33
  34 BDEPEND="
  35         test? (
  36                 dev-python/pytest[${PYTHON_USEDEP}]
  37                 dev-python/waitress[${PYTHON_USEDEP}]
  38         )
  39 "
  40
  41 distutils_enable_tests pytest
  42
  43 RDIR=/var/lib/"${PN}"
  44
  45 DOCS=( DOCUMENTATION.md CHANGELOG.md )
  46
  47 python_test() {
  48         epytest -o addopts= radicale/tests/
  49 }
  50
  51 python_install_all() {
  52         rm README* || die
  53         # init file
  54         newinitd "${FILESDIR}"/radicale-r4.init.d radicale
  55         systemd_dounit "${FILESDIR}/${PN}.service"
  56
  57         # directories
  58         keepdir "${RDIR}"
  59         fperms 0750 "${RDIR}"
  60         fowners "${PN}:${PN}" "${RDIR}"
  61
  62         # config file
  63         insinto /etc/"${PN}"
  64         doins config
  65
  66         # fcgi and wsgi files
  67         exeinto /usr/share/"${PN}"
  68         doexe radicale.wsgi
  69
  70         distutils-r1_python_install_all
  71 }
  72
  73 pkg_postinst() {
  74         local _erdir="${EROOT}${RDIR}"
  75
  76         einfo "A sample WSGI script has been put into ${EROOT}/usr/share/${PN}."
  77         einfo "You will also find there an example FastCGI script."
  78         if [[ $(stat --format="%U:%G:%a" "${_erdir}") != "${PN}:${PN}:750" ]]
  79         then
  80                 ewarn ""
  81                 ewarn "Unsafe file permissions detected on ${_erdir}."
  82                 ewarn "This probably comes from an earlier version of this ebuild."
  83                 ewarn "To fix run:"
  84                 ewarn "#  \`chown -R ${PN}:${PN} ${_erdir}\`"
  85                 ewarn "#  \`chmod 0750 ${_erdir}\`"
  86                 ewarn "#  \`chmod -R o= ${_erdir}\`"
  87         fi
  88
  89         optfeature "Publish changes to rabbitmq" dev-python/pika
  90         optfeature "LDAP/LDAPS authentication" dev-python/ldap3 dev-python/python-ldap
  91 }