media-libs/cal3d/cal3d-0.11.0-r1.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit autotools
   7
   8 DESCRIPTION="Cal3D is a skeletal based character animation library"
   9 HOMEPAGE="https://mp3butcher.github.io/Cal3D/"
  10 SRC_URI="https://mp3butcher.github.io/Cal3D/sources/${P}.tar.gz"
  11
  12 LICENSE="LGPL-2.1"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc x86"
  15 IUSE="16bit-indices debug doc"
  16
  17 BDEPEND="
  18         doc? (
  19                 app-text/doxygen
  20                 app-text/docbook-sgml-utils
  21         )"
  22
  23 PATCHES=(
  24         "${FILESDIR}"/${P}-gcc43.patch
  25         "${FILESDIR}"/${P}-tests.patch
  26         "${FILESDIR}"/${P}-verbose.patch
  27         "${FILESDIR}"/${P}-gcc6.patch
  28         "${FILESDIR}"/${P}-docbook2html.patch
  29 )
  30
  31 src_prepare() {
  32         default
  33         eautoreconf
  34 }
  35
  36 src_configure() {
  37         econf \
  38                 $(use_enable debug) \
  39                 $(use_enable 16bit-indices)
  40 }
  41
  42 src_compile() {
  43         emake
  44
  45         if use doc; then
  46                 cd docs || die
  47                 emake doc-api
  48                 emake doc-guide
  49                 mkdir -p html/{guide,api} || die
  50                 mv *.{html,gif} html/guide/ || die
  51                 mv api/html/* html/api/ || die
  52                 HTML_DOCS=( docs/html/api docs/html/guide )
  53         fi
  54 }