media-libs/libopenmpt/libopenmpt-0.7.10.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit multilib-minimal
   7
   8 MY_P="libopenmpt-${PV}+release.autotools"
   9 DESCRIPTION="Library to decode tracked music files (modules)"
  10 HOMEPAGE="https://lib.openmpt.org/libopenmpt/"
  11 SRC_URI="https://lib.openmpt.org/files/libopenmpt/src/${MY_P}.tar.gz"
  12 S="${WORKDIR}/${MY_P}"
  13 LICENSE="BSD"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
  16 IUSE="examples mp3 ogg static-libs test vorbis zlib"
  17 RESTRICT="!test? ( test )"
  18
  19 RDEPEND="
  20         mp3? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
  21         ogg? ( media-libs/libogg[${MULTILIB_USEDEP}] )
  22         vorbis? ( media-libs/libvorbis[${MULTILIB_USEDEP}] )
  23         zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
  24 "
  25
  26 DEPEND="${RDEPEND}"
  27 BDEPEND="virtual/pkgconfig"
  28
  29 ECONF_SOURCE="${S}"
  30
  31 multilib_src_configure() {
  32         # A lot of these optional dependencies relate to openmpt123, which
  33         # we package separately, so we disable them here.
  34         econf \
  35                 $(use_enable static-libs static) \
  36                 --disable-openmpt123 \
  37                 --disable-examples \
  38                 $(use_enable test tests) \
  39                 --disable-doxygen-doc \
  40                 $(use_with zlib) \
  41                 $(use_with mp3 mpg123) \
  42                 $(use_with ogg) \
  43                 $(use_with vorbis) \
  44                 $(use_with vorbis vorbisfile) \
  45                 --without-pulseaudio \
  46                 --without-portaudio \
  47                 --without-portaudiocpp \
  48                 --without-sdl2 \
  49                 --without-sndfile \
  50                 --without-flac
  51 }
  52
  53 multilib_src_install_all() {
  54         rm -f \
  55                 "${ED}"/usr/*/*.la \
  56                 "${ED}"/usr/share/doc/${P}/LICENSE || die
  57
  58         if ! use examples; then
  59                 rm -r "${ED}"/usr/share/doc/${P}/examples || die
  60         fi
  61 }