games-board/freedoko/freedoko-0.8.0.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit desktop flag-o-matic toolchain-funcs
   7
   8 DESCRIPTION="FreeDoko is a Doppelkopf-game"
   9 HOMEPAGE="https://free-doko.sourceforge.net"
  10 SRC_URI="
  11         https://downloads.sourceforge.net/free-doko/FreeDoko_${PV}.src.zip
  12         backgrounds? ( https://downloads.sourceforge.net/free-doko/backgrounds.zip -> ${PN}-backgrounds.zip )
  13         gnomecards? ( https://downloads.sourceforge.net/free-doko/gnome-games.zip )
  14         kdecards? ( https://downloads.sourceforge.net/free-doko/kdecarddecks.zip )
  15         openclipartcards? ( https://downloads.sourceforge.net/free-doko/openclipart.zip )
  16         pysolcards? ( https://downloads.sourceforge.net/free-doko/pysol.zip )
  17         xskatcards? ( https://downloads.sourceforge.net/free-doko/xskat.zip )
  18         !xskatcards? (
  19                 !kdecards? (
  20                         !gnomecards? (
  21                                 !openclipartcards? (
  22                                         !pysolcards? (
  23                                                 https://downloads.sourceforge.net/free-doko/xskat.zip ) ) ) ) )"
  24 S="${WORKDIR}/FreeDoko_${PV}"
  25
  26 LICENSE="GPL-2+"
  27 SLOT="0"
  28 KEYWORDS="~amd64 ~x86"
  29 IUSE="+backgrounds +gnomecards +kdecards +openclipartcards +pysolcards +xskatcards"
  30
  31 RDEPEND="
  32         dev-cpp/gtkmm:3.0
  33         media-libs/openal"
  34 DEPEND="${RDEPEND}"
  35 BDEPEND="
  36         app-arch/unzip
  37         virtual/pkgconfig"
  38
  39 PATCHES=(
  40         "${FILESDIR}"/${PN}-0.8.0-gentoo.patch
  41 )
  42
  43 src_unpack() {
  44         unpack FreeDoko_${PV}.src.zip
  45
  46         local cards=
  47         unpack_cards() {
  48                 if use $1; then
  49                         cards=y
  50                         unpack $2
  51                 fi
  52         }
  53
  54         cd "${S}"/data/cardsets || die
  55
  56         unpack_cards gnomecards       gnome-games.zip
  57         unpack_cards kdecards         kdecarddecks.zip
  58         unpack_cards openclipartcards openclipart.zip
  59         unpack_cards pysolcards       pysol.zip
  60         unpack_cards xskatcards       xskat.zip
  61         [[ $cards ]] || unpack xskat.zip # fall back to xskat
  62
  63         if use backgrounds ; then
  64                 cd "${S}"/data/backgrounds || die
  65                 unpack ${PN}-backgrounds.zip
  66         fi
  67 }
  68
  69 src_compile() {
  70         tc-export CXX
  71         append-cppflags \
  72                 -DPUBLIC_DATA_DIRECTORY_VALUE="'\"${EPREFIX}/usr/share/${PN}\"'" \
  73                 -DMANUAL_DIRECTORY_VALUE="'\"${EPREFIX}/usr/share/doc/${PF}/html\"'"
  74         touch src/Makefile.local || die # needed for above paths to be used
  75
  76         export OSTYPE=Linux
  77         export USE_NETWORK=false
  78         export USE_SOUND_ALUT=false # still marked experimental
  79         export VARTEXFONTS="${T}/fonts" #652028
  80
  81         emake Version
  82         emake -C src FreeDoko LIBS="${LDFLAGS}"
  83 }
  84
  85 src_install() {
  86         newbin src/FreeDoko freedoko
  87
  88         insinto /usr/share/${PN}
  89         doins -r data/{backgrounds,cardsets,iconsets,sounds,*.png}
  90
  91         newicon src/icon.png ${PN}.png
  92         make_desktop_entry ${PN} FreeDoko
  93
  94         einstalldocs
  95
  96         find "${ED}"/usr/share/${PN} -name Makefile -delete || die
  97 }