media-libs/plib/plib-1.8.5-r4.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit autotools flag-o-matic
   7
   8 DESCRIPTION="Multimedia library used by many games"
   9 HOMEPAGE="https://plib.sourceforge.net/"
  10 SRC_URI="https://plib.sourceforge.net/dist/${P}.tar.gz"
  11
  12 LICENSE="LGPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 ~hppa ppc sparc x86"
  15
  16 DEPEND="virtual/opengl"
  17 RDEPEND="${DEPEND}"
  18
  19 PATCHES=(
  20         "${FILESDIR}"/${P}-shared-libs.patch
  21         "${FILESDIR}"/${P}-X11-r1.patch
  22         "${FILESDIR}"/${P}-CVE-2011-4620.patch
  23         "${FILESDIR}"/${P}-CVE-2012-4552.patch
  24 )
  25
  26 src_prepare() {
  27         default
  28
  29         eautoreconf
  30 }
  31
  32 src_configure() {
  33         append-cxxflags -std=c++03
  34
  35         # violates strict aliasing rules and is LTO-unsafe: https://bugs.gentoo.org/860048
  36         # Per upstream in 2021, "PLIB has been obsolete and unmaintained for at LEAST 15 years!!"
  37         # so this is getting fixed exactly never and getting worse.
  38         append-cxxflags -fno-strict-aliasing
  39         filter-lto
  40
  41         local myconf=(
  42                 --enable-shared
  43         )
  44
  45         econf "${myconf[@]}"
  46 }
  47
  48 src_install() {
  49         default
  50
  51         dodoc KNOWN_BUGS TODO* NOTICE
  52
  53         find "${ED}" -name '*.la' -delete || die
  54 }