configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49 #
  50 # GIT_PARSE_WITH(PACKAGE)
  51 # -----------------------
  52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56 AC_DEFUN([GIT_PARSE_WITH],
  57 [PACKAGE=m4_toupper($1); \
  58 if test "$withval" = "no"; then \
  59         m4_toupper(NO_$1)=YesPlease; \
  60 elif test "$withval" = "yes"; then \
  61         m4_toupper(NO_$1)=; \
  62 else \
  63         m4_toupper(NO_$1)=; \
  64         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65 fi \
  66 ])# GIT_PARSE_WITH
  67
  68
  69 ## Site configuration related to programs (before tests)
  70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  71 #
  72 # Define SHELL_PATH to provide path to shell.
  73 GIT_ARG_SET_PATH(shell)
  74 #
  75 # Define PERL_PATH to provide path to Perl.
  76 GIT_ARG_SET_PATH(perl)
  77 #
  78 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
  79 # Define PYTHON_PATH to provide path to Python.
  80 AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
  81 AS_HELP_STRING([--without-python], [don't use python scripts])],
  82  [if test "$withval" = "no"; then \
  83     NO_PYTHON=YesPlease; \
  84   elif test "$withval" = "yes"; then \
  85     NO_PYTHON=; \
  86   else \
  87     NO_PYTHON=; \
  88     PYTHON_PATH=$withval; \
  89   fi; \
  90  ])
  91 AC_SUBST(NO_PYTHON)
  92 AC_SUBST(PYTHON_PATH)
  93
  94
  95 ## Checks for programs.
  96 AC_MSG_NOTICE([CHECKS for programs])
  97 #
  98 AC_PROG_CC([cc gcc])
  99 if test -n "$GCC"; then
 100         PIC_FLAG="-fPIC"
 101 else
 102         AC_CHECK_DECL(__SUNPRO_C, [CFLAGS="$CFLAGS -xO3"; PIC_FLAG="-KPIC"])
 103 fi
 104 AC_SUBST(PIC_FLAG)
 105
 106 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 107 AC_CHECK_TOOL(AR, ar, :)
 108 AC_CHECK_PROGS(TAR, [gtar tar])
 109 #
 110 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 111 # Define PYTHON_PATH to provide path to Python.
 112 if test -z "$NO_PYTHON"; then
 113         if test -z "$PYTHON_PATH"; then
 114                 AC_PATH_PROGS(PYTHON_PATH, [python python2.4 python2.3 python2])
 115         fi
 116         if test -n "$PYTHON_PATH"; then
 117                 GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
 118                 NO_PYTHON=""
 119         fi
 120 fi
 121
 122
 123 ## Checks for libraries.
 124 AC_MSG_NOTICE([CHECKS for libraries])
 125 #
 126 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 127 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 128 AC_CHECK_LIB([crypto], [SHA1_Init],
 129 [NEEDS_SSL_WITH_CRYPTO=],
 130 [AC_CHECK_LIB([ssl], [SHA1_Init],
 131  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 132   NEEDS_SSL_WITH_CRYPTO=],
 133  [NO_OPENSSL=YesPlease])])
 134 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 135 AC_SUBST(NO_OPENSSL)
 136 #
 137 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 138 # git-http-push are not built, and you cannot use http:// and https://
 139 # transports.
 140 AC_CHECK_LIB([curl], [curl_global_init],
 141 [NO_CURL=],
 142 [NO_CURL=YesPlease])
 143 AC_SUBST(NO_CURL)
 144 #
 145 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 146 # not built, and you cannot push using http:// and https:// transports.
 147 AC_CHECK_LIB([expat], [XML_ParserCreate],
 148 [NO_EXPAT=],
 149 [NO_EXPAT=YesPlease])
 150 AC_SUBST(NO_EXPAT)
 151 #
 152 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 153 AC_CHECK_LIB([c], [iconv],
 154 [NEEDS_LIBICONV=],
 155 [NEEDS_LIBICONV=YesPlease])
 156 AC_SUBST(NEEDS_LIBICONV)
 157 #
 158 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 159 # Patrick Mauritz).
 160 AC_CHECK_LIB([c], [socket],
 161 [NEEDS_SOCKET=],
 162 [NEEDS_SOCKET=YesPlease])
 163 AC_SUBST(NEEDS_SOCKET)
 164 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 165
 166
 167 ## Checks for header files.
 168
 169
 170 ## Checks for typedefs, structures, and compiler characteristics.
 171 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 172 #
 173 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 174 AC_CHECK_MEMBER(struct dirent.d_ino,
 175 [NO_D_INO_IN_DIRENT=],
 176 [NO_D_INO_IN_DIRENT=YesPlease],
 177 [#include <dirent.h>])
 178 AC_SUBST(NO_D_INO_IN_DIRENT)
 179 #
 180 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 181 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 182 AC_CHECK_MEMBER(struct dirent.d_type,
 183 [NO_D_TYPE_IN_DIRENT=],
 184 [NO_D_TYPE_IN_DIRENT=YesPlease],
 185 [#include <dirent.h>])
 186 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 187 #
 188 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 189 # sockaddr_storage.
 190 AC_CHECK_TYPE(struct sockaddr_storage,
 191 [NO_SOCKADDR_STORAGE=],
 192 [NO_SOCKADDR_STORAGE=YesPlease],[
 193 #include <sys/types.h>
 194 #include <sys/socket.h>
 195 ])
 196 AC_SUBST(NO_SOCKADDR_STORAGE)
 197 #
 198 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 199 AC_CHECK_TYPE([struct addrinfo],[
 200  AC_CHECK_FUNC([getaddrinfo],
 201   [NO_IPV6=],
 202   [NO_IPV6=YesPlease])
 203 ],[NO_IPV6=YesPlease],[
 204 #include <sys/types.h>
 205 #include <sys/socket.h>
 206 #include <netdb.h>
 207 ])
 208 AC_SUBST(NO_IPV6)
 209 #
 210 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 211 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 212 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 213 # some C compilers supported these specifiers prior to C99 as an extension.
 214 AC_CACHE_CHECK(whether formatted IO functions support C99 size specifiers,
 215  ac_cv_c_c99_format,
 216 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 217 AC_RUN_IFELSE(
 218         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 219                 [[char buf[64];
 220                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 221                   exit(1);
 222                 else if (strcmp(buf, "12345"))
 223                   exit(2);]])],
 224         [ac_cv_c_c99_format=yes],
 225         [ac_cv_c_c99_format=no])
 226 ])
 227 if test $ac_cv_c_c99_format = no; then
 228         NO_C99_FORMAT=YesPlease
 229 else
 230         NO_C99_FORMAT=
 231 fi
 232 AC_SUBST(NO_C99_FORMAT)
 233
 234
 235 ## Checks for library functions.
 236 ## (in default C library and libraries checked by AC_CHECK_LIB)
 237 AC_MSG_NOTICE([CHECKS for library functions])
 238 #
 239 # Define NO_STRCASESTR if you don't have strcasestr.
 240 AC_CHECK_FUNC(strcasestr,
 241 [NO_STRCASESTR=],
 242 [NO_STRCASESTR=YesPlease])
 243 AC_SUBST(NO_STRCASESTR)
 244 #
 245 # Define NO_STRLCPY if you don't have strlcpy.
 246 AC_CHECK_FUNC(strlcpy,
 247 [NO_STRLCPY=],
 248 [NO_STRLCPY=YesPlease])
 249 AC_SUBST(NO_STRLCPY)
 250 #
 251 # Define NO_SETENV if you don't have setenv in the C library.
 252 AC_CHECK_FUNC(setenv,
 253 [NO_SETENV=],
 254 [NO_SETENV=YesPlease])
 255 AC_SUBST(NO_SETENV)
 256 #
 257 # Define NO_MMAP if you want to avoid mmap.
 258 #
 259 # Define NO_ICONV if your libc does not properly support iconv.
 260
 261
 262 ## Other checks.
 263 # Define USE_PIC if you need the main git objects to be built with -fPIC
 264 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 265 #
 266 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 267 # Enable it on Windows.  By default, symrefs are still used.
 268 #
 269 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 270 #
 271 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 272 # a missing newline at the end of the file.
 273
 274
 275 ## Site configuration (override autodetection)
 276 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 277 AC_MSG_NOTICE([CHECKS for site configuration])
 278 #
 279 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 280 # tests.  These tests take up a significant amount of the total test time
 281 # but are not needed unless you plan to talk to SVN repos.
 282 #
 283 # Define MOZILLA_SHA1 environment variable when running make to make use of
 284 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 285 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 286 # choice) has very fast version optimized for i586.
 287 #
 288 # Define PPC_SHA1 environment variable when running make to make use of
 289 # a bundled SHA1 routine optimized for PowerPC.
 290 #
 291 # Define ARM_SHA1 environment variable when running make to make use of
 292 # a bundled SHA1 routine optimized for ARM.
 293 #
 294 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 295 # This also implies MOZILLA_SHA1.
 296 #
 297 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 298 # /foo/bar/include and /foo/bar/lib directories.
 299 AC_ARG_WITH(openssl,
 300 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 301 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 302 GIT_PARSE_WITH(openssl))
 303 #
 304 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 305 # git-http-push are not built, and you cannot use http:// and https://
 306 # transports.
 307 #
 308 # Define CURLDIR=/foo/bar if your curl header and library files are in
 309 # /foo/bar/include and /foo/bar/lib directories.
 310 AC_ARG_WITH(curl,
 311 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 312 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 313 GIT_PARSE_WITH(curl))
 314 #
 315 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 316 # not built, and you cannot push using http:// and https:// transports.
 317 #
 318 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 319 # /foo/bar/include and /foo/bar/lib directories.
 320 AC_ARG_WITH(expat,
 321 AS_HELP_STRING([--with-expat],
 322 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 323 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 324 GIT_PARSE_WITH(expat))
 325 #
 326 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 327 # installed in /sw, but don't want GIT to link against any libraries
 328 # installed there.  If defined you may specify your own (or Fink's)
 329 # include directories and library directories by defining CFLAGS
 330 # and LDFLAGS appropriately.
 331 #
 332 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 333 # have DarwinPorts installed in /opt/local, but don't want GIT to
 334 # link against any libraries installed there.  If defined you may
 335 # specify your own (or DarwinPort's) include directories and
 336 # library directories by defining CFLAGS and LDFLAGS appropriately.
 337 #
 338 # Define NO_MMAP if you want to avoid mmap.
 339
 340 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 341 #
 342 # Define COLLISION_CHECK below if you believe that SHA1's
 343 # 1461501637330902918203684832716283019655932542976 hashes do not give you
 344 # sufficient guarantee that no collisions between objects will ever happen.
 345 #
 346 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 347 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 348 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 349 # randomly break unless your underlying filesystem supports those sub-second
 350 # times (my ext3 doesn't).
 351 #
 352 # Define USE_STDEV below if you want git to care about the underlying device
 353 # change being considered an inode change from the update-cache perspective.
 354
 355
 356 ## Output files
 357 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 358 AC_OUTPUT
 359
 360
 361 ## Cleanup
 362 rm -f "${config_append}"