media-libs/libmediainfo/libmediainfo-24.11.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 # These must be bumped together:
   7 # - media-libs/libzen (if a release is available)
   8 # - media-libs/libmediainfo
   9 # - media-video/mediainfo
  10
  11 MY_PN="MediaInfo"
  12 inherit autotools edos2unix flag-o-matic
  13
  14 DESCRIPTION="MediaInfo libraries"
  15 HOMEPAGE="https://mediaarea.net/en/MediaInfo https://github.com/MediaArea/MediaInfoLib"
  16 SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
  17 S="${WORKDIR}"/${MY_PN}Lib/Project/GNU/Library
  18
  19 LICENSE="BSD-2"
  20 SLOT="0"
  21 KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
  22 IUSE="curl doc mms"
  23
  24 # Tests try to fetch data from online sources
  25 RESTRICT="test"
  26
  27 # The libzen dep usually needs to be bumped for each release!
  28 RDEPEND="
  29         dev-libs/tinyxml2:=
  30         >=media-libs/libzen-0.4.41
  31         sys-libs/zlib
  32         curl? ( net-misc/curl )
  33         mms? ( >=media-libs/libmms-0.6.1 )
  34 "
  35 DEPEND="${RDEPEND}"
  36 BDEPEND="
  37         virtual/pkgconfig
  38         doc? ( app-text/doxygen )
  39 "
  40
  41 src_prepare() {
  42         default
  43
  44         sed -i 's:-O2::' configure.ac || die
  45
  46         append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
  47
  48         eautoreconf
  49 }
  50
  51 src_configure() {
  52         econf \
  53                 --enable-shared \
  54                 --disable-static \
  55                 --disable-staticlibs \
  56                 --with-libtinyxml2 \
  57                 $(use_with curl libcurl) \
  58                 $(use_with mms libmms)
  59 }
  60
  61 src_compile() {
  62         default
  63
  64         if use doc; then
  65                 cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc || die
  66                 doxygen Doxyfile || die
  67         fi
  68 }
  69
  70 src_install() {
  71         if use doc; then
  72                 local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
  73         fi
  74
  75         default
  76
  77         edos2unix ${PN}.pc #414545
  78         insinto /usr/$(get_libdir)/pkgconfig
  79         doins ${PN}.pc
  80
  81         for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
  82                 insinto /usr/include/${MY_PN}/${x}
  83                 doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
  84         done
  85
  86         insinto /usr/include/${MY_PN}DLL
  87         doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
  88
  89         dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
  90
  91         find "${ED}" -name '*.la' -delete || die
  92 }