m4/fp_cpp_cmd_with_args.m4

   1 # FP_CPP_CMD_WITH_ARGS()
   2 # ----------------------
   3 # sets CPP command and its arguments
   4 #
   5 # $1 = CC (unmodified)
   6 # $2 = the variable to set to CPP command
   7 # $3 = the variable to set to CPP command arguments
   8 #
   9 # The reason for using the non-standard --with-cpp and --with-cpp-flags instead
  10 # of the standard CPP and CPPFLAGS is that autoconf sets CPP to "$CC -E",
  11 # whereas we expect the CPP command to be configured as a standalone executable
  12 # rather than a command. These are symmetrical with --with-hs-cpp and
  13 # --with-hs-cpp-flags.
  14 AC_DEFUN([FP_CPP_CMD_WITH_ARGS],[
  15
  16 AC_ARG_WITH(cpp,
  17 [AS_HELP_STRING([--with-cpp=ARG],
  18       [Path to the (C) preprocessor [default=autodetect].
  19        If you set --with-cpp=CC, ensure -E is included in --with-cpp-flags])],
  20 [
  21     if test "$HostOS" = "mingw32"
  22     then
  23         AC_MSG_WARN([Request to use $withval will be ignored])
  24     else
  25         CPP_CMD="$withval"
  26     fi
  27 ],
  28 [
  29     # We can't use the CPP var here, since CPP_CMD is expected to be a single
  30     # command (no flags), and autoconf defines CPP as "/usr/bin/gcc -E".
  31     # So we use CC with -E by default
  32     CPP_CMD="$1"
  33     CPP_ARGS="-E"
  34 ]
  35 )
  36
  37 AC_ARG_WITH(cpp-flags,
  38 [AS_HELP_STRING([--with-cpp-flags=ARG],
  39   [Flags to the (C) preprocessor [default=autodetect]])],
  40 [
  41   if test "$HostOS" = "mingw32"
  42   then
  43       AC_MSG_WARN([Request to use $withval will be ignored])
  44   else
  45       # Use whatever flags were manually set, ignoring previously configured
  46       # flags; and add CPP_ARGS (which will be -E if CPP_CMD was not specified)
  47       CPP_ARGS="$CPP_ARGS $withval"
  48       USER_CPP_ARGS="$withval"
  49   fi
  50 ],
  51 [
  52   # Augment CPP_ARGS with whatever flags were previously configured and passed
  53   # as an argument.
  54   CPP_ARGS="$$3 $CPP_ARGS"
  55 ])
  56
  57 $2="$CPP_CMD"
  58 $3="$CPP_ARGS"
  59
  60 # Clear CPP_CMD and CPP_ARGS
  61 unset CPP_CMD
  62 unset CPP_ARGS
  63
  64 ])
  65