media-libs/libvisio/libvisio-0.1.8.ebuild

   1 # Copyright 1999-2025 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit flag-o-matic
   7
   8 if [[ ${PV} == *9999* ]]; then
   9         EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libvisio.git"
  10         inherit autotools git-r3
  11 else
  12         SRC_URI="https://dev-www.libreoffice.org/src/libvisio/${P}.tar.xz"
  13         KEYWORDS="amd64 ~arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~sparc x86"
  14 fi
  15
  16 DESCRIPTION="Library parsing the file format of MS Visio documents"
  17 HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libvisio"
  18
  19 LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
  20 SLOT="0"
  21 IUSE="doc test tools"
  22 RESTRICT="!test? ( test )"
  23
  24 RDEPEND="
  25         dev-libs/icu:=
  26         dev-libs/librevenge
  27         dev-libs/libxml2
  28 "
  29 DEPEND="${RDEPEND}
  30         dev-libs/boost
  31         dev-util/gperf
  32         dev-build/libtool
  33         test? ( dev-util/cppunit )
  34 "
  35 BDEPEND="
  36         dev-lang/perl
  37         virtual/pkgconfig
  38         doc? ( app-text/doxygen )
  39 "
  40
  41 src_prepare() {
  42         default
  43         [[ -d m4 ]] || mkdir "m4" || die
  44         [[ ${PV} == *9999* ]] && eautoreconf
  45 }
  46
  47 src_configure() {
  48         # bug 619688, 932496
  49         append-cxxflags -std=c++17
  50
  51         local myeconfargs=(
  52                 $(use_with doc docs)
  53                 $(use_enable test tests)
  54                 $(use_enable tools)
  55         )
  56         econf "${myeconfargs[@]}"
  57 }
  58
  59 src_install() {
  60         default
  61         find "${ED}" -name '*.la' -delete || die
  62 }