games-action/fakk2/fakk2-1.02-r1.ebuild

   1 # Copyright 1999-2021 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cdrom desktop wrapper
   7
   8 DESCRIPTION="3D third-person action shooter based on the Heavy Metal comics/movies"
   9 HOMEPAGE="http://www.lokigames.com/products/fakk2/"
  10 SRC_URI=""
  11 S="${WORKDIR}"
  12
  13 LICENSE="LOKI-EULA"
  14 SLOT="0"
  15 KEYWORDS="~x86"
  16 IUSE="nocd"
  17 RESTRICT="strip bindist"
  18
  19 RDEPEND="virtual/opengl"
  20
  21 dir=/opt/${PN}
  22 Ddir=${D}/${dir}
  23
  24 pkg_setup() {
  25         if use nocd ; then
  26                 ewarn "The installed game takes about 378MB of space!"
  27         fi
  28 }
  29
  30 src_install() {
  31         cdrom_get_cds fakk
  32         einfo "Copying files... this may take a while..."
  33         exeinto "${dir}"
  34         doexe ${CDROM_ROOT}/bin/x86/glibc-2.1/${PN}
  35         insinto "${dir}"
  36         doins ${CDROM_ROOT}/{README,icon.{bmp,xpm}}
  37         exeinto "${dir}"/fakk
  38         doexe ${CDROM_ROOT}/bin/x86/glibc-2.1/fakk/{c,f}game.so
  39         if use nocd ; then
  40                 insinto "${dir}"/fakk
  41                 doins ${CDROM_ROOT}/fakk/pak{0,1,2,3}.pk3
  42                 doins ${CDROM_ROOT}/fakk/default.cfg
  43         fi
  44
  45         # Now, since these files are coming off a cd, the times/sizes/md5sums won't
  46         # be different ... that means portage will try to unmerge some files (!)
  47         # So, we run touch on ${D} to make sure portage doesn't do any such thing
  48         find "${Ddir}" -exec touch '{}' \; || die
  49
  50         make_wrapper ${PN} ./${PN} "${dir}" "${dir}"
  51         newicon ${CDROM_ROOT}/icon.xpm ${PN}.xpm
  52
  53         make_desktop_entry ${PN} "FAKK2" ${PN}
  54 }
  55
  56 pkg_postinst() {
  57         echo
  58         ewarn "There are two possible security bugs in this package, both causing a denial of"
  59         ewarn "service.  One affects the game when running a server, the other when running as"
  60         ewarn "a client.  For more information, see bug #82149."
  61         echo
  62         elog "To play the game run:"
  63         elog " fakk2"
  64 }