games-board/maitretarot/maitretarot-0.1.98-r2.ebuild

   1 # Copyright 1999-2021 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools
   7
   8 DESCRIPTION="Server for the french tarot game maitretarot"
   9 HOMEPAGE="http://www.nongnu.org/maitretarot/"
  10 SRC_URI="https://savannah.nongnu.org/download/maitretarot/${PN}.pkg/${PV}/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15
  16 BDEPEND="virtual/pkgconfig"
  17 DEPEND="dev-libs/glib:2
  18         dev-libs/libxml2
  19         dev-games/libmaitretarot"
  20 RDEPEND="${DEPEND}"
  21
  22 PATCHES=(
  23         "${FILESDIR}"/${P}-format.patch
  24 )
  25
  26 src_prepare() {
  27         default
  28
  29         mv configure.{in,ac} || die
  30
  31         # Remove bundled macros (avoid patching same file multiple times)
  32         rm -rf m4/{libmaitretarot,libmt_client}.m4 || die
  33
  34         # Ensure we generate auto* with the fixed macros in tree
  35         # (not bundled)
  36         # bug #739142
  37         eautoreconf
  38 }
  39
  40 src_configure() {
  41         econf --with-default-config-file="/etc/maitretarotrc.xml"
  42 }