stylesheets/getsortkey.xsl

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3     This file is part of the gimp-help-2 project and is
   4     (C) The GIMP Documentation Team.
   5     You may use this file in accordance to the GNU General Public License
   6     Version 2 which is available from http://www.gnu.org.
   7 -->
   8
   9 <!--
  10     This file provides the template "gimp-help.help-id.sort"
  11     which generates a key for sorting <help-item>s.
  12 -->
  13
  14 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  15                 xmlns:gimp-help="http://www.gimp.org/docs"
  16                 exclude-result-prefixes="gimp-help"
  17                 version="1.0">
  18
  19   <!-- Testing & debugging -->
  20   <xsl:param name="help-id.sort.debug" select="0"/>
  21
  22   <!-- Top-level section numbers -->
  23   <xsl:variable name="division.id">66</xsl:variable>
  24   <xsl:variable name="appendix.id">77</xsl:variable>
  25   <xsl:variable name="biblio.id">88</xsl:variable>
  26   <xsl:variable name="index.id">99</xsl:variable>
  27
  28
  29   <!-- ============================================================= -->
  30   <xsl:template name="gimp-help.help-id.sort">
  31   <!-- ============================================================= -->
  32     <xsl:if test="$help-id.sort.debug>0">
  33       <xsl:message>
  34         <xsl:text>Debug getsortkey: processing </xsl:text>
  35         <xsl:value-of select="local-name()"/>
  36         <xsl:text> (element=</xsl:text>
  37         <xsl:value-of select="@element"/>
  38         <xsl:text>, targetptr=</xsl:text>
  39         <xsl:value-of select="@targetptr"/>
  40         <xsl:text>, number=</xsl:text>
  41         <xsl:value-of select="@number"/>
  42         <xsl:text>)</xsl:text>
  43       </xsl:message>
  44     </xsl:if>
  45     <xsl:choose>
  46       <xsl:when test="@number != ''">
  47         <!-- case 1: element has attribute "number" -->
  48         <xsl:choose>
  49           <!-- case 1a: simple or dotted number "1", "1.1", etc. (DocBook <sect*>) -->
  50           <xsl:when test="string(number(substring(@number,1,1))) != 'NaN'">
  51             <xsl:value-of select="@number"/>
  52           </xsl:when>
  53           <!-- case 1b: roman number "I", "II", etc. (DocBook <part>) -->
  54           <xsl:when test="starts-with(@number,'I') or
  55                           starts-with(@number,'V')">
  56             <xsl:variable name="roman">
  57               <xsl:call-template name="number.roman.decode">
  58                 <xsl:with-param name="number" select="@number"/>
  59               </xsl:call-template>
  60             </xsl:variable>
  61             <xsl:value-of select="concat($division.id,'.',$roman)"/>
  62           </xsl:when>
  63           <!-- case 1c: number "A", "B", "C", etc.(DocBook <appendix>) -->
  64           <xsl:when test="string-length(@number) = 1">
  65             <xsl:choose>
  66               <xsl:when test="number(translate(@number,'ABCDEF','123456'))">
  67                 <xsl:value-of select="concat($appendix.id,'.',
  68                   translate(@number,'ABCDEF','123456'))"/>
  69               </xsl:when>
  70               <xsl:otherwise>
  71                 <xsl:message>
  72                   <xsl:text>Warning: invalid number: </xsl:text>
  73                   <xsl:value-of select="@number"/>
  74                 </xsl:message>
  75               </xsl:otherwise>
  76             </xsl:choose>
  77           </xsl:when>
  78           <!-- Error -->
  79           <xsl:otherwise>
  80             <xsl:message>
  81               <xsl:text>Warning: invalid number: </xsl:text>
  82               <xsl:value-of select="@number"/>
  83             </xsl:message>
  84           </xsl:otherwise>
  85         </xsl:choose>
  86       </xsl:when>
  87       <xsl:otherwise> <!-- @number = '' -->
  88         <xsl:choose>
  89           <!-- Special case: Bibliography -->
  90           <xsl:when test="@targetptr = 'bibliography'">
  91             <xsl:value-of select="$biblio.id"/>
  92           </xsl:when>
  93           <!-- Special case: Index -->
  94           <xsl:when test="@targetptr = 'gimp-help-index'">
  95             <xsl:value-of select="$index.id"/>
  96           </xsl:when>
  97           <xsl:when test="not(@targetptr)">
  98             <xsl:value-of select="0"/>
  99           </xsl:when>
 100           <xsl:otherwise>
 101             <xsl:variable name="sort.parent">
 102               <!--xsl:for-each select=".."-->
 103               <xsl:for-each select="parent::div|parent::obj">
 104                 <xsl:call-template name="gimp-help.help-id.sort"/>
 105               </xsl:for-each>
 106             </xsl:variable>
 107             <xsl:choose>
 108               <xsl:when test="$sort.parent!=''">
 109                 <xsl:value-of select="concat($sort.parent,'.0.',position())"/>
 110               </xsl:when>
 111               <xsl:otherwise>
 112                 <xsl:value-of select="position()"/>
 113               </xsl:otherwise>
 114             </xsl:choose>
 115           </xsl:otherwise>
 116         </xsl:choose> <!--@targetptr-->
 117       </xsl:otherwise>
 118     </xsl:choose> <!--@number-->
 119   </xsl:template>
 120
 121   <!-- ============================================================= -->
 122   <xsl:template name="number.roman.decode">
 123   <!-- ============================================================= -->
 124     <xsl:param name="number" select="''"/>
 125     <xsl:variable name="head">
 126       <xsl:choose>
 127         <xsl:when test="$number = ''">0</xsl:when>
 128         <xsl:when test="starts-with($number,'IV')">4</xsl:when>
 129         <xsl:when test="starts-with($number,'I')">1</xsl:when>
 130         <xsl:when test="starts-with($number,'V')">5</xsl:when>
 131         <xsl:otherwise>0</xsl:otherwise>
 132       </xsl:choose>
 133     </xsl:variable>
 134     <xsl:variable name="tail">
 135       <xsl:choose>
 136         <xsl:when test="$number = ''"></xsl:when>
 137         <xsl:when test="starts-with($number,'IV')">
 138           <xsl:value-of select="substring($number,3)"/>
 139         </xsl:when>
 140         <xsl:otherwise>
 141           <xsl:value-of select="substring($number,2)"/>
 142         </xsl:otherwise>
 143       </xsl:choose>
 144     </xsl:variable>
 145     <xsl:choose>
 146       <xsl:when test="$tail != '' and $head > 0">
 147         <xsl:variable name="tail.decoded">
 148           <xsl:call-template name="number.roman.decode">
 149             <xsl:with-param name="number" select="$tail"/>
 150           </xsl:call-template>
 151         </xsl:variable>
 152         <xsl:value-of select="$head + $tail.decoded"/>
 153       </xsl:when>
 154       <xsl:otherwise>
 155         <xsl:value-of select="number($head)"/>
 156       </xsl:otherwise>
 157     </xsl:choose>
 158   </xsl:template>
 159
 160 </xsl:stylesheet>