media-libs/vamp-plugin-sdk/vamp-plugin-sdk-2.10.ebuild

   1 # Copyright 1999-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs multilib-minimal
   7
   8 DESCRIPTION="Audio processing system for plugins to extract information from audio data"
   9 HOMEPAGE="https://www.vamp-plugins.org"
  10 SRC_URI="https://github.com/c4dm/${PN}/archive/${PN}-v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86"
  15 IUSE="doc"
  16
  17 RDEPEND="media-libs/libsndfile:0=[${MULTILIB_USEDEP}]"
  18 DEPEND="${RDEPEND}"
  19 BDEPEND="
  20         virtual/pkgconfig
  21         doc? ( app-text/doxygen )
  22 "
  23
  24 S="${WORKDIR}/${PN}-${PN}-v${PV}"
  25
  26 src_prepare() {
  27         default
  28         multilib_copy_sources
  29 }
  30
  31 multilib_src_configure() {
  32         MAKEOPTS+=" -j1" # bug #943866
  33
  34         # multilib for default search paths
  35         sed -i -e "s:/usr/lib/vamp:${EPREFIX}/usr/$(get_libdir)/vamp:" \
  36                 src/vamp-hostsdk/PluginHostAdapter.cpp || die
  37         econf
  38 }
  39
  40 multilib_src_compile() {
  41         emake \
  42                 AR="$(tc-getAR)" \
  43                 RANLIB="$(tc-getRANLIB)"
  44
  45         if multilib_is_native_abi && use doc; then
  46                 cd build || die
  47                 doxygen || die "creating doxygen doc failed"
  48                 HTML_DOCS=( "${BUILD_DIR}"/build/doc/html/. )
  49         fi
  50 }
  51
  52 multilib_src_install() {
  53         emake \
  54                 DESTDIR="${D}" \
  55                 INSTALL_SDK_LIBS="${EPREFIX}"/usr/$(get_libdir) \
  56                 INSTALL_PKGCONFIG="${EPREFIX}"/usr/$(get_libdir)/pkgconfig \
  57                 INSTALL_PLUGINS="${EPREFIX}"/usr/$(get_libdir)/vamp \
  58                 install
  59
  60         # fix .pc files
  61         sed -Ei "s/lib$/$(get_libdir)/g" "${D}"/usr/$(get_libdir)/pkgconfig/*.pc
  62 }
  63
  64 multilib_src_install_all() {
  65         einstalldocs
  66
  67         # don't want static archives, #474768
  68         find "${D}" -name '*.a' -delete || die
  69 }
  70
  71 pkg_postinst() {
  72         elog
  73         elog "You might also want to install some Vamp plugins."
  74         elog "See media-plugins/vamp-*"
  75         elog
  76 }