app-forensics/radamsa/radamsa-0.7.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit toolchain-funcs
   7
   8 MY_P="${PN}-v${PV}"
   9
  10 DESCRIPTION="A general-purpose fuzzer"
  11 HOMEPAGE="https://gitlab.com/akihe/radamsa"
  12 SRC_URI="
  13         https://gitlab.com/akihe/${PN}/-/archive/v${PV}/${MY_P}.tar.bz2
  14         https://gitlab.com/akihe/${PN}/uploads/d774a42f7893012d0a56c490a75ae12b/${P}.c.gz
  15 "
  16
  17 LICENSE="MIT"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20
  21 # needs an owl-lisp
  22 RESTRICT=test
  23
  24 PATCHES=(
  25         "${FILESDIR}"/${PN}-0.7_prebuilt-c.patch
  26 )
  27
  28 S="${WORKDIR}"/${MY_P}
  29
  30 src_prepare() {
  31         default
  32
  33         cp "${WORKDIR}"/${P}.c "${S}"/${PN}.c || die
  34 }
  35
  36 src_compile() {
  37         emake bin/radamsa CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
  38 }
  39
  40 src_install() {
  41         dobin bin/radamsa
  42         # avoid man compression by build system
  43         doman doc/radamsa.1
  44
  45         einstalldocs
  46 }