media-libs/svt-av1/svt-av1-1.4.1.ebuild

   1 # Copyright 2020-2023 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit cmake-multilib flag-o-matic
   7
   8 DESCRIPTION="Scalable Video Technology for AV1 (SVT-AV1 Encoder and Decoder)"
   9 HOMEPAGE="https://gitlab.com/AOMediaCodec/SVT-AV1"
  10
  11 if [[ ${PV} = 9999 ]]; then
  12         inherit git-r3
  13         EGIT_REPO_URI="https://gitlab.com/AOMediaCodec/SVT-AV1.git"
  14 else
  15         SRC_URI="https://gitlab.com/AOMediaCodec/SVT-AV1/-/archive/v${PV}/SVT-AV1-v${PV}.tar.bz2"
  16         KEYWORDS="amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv sparc x86"
  17         S="${WORKDIR}/SVT-AV1-v${PV}"
  18 fi
  19
  20 # Also see "Alliance for Open Media Patent License 1.0"
  21 LICENSE="BSD-2 Apache-2.0 BSD ISC LGPL-2.1+ MIT"
  22 SLOT="0"
  23
  24 BDEPEND="amd64? ( dev-lang/yasm )"
  25
  26 multilib_src_configure() {
  27         append-ldflags -Wl,-z,noexecstack
  28
  29         local mycmakeargs=(
  30                 # Tests require linking against https://github.com/Cidana-Developers/aom/tree/av1-normative ?
  31                 # undefined reference to `ifd_inspect'
  32                 # https://github.com/Cidana-Developers/aom/commit/cfc5c9e95bcb48a5a41ca7908b44df34ea1313c0
  33                 # .. and https://gitlab.com/AOMediaCodec/SVT-AV1/-/blob/master/.gitlab/workflows/linux/.gitlab-ci.yml implies it's all quite manual?
  34                 -DBUILD_TESTING=OFF
  35                 -DCMAKE_OUTPUT_DIRECTORY="${BUILD_DIR}"
  36         )
  37
  38         [[ ${ABI} != amd64 ]] && mycmakeargs+=( -DCOMPILE_C_ONLY=ON )
  39
  40         cmake_src_configure
  41 }