?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
Make run_diff_index() use unpack_trees(), not read_tree()
[git/git-p4.git] / git-svn.perl
blob9f2b587b2534e29054b5399a745d56e2ed5ea216
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
45
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
58
59 my ($SVN);
60
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose);
69 $Git::SVN::_follow_parent = 1;
70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
71 'config-dir=s' => \$Git::SVN::Ra::config_dir,
72 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
74 'authors-file|A=s' => \$_authors,
75 'repack:i' => \$Git::SVN::_repack,
76 'noMetadata' => \$Git::SVN::_no_metadata,
77 'useSvmProps' => \$Git::SVN::_use_svm_props,
78 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
79 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
80 'no-checkout' => \$_no_checkout,
81 'quiet|q' => \$_q,
82 'repack-flags|repack-args|repack-opts=s' =>
83 \$Git::SVN::_repack_flags,
84 'use-log-author' => \$Git::SVN::_use_log_author,
85 %remote_opts );
86
87 my ($_trunk, $_tags, $_branches, $_stdlayout);
88 my %icv;
89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
90 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
91 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
92 'stdlayout|s' => \$_stdlayout,
93 'minimize-url|m' => \$Git::SVN::_minimize_url,
94 'no-metadata' => sub { $icv{noMetadata} = 1 },
95 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
96 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
97 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
98 %remote_opts );
99 my %cmt_opts = ( 'edit|e' => \$_edit,
100 'rmdir' => \$SVN::Git::Editor::_rmdir,
101 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
102 'l=i' => \$SVN::Git::Editor::_rename_limit,
103 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
104 );
105
106 my %cmd = (
107 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
108 { 'revision|r=s' => \$_revision,
109 'fetch-all|all' => \$_fetch_all,
110 %fc_opts } ],
111 clone => [ \&cmd_clone, "Initialize and fetch revisions",
112 { 'revision|r=s' => \$_revision,
113 %fc_opts, %init_opts } ],
114 init => [ \&cmd_init, "Initialize a repo for tracking" .
115 " (requires URL argument)",
116 \%init_opts ],
117 'multi-init' => [ \&cmd_multi_init,
118 "Deprecated alias for ".
119 "'$0 init -T<trunk> -b<branches> -t<tags>'",
120 \%init_opts ],
121 dcommit => [ \&cmd_dcommit,
122 'Commit several diffs to merge with upstream',
123 { 'merge|m|M' => \$_merge,
124 'strategy|s=s' => \$_strategy,
125 'verbose|v' => \$_verbose,
126 'dry-run|n' => \$_dry_run,
127 'fetch-all|all' => \$_fetch_all,
128 'no-rebase' => \$_no_rebase,
129 %cmt_opts, %fc_opts } ],
130 'set-tree' => [ \&cmd_set_tree,
131 "Set an SVN repository to a git tree-ish",
132 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
133 'create-ignore' => [ \&cmd_create_ignore,
134 'Create a .gitignore per svn:ignore',
135 { 'revision|r=i' => \$_revision
136 } ],
137 'propget' => [ \&cmd_propget,
138 'Print the value of a property on a file or directory',
139 { 'revision|r=i' => \$_revision } ],
140 'proplist' => [ \&cmd_proplist,
141 'List all properties of a file or directory',
142 { 'revision|r=i' => \$_revision } ],
143 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
144 { 'revision|r=i' => \$_revision
145 } ],
146 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
147 { 'revision|r=i' => \$_revision
148 } ],
149 'multi-fetch' => [ \&cmd_multi_fetch,
150 "Deprecated alias for $0 fetch --all",
151 { 'revision|r=s' => \$_revision, %fc_opts } ],
152 'migrate' => [ sub { },
153 # no-op, we automatically run this anyways,
154 'Migrate configuration/metadata/layout from
155 previous versions of git-svn',
156 { 'minimize' => \$Git::SVN::Migration::_minimize,
157 %remote_opts } ],
158 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
159 { 'limit=i' => \$Git::SVN::Log::limit,
160 'revision|r=s' => \$_revision,
161 'verbose|v' => \$Git::SVN::Log::verbose,
162 'incremental' => \$Git::SVN::Log::incremental,
163 'oneline' => \$Git::SVN::Log::oneline,
164 'show-commit' => \$Git::SVN::Log::show_commit,
165 'non-recursive' => \$Git::SVN::Log::non_recursive,
166 'authors-file|A=s' => \$_authors,
167 'color' => \$Git::SVN::Log::color,
168 'pager=s' => \$Git::SVN::Log::pager
169 } ],
170 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
171 {} ],
172 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
173 { 'merge|m|M' => \$_merge,
174 'verbose|v' => \$_verbose,
175 'strategy|s=s' => \$_strategy,
176 'local|l' => \$_local,
177 'fetch-all|all' => \$_fetch_all,
178 %fc_opts } ],
179 'commit-diff' => [ \&cmd_commit_diff,
180 'Commit a diff between two trees',
181 { 'message|m=s' => \$_message,
182 'file|F=s' => \$_file,
183 'revision|r=s' => \$_revision,
184 %cmt_opts } ],
185 'info' => [ \&cmd_info,
186 "Show info about the latest SVN revision
187 on the current branch",
188 { 'url' => \$_url, } ],
189 );
190
191 my $cmd;
192 for (my $i = 0; $i < @ARGV; $i++) {
193 if (defined $cmd{$ARGV[$i]}) {
194 $cmd = $ARGV[$i];
195 splice @ARGV, $i, 1;
196 last;
197 }
198 };
199
200 # make sure we're always running at the top-level working directory
201 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
202 unless (-d $ENV{GIT_DIR}) {
203 if ($git_dir_user_set) {
204 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
205 "but it is not a directory\n";
206 }
207 my $git_dir = delete $ENV{GIT_DIR};
208 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
209 unless (length $cdup) {
210 die "Already at toplevel, but $git_dir ",
211 "not found '$cdup'\n";
212 }
213 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
214 unless (-d $git_dir) {
215 die "$git_dir still not found after going to ",
216 "'$cdup'\n";
217 }
218 $ENV{GIT_DIR} = $git_dir;
219 }
220 }
221
222 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
223
224 read_repo_config(\%opts);
225 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
226 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
227 'minimize-connections' => \$Git::SVN::Migration::_minimize,
228 'id|i=s' => \$Git::SVN::default_ref_id,
229 'svn-remote|remote|R=s' => sub {
230 $Git::SVN::no_reuse_existing = 1;
231 $Git::SVN::default_repo_id = $_[1] });
232 exit 1 if (!$rv && $cmd && $cmd ne 'log');
233
234 usage(0) if $_help;
235 version() if $_version;
236 usage(1) unless defined $cmd;
237 load_authors() if $_authors;
238
239 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
240 Git::SVN::Migration::migration_check();
241 }
242 Git::SVN::init_vars();
243 eval {
244 Git::SVN::verify_remotes_sanity();
245 $cmd{$cmd}->[0]->(@ARGV);
246 };
247 fatal $@ if $@;
248 post_fetch_checkout();
249 exit 0;
250
251 ####################### primary functions ######################
252 sub usage {
253 my $exit = shift || 0;
254 my $fd = $exit ? \*STDERR : \*STDOUT;
255 print $fd <<"";
256 git-svn - bidirectional operations between a single Subversion tree and git
257 Usage: $0 <command> [options] [arguments]\n
258
259 print $fd "Available commands:\n" unless $cmd;
260
261 foreach (sort keys %cmd) {
262 next if $cmd && $cmd ne $_;
263 next if /^multi-/; # don't show deprecated commands
264 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
265 foreach (sort keys %{$cmd{$_}->[2]}) {
266 # mixed-case options are for .git/config only
267 next if /[A-Z]/ && /^[a-z]+$/i;
268 # prints out arguments as they should be passed:
269 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
270 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
271 "--$_" : "-$_" }
272 split /\|/,$_)," $x\n";
273 }
274 }
275 print $fd <<"";
276 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
277 arbitrary identifier if you're tracking multiple SVN branches/repositories in
278 one git repository and want to keep them separate. See git-svn(1) for more
279 information.
280
281 exit $exit;
282 }
283
284 sub version {
285 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
286 exit 0;
287 }
288
289 sub do_git_init_db {
290 unless (-d $ENV{GIT_DIR}) {
291 my @init_db = ('init');
292 push @init_db, "--template=$_template" if defined $_template;
293 if (defined $_shared) {
294 if ($_shared =~ /[a-z]/) {
295 push @init_db, "--shared=$_shared";
296 } else {
297 push @init_db, "--shared";
298 }
299 }
300 command_noisy(@init_db);
301 }
302 my $set;
303 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
304 foreach my $i (keys %icv) {
305 die "'$set' and '$i' cannot both be set\n" if $set;
306 next unless defined $icv{$i};
307 command_noisy('config', "$pfx.$i", $icv{$i});
308 $set = $i;
309 }
310 }
311
312 sub init_subdir {
313 my $repo_path = shift or return;
314 mkpath([$repo_path]) unless -d $repo_path;
315 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
316 $ENV{GIT_DIR} = '.git';
317 }
318
319 sub cmd_clone {
320 my ($url, $path) = @_;
321 if (!defined $path &&
322 (defined $_trunk || defined $_branches || defined $_tags ||
323 defined $_stdlayout) &&
324 $url !~ m#^[a-z\+]+://#) {
325 $path = $url;
326 }
327 $path = basename($url) if !defined $path || !length $path;
328 cmd_init($url, $path);
329 Git::SVN::fetch_all($Git::SVN::default_repo_id);
330 }
331
332 sub cmd_init {
333 if (defined $_stdlayout) {
334 $_trunk = 'trunk' if (!defined $_trunk);
335 $_tags = 'tags' if (!defined $_tags);
336 $_branches = 'branches' if (!defined $_branches);
337 }
338 if (defined $_trunk || defined $_branches || defined $_tags) {
339 return cmd_multi_init(@_);
340 }
341 my $url = shift or die "SVN repository location required ",
342 "as a command-line argument\n";
343 init_subdir(@_);
344 do_git_init_db();
345
346 Git::SVN->init($url);
347 }
348
349 sub cmd_fetch {
350 if (grep /^\d+=./, @_) {
351 die "'<rev>=<commit>' fetch arguments are ",
352 "no longer supported.\n";
353 }
354 my ($remote) = @_;
355 if (@_ > 1) {
356 die "Usage: $0 fetch [--all] [svn-remote]\n";
357 }
358 $remote ||= $Git::SVN::default_repo_id;
359 if ($_fetch_all) {
360 cmd_multi_fetch();
361 } else {
362 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
363 }
364 }
365
366 sub cmd_set_tree {
367 my (@commits) = @_;
368 if ($_stdin || !@commits) {
369 print "Reading from stdin...\n";
370 @commits = ();
371 while (<STDIN>) {
372 if (/\b($sha1_short)\b/o) {
373 unshift @commits, $1;
374 }
375 }
376 }
377 my @revs;
378 foreach my $c (@commits) {
379 my @tmp = command('rev-parse',$c);
380 if (scalar @tmp == 1) {
381 push @revs, $tmp[0];
382 } elsif (scalar @tmp > 1) {
383 push @revs, reverse(command('rev-list',@tmp));
384 } else {
385 fatal "Failed to rev-parse $c";
386 }
387 }
388 my $gs = Git::SVN->new;
389 my ($r_last, $cmt_last) = $gs->last_rev_commit;
390 $gs->fetch;
391 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
392 fatal "There are new revisions that were fetched ",
393 "and need to be merged (or acknowledged) ",
394 "before committing.\nlast rev: $r_last\n",
395 " current: $gs->{last_rev}";
396 }
397 $gs->set_tree($_) foreach @revs;
398 print "Done committing ",scalar @revs," revisions to SVN\n";
399 unlink $gs->{index};
400 }
401
402 sub cmd_dcommit {
403 my $head = shift;
404 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
405 'Cannot dcommit with a dirty index. Commit your changes first, '
406 . "or stash them with `git stash'.\n";
407 $head ||= 'HEAD';
408 my @refs;
409 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
410 print "Committing to $url ...\n";
411 unless ($gs) {
412 die "Unable to determine upstream SVN information from ",
413 "$head history\n";
414 }
415 my $last_rev;
416 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
417 if ($_no_rebase && scalar(@$linear_refs) > 1) {
418 warn "Attempting to commit more than one change while ",
419 "--no-rebase is enabled.\n",
420 "If these changes depend on each other, re-running ",
421 "without --no-rebase may be required."
422 }
423 while (1) {
424 my $d = shift @$linear_refs or last;
425 unless (defined $last_rev) {
426 (undef, $last_rev, undef) = cmt_metadata("$d~1");
427 unless (defined $last_rev) {
428 fatal "Unable to extract revision information ",
429 "from commit $d~1";
430 }
431 }
432 if ($_dry_run) {
433 print "diff-tree $d~1 $d\n";
434 } else {
435 my $cmt_rev;
436 my %ed_opts = ( r => $last_rev,
437 log => get_commit_entry($d)->{log},
438 ra => Git::SVN::Ra->new($gs->full_url),
439 config => SVN::Core::config_get_config(
440 $Git::SVN::Ra::config_dir
441 ),
442 tree_a => "$d~1",
443 tree_b => $d,
444 editor_cb => sub {
445 print "Committed r$_[0]\n";
446 $cmt_rev = $_[0];
447 },
448 svn_path => '');
449 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
450 print "No changes\n$d~1 == $d\n";
451 } elsif ($parents->{$d} && @{$parents->{$d}}) {
452 $gs->{inject_parents_dcommit}->{$cmt_rev} =
453 $parents->{$d};
454 }
455 $_fetch_all ? $gs->fetch_all : $gs->fetch;
456 $last_rev = $cmt_rev;
457 next if $_no_rebase;
458
459 # we always want to rebase against the current HEAD,
460 # not any head that was passed to us
461 my @diff = command('diff-tree', $d,
462 $gs->refname, '--');
463 my @finish;
464 if (@diff) {
465 @finish = rebase_cmd();
466 print STDERR "W: $d and ", $gs->refname,
467 " differ, using @finish:\n",
468 join("\n", @diff), "\n";
469 } else {
470 print "No changes between current HEAD and ",
471 $gs->refname,
472 "\nResetting to the latest ",
473 $gs->refname, "\n";
474 @finish = qw/reset --mixed/;
475 }
476 command_noisy(@finish, $gs->refname);
477 if (@diff) {
478 @refs = ();
479 my ($url_, $rev_, $uuid_, $gs_) =
480 working_head_info($head, \@refs);
481 my ($linear_refs_, $parents_) =
482 linearize_history($gs_, \@refs);
483 if (scalar(@$linear_refs) !=
484 scalar(@$linear_refs_)) {
485 fatal "# of revisions changed ",
486 "\nbefore:\n",
487 join("\n", @$linear_refs),
488 "\n\nafter:\n",
489 join("\n", @$linear_refs_), "\n",
490 'If you are attempting to commit ',
491 "merges, try running:\n\t",
492 'git rebase --interactive',
493 '--preserve-merges ',
494 $gs->refname,
495 "\nBefore dcommitting";
496 }
497 if ($url_ ne $url) {
498 fatal "URL mismatch after rebase: ",
499 "$url_ != $url";
500 }
501 if ($uuid_ ne $uuid) {
502 fatal "uuid mismatch after rebase: ",
503 "$uuid_ != $uuid";
504 }
505 # remap parents
506 my (%p, @l, $i);
507 for ($i = 0; $i < scalar @$linear_refs; $i++) {
508 my $new = $linear_refs_->[$i] or next;
509 $p{$new} =
510 $parents->{$linear_refs->[$i]};
511 push @l, $new;
512 }
513 $parents = \%p;
514 $linear_refs = \@l;
515 }
516 }
517 }
518 unlink $gs->{index};
519 }
520
521 sub cmd_find_rev {
522 my $revision_or_hash = shift;
523 my $result;
524 if ($revision_or_hash =~ /^r\d+$/) {
525 my $head = shift;
526 $head ||= 'HEAD';
527 my @refs;
528 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
529 unless ($gs) {
530 die "Unable to determine upstream SVN information from ",
531 "$head history\n";
532 }
533 my $desired_revision = substr($revision_or_hash, 1);
534 $result = $gs->rev_map_get($desired_revision);
535 } else {
536 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
537 $result = $rev;
538 }
539 print "$result\n" if $result;
540 }
541
542 sub cmd_rebase {
543 command_noisy(qw/update-index --refresh/);
544 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
545 unless ($gs) {
546 die "Unable to determine upstream SVN information from ",
547 "working tree history\n";
548 }
549 if (command(qw/diff-index HEAD --/)) {
550 print STDERR "Cannot rebase with uncommited changes:\n";
551 command_noisy('status');
552 exit 1;
553 }
554 unless ($_local) {
555 # rebase will checkout for us, so no need to do it explicitly
556 $_no_checkout = 'true';
557 $_fetch_all ? $gs->fetch_all : $gs->fetch;
558 }
559 command_noisy(rebase_cmd(), $gs->refname);
560 }
561
562 sub cmd_show_ignore {
563 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
564 $gs ||= Git::SVN->new;
565 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
566 $gs->prop_walk($gs->{path}, $r, sub {
567 my ($gs, $path, $props) = @_;
568 print STDOUT "\n# $path\n";
569 my $s = $props->{'svn:ignore'} or return;
570 $s =~ s/[\r\n]+/\n/g;
571 chomp $s;
572 $s =~ s#^#$path#gm;
573 print STDOUT "$s\n";
574 });
575 }
576
577 sub cmd_show_externals {
578 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
579 $gs ||= Git::SVN->new;
580 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
581 $gs->prop_walk($gs->{path}, $r, sub {
582 my ($gs, $path, $props) = @_;
583 print STDOUT "\n# $path\n";
584 my $s = $props->{'svn:externals'} or return;
585 $s =~ s/[\r\n]+/\n/g;
586 chomp $s;
587 $s =~ s#^#$path#gm;
588 print STDOUT "$s\n";
589 });
590 }
591
592 sub cmd_create_ignore {
593 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
594 $gs ||= Git::SVN->new;
595 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
596 $gs->prop_walk($gs->{path}, $r, sub {
597 my ($gs, $path, $props) = @_;
598 # $path is of the form /path/to/dir/
599 my $ignore = '.' . $path . '.gitignore';
600 my $s = $props->{'svn:ignore'} or return;
601 open(GITIGNORE, '>', $ignore)
602 or fatal("Failed to open `$ignore' for writing: $!");
603 $s =~ s/[\r\n]+/\n/g;
604 chomp $s;
605 # Prefix all patterns so that the ignore doesn't apply
606 # to sub-directories.
607 $s =~ s#^#/#gm;
608 print GITIGNORE "$s\n";
609 close(GITIGNORE)
610 or fatal("Failed to close `$ignore': $!");
611 command_noisy('add', $ignore);
612 });
613 }
614
615 sub canonicalize_path {
616 my ($path) = @_;
617 my $dot_slash_added = 0;
618 if (substr($path, 0, 1) ne "/") {
619 $path = "./" . $path;
620 $dot_slash_added = 1;
621 }
622 # File::Spec->canonpath doesn't collapse x/../y into y (for a
623 # good reason), so let's do this manually.
624 $path =~ s#/+#/#g;
625 $path =~ s#/\.(?:/|$)#/#g;
626 $path =~ s#/[^/]+/\.\.##g;
627 $path =~ s#/$##g;
628 $path =~ s#^\./## if $dot_slash_added;
629 return $path;
630 }
631
632 # get_svnprops(PATH)
633 # ------------------
634 # Helper for cmd_propget and cmd_proplist below.
635 sub get_svnprops {
636 my $path = shift;
637 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
638 $gs ||= Git::SVN->new;
639
640 # prefix THE PATH by the sub-directory from which the user
641 # invoked us.
642 $path = $cmd_dir_prefix . $path;
643 fatal("No such file or directory: $path") unless -e $path;
644 my $is_dir = -d $path ? 1 : 0;
645 $path = $gs->{path} . '/' . $path;
646
647 # canonicalize the path (otherwise libsvn will abort or fail to
648 # find the file)
649 $path = canonicalize_path($path);
650
651 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
652 my $props;
653 if ($is_dir) {
654 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
655 }
656 else {
657 (undef, $props) = $gs->ra->get_file($path, $r, undef);
658 }
659 return $props;
660 }
661
662 # cmd_propget (PROP, PATH)
663 # ------------------------
664 # Print the SVN property PROP for PATH.
665 sub cmd_propget {
666 my ($prop, $path) = @_;
667 $path = '.' if not defined $path;
668 usage(1) if not defined $prop;
669 my $props = get_svnprops($path);
670 if (not defined $props->{$prop}) {
671 fatal("`$path' does not have a `$prop' SVN property.");
672 }
673 print $props->{$prop} . "\n";
674 }
675
676 # cmd_proplist (PATH)
677 # -------------------
678 # Print the list of SVN properties for PATH.
679 sub cmd_proplist {
680 my $path = shift;
681 $path = '.' if not defined $path;
682 my $props = get_svnprops($path);
683 print "Properties on '$path':\n";
684 foreach (sort keys %{$props}) {
685 print " $_\n";
686 }
687 }
688
689 sub cmd_multi_init {
690 my $url = shift;
691 unless (defined $_trunk || defined $_branches || defined $_tags) {
692 usage(1);
693 }
694
695 # there are currently some bugs that prevent multi-init/multi-fetch
696 # setups from working well without this.
697 $Git::SVN::_minimize_url = 1;
698
699 $_prefix = '' unless defined $_prefix;
700 if (defined $url) {
701 $url =~ s#/+$##;
702 init_subdir(@_);
703 }
704 do_git_init_db();
705 if (defined $_trunk) {
706 my $trunk_ref = $_prefix . 'trunk';
707 # try both old-style and new-style lookups:
708 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
709 unless ($gs_trunk) {
710 my ($trunk_url, $trunk_path) =
711 complete_svn_url($url, $_trunk);
712 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
713 undef, $trunk_ref);
714 }
715 }
716 return unless defined $_branches || defined $_tags;
717 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
718 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
719 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
720 }
721
722 sub cmd_multi_fetch {
723 my $remotes = Git::SVN::read_all_remotes();
724 foreach my $repo_id (sort keys %$remotes) {
725 if ($remotes->{$repo_id}->{url}) {
726 Git::SVN::fetch_all($repo_id, $remotes);
727 }
728 }
729 }
730
731 # this command is special because it requires no metadata
732 sub cmd_commit_diff {
733 my ($ta, $tb, $url) = @_;
734 my $usage = "Usage: $0 commit-diff -r<revision> ".
735 "<tree-ish> <tree-ish> [<URL>]";
736 fatal($usage) if (!defined $ta || !defined $tb);
737 my $svn_path;
738 if (!defined $url) {
739 my $gs = eval { Git::SVN->new };
740 if (!$gs) {
741 fatal("Needed URL or usable git-svn --id in ",
742 "the command-line\n", $usage);
743 }
744 $url = $gs->{url};
745 $svn_path = $gs->{path};
746 }
747 unless (defined $_revision) {
748 fatal("-r|--revision is a required argument\n", $usage);
749 }
750 if (defined $_message && defined $_file) {
751 fatal("Both --message/-m and --file/-F specified ",
752 "for the commit message.\n",
753 "I have no idea what you mean");
754 }
755 if (defined $_file) {
756 $_message = file_to_s($_file);
757 } else {
758 $_message ||= get_commit_entry($tb)->{log};
759 }
760 my $ra ||= Git::SVN::Ra->new($url);
761 $svn_path ||= $ra->{svn_path};
762 my $r = $_revision;
763 if ($r eq 'HEAD') {
764 $r = $ra->get_latest_revnum;
765 } elsif ($r !~ /^\d+$/) {
766 die "revision argument: $r not understood by git-svn\n";
767 }
768 my %ed_opts = ( r => $r,
769 log => $_message,
770 ra => $ra,
771 tree_a => $ta,
772 tree_b => $tb,
773 editor_cb => sub { print "Committed r$_[0]\n" },
774 svn_path => $svn_path );
775 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
776 print "No changes\n$ta == $tb\n";
777 }
778 }
779
780 sub cmd_info {
781 my $path = canonicalize_path(shift or ".");
782 unless (scalar(@_) == 0) {
783 die "Too many arguments specified\n";
784 }
785
786 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
787
788 if (!$file_type && !$diff_status) {
789 print STDERR "$path: (Not a versioned resource)\n\n";
790 return;
791 }
792
793 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
794 unless ($gs) {
795 die "Unable to determine upstream SVN information from ",
796 "working tree history\n";
797 }
798 my $full_url = $url . ($path eq "." ? "" : "/$path");
799
800 if ($_url) {
801 print $full_url, "\n";
802 return;
803 }
804
805 my $result = "Path: $path\n";
806 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
807 $result .= "URL: " . $full_url . "\n";
808
809 eval {
810 my $repos_root = $gs->repos_root;
811 Git::SVN::remove_username($repos_root);
812 $result .= "Repository Root: $repos_root\n";
813 };
814 if ($@) {
815 $result .= "Repository Root: (offline)\n";
816 }
817 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
818 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
819
820 $result .= "Node Kind: " .
821 ($file_type eq "dir" ? "directory" : "file") . "\n";
822
823 my $schedule = $diff_status eq "A"
824 ? "add"
825 : ($diff_status eq "D" ? "delete" : "normal");
826 $result .= "Schedule: $schedule\n";
827
828 if ($diff_status eq "A") {
829 print $result, "\n";
830 return;
831 }
832
833 my ($lc_author, $lc_rev, $lc_date_utc);
834 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
835 my $log = command_output_pipe(@args);
836 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
837 while (<$log>) {
838 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
839 $lc_author = $1;
840 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
841 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
842 (undef, $lc_rev, undef) = ::extract_metadata($1);
843 }
844 }
845 close $log;
846
847 Git::SVN::Log::set_local_timezone();
848
849 $result .= "Last Changed Author: $lc_author\n";
850 $result .= "Last Changed Rev: $lc_rev\n";
851 $result .= "Last Changed Date: " .
852 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
853
854 if ($file_type ne "dir") {
855 my $text_last_updated_date =
856 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
857 $result .=
858 "Text Last Updated: " .
859 Git::SVN::Log::format_svn_date($text_last_updated_date) .
860 "\n";
861 my $checksum;
862 if ($diff_status eq "D") {
863 my ($fh, $ctx) =
864 command_output_pipe(qw(cat-file blob), "HEAD:$path");
865 if ($file_type eq "link") {
866 my $file_name = <$fh>;
867 $checksum = md5sum("link $file_name");
868 } else {
869 $checksum = md5sum($fh);
870 }
871 command_close_pipe($fh, $ctx);
872 } elsif ($file_type eq "link") {
873 my $file_name =
874 command(qw(cat-file blob), "HEAD:$path");
875 $checksum =
876 md5sum("link " . $file_name);
877 } else {
878 open FILE, "<", $path or die $!;
879 $checksum = md5sum(\*FILE);
880 close FILE or die $!;
881 }
882 $result .= "Checksum: " . $checksum . "\n";
883 }
884
885 print $result, "\n";
886 }
887
888 ########################### utility functions #########################
889
890 sub rebase_cmd {
891 my @cmd = qw/rebase/;
892 push @cmd, '-v' if $_verbose;
893 push @cmd, qw/--merge/ if $_merge;
894 push @cmd, "--strategy=$_strategy" if $_strategy;
895 @cmd;
896 }
897
898 sub post_fetch_checkout {
899 return if $_no_checkout;
900 my $gs = $Git::SVN::_head or return;
901 return if verify_ref('refs/heads/master^0');
902
903 my $valid_head = verify_ref('HEAD^0');
904 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
905 return if ($valid_head || !verify_ref('HEAD^0'));
906
907 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
908 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
909 return if -f $index;
910
911 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
912 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
913 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
914 print STDERR "Checked out HEAD:\n ",
915 $gs->full_url, " r", $gs->last_rev, "\n";
916 }
917
918 sub complete_svn_url {
919 my ($url, $path) = @_;
920 $path =~ s#/+$##;
921 if ($path !~ m#^[a-z\+]+://#) {
922 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
923 fatal("E: '$path' is not a complete URL ",
924 "and a separate URL is not specified");
925 }
926 return ($url, $path);
927 }
928 return ($path, '');
929 }
930
931 sub complete_url_ls_init {
932 my ($ra, $repo_path, $switch, $pfx) = @_;
933 unless ($repo_path) {
934 print STDERR "W: $switch not specified\n";
935 return;
936 }
937 $repo_path =~ s#/+$##;
938 if ($repo_path =~ m#^[a-z\+]+://#) {
939 $ra = Git::SVN::Ra->new($repo_path);
940 $repo_path = '';
941 } else {
942 $repo_path =~ s#^/+##;
943 unless ($ra) {
944 fatal("E: '$repo_path' is not a complete URL ",
945 "and a separate URL is not specified");
946 }
947 }
948 my $url = $ra->{url};
949 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
950 my $k = "svn-remote.$gs->{repo_id}.url";
951 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
952 if ($orig_url && ($orig_url ne $gs->{url})) {
953 die "$k already set: $orig_url\n",
954 "wanted to set to: $gs->{url}\n";
955 }
956 command_oneline('config', $k, $gs->{url}) unless $orig_url;
957 my $remote_path = "$ra->{svn_path}/$repo_path/*";
958 $remote_path =~ s#/+#/#g;
959 $remote_path =~ s#^/##g;
960 my ($n) = ($switch =~ /^--(\w+)/);
961 if (length $pfx && $pfx !~ m#/$#) {
962 die "--prefix='$pfx' must have a trailing slash '/'\n";
963 }
964 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
965 "$remote_path:refs/remotes/$pfx*");
966 }
967
968 sub verify_ref {
969 my ($ref) = @_;
970 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
971 { STDERR => 0 }); };
972 }
973
974 sub get_tree_from_treeish {
975 my ($treeish) = @_;
976 # $treeish can be a symbolic ref, too:
977 my $type = command_oneline(qw/cat-file -t/, $treeish);
978 my $expected;
979 while ($type eq 'tag') {
980 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
981 }
982 if ($type eq 'commit') {
983 $expected = (grep /^tree /, command(qw/cat-file commit/,
984 $treeish))[0];
985 ($expected) = ($expected =~ /^tree ($sha1)$/o);
986 die "Unable to get tree from $treeish\n" unless $expected;
987 } elsif ($type eq 'tree') {
988 $expected = $treeish;
989 } else {
990 die "$treeish is a $type, expected tree, tag or commit\n";
991 }
992 return $expected;
993 }
994
995 sub get_commit_entry {
996 my ($treeish) = shift;
997 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
998 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
999 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1000 open my $log_fh, '>', $commit_editmsg or croak $!;
1001
1002 my $type = command_oneline(qw/cat-file -t/, $treeish);
1003 if ($type eq 'commit' || $type eq 'tag') {
1004 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1005 $type, $treeish);
1006 my $in_msg = 0;
1007 while (<$msg_fh>) {
1008 if (!$in_msg) {
1009 $in_msg = 1 if (/^\s*$/);
1010 } elsif (/^git-svn-id: /) {
1011 # skip this for now, we regenerate the
1012 # correct one on re-fetch anyways
1013 # TODO: set *:merge properties or like...
1014 } else {
1015 print $log_fh $_ or croak $!;
1016 }
1017 }
1018 command_close_pipe($msg_fh, $ctx);
1019 }
1020 close $log_fh or croak $!;
1021
1022 if ($_edit || ($type eq 'tree')) {
1023 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1024 # TODO: strip out spaces, comments, like git-commit.sh
1025 system($editor, $commit_editmsg);
1026 }
1027 rename $commit_editmsg, $commit_msg or croak $!;
1028 open $log_fh, '<', $commit_msg or croak $!;
1029 { local $/; chomp($log_entry{log} = <$log_fh>); }
1030 close $log_fh or croak $!;
1031 unlink $commit_msg;
1032 \%log_entry;
1033 }
1034
1035 sub s_to_file {
1036 my ($str, $file, $mode) = @_;
1037 open my $fd,'>',$file or croak $!;
1038 print $fd $str,"\n" or croak $!;
1039 close $fd or croak $!;
1040 chmod ($mode &~ umask, $file) if (defined $mode);
1041 }
1042
1043 sub file_to_s {
1044 my $file = shift;
1045 open my $fd,'<',$file or croak "$!: file: $file\n";
1046 local $/;
1047 my $ret = <$fd>;
1048 close $fd or croak $!;
1049 $ret =~ s/\s*$//s;
1050 return $ret;
1051 }
1052
1053 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1054 sub load_authors {
1055 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1056 my $log = $cmd eq 'log';
1057 while (<$authors>) {
1058 chomp;
1059 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1060 my ($user, $name, $email) = ($1, $2, $3);
1061 if ($log) {
1062 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1063 } else {
1064 $users{$user} = [$name, $email];
1065 }
1066 }
1067 close $authors or croak $!;
1068 }
1069
1070 # convert GetOpt::Long specs for use by git-config
1071 sub read_repo_config {
1072 return unless -d $ENV{GIT_DIR};
1073 my $opts = shift;
1074 my @config_only;
1075 foreach my $o (keys %$opts) {
1076 # if we have mixedCase and a long option-only, then
1077 # it's a config-only variable that we don't need for
1078 # the command-line.
1079 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1080 my $v = $opts->{$o};
1081 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1082 $key =~ s/-//g;
1083 my $arg = 'git-config';
1084 $arg .= ' --int' if ($o =~ /[:=]i$/);
1085 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1086 if (ref $v eq 'ARRAY') {
1087 chomp(my @tmp = `$arg --get-all svn.$key`);
1088 @$v = @tmp if @tmp;
1089 } else {
1090 chomp(my $tmp = `$arg --get svn.$key`);
1091 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1092 $$v = $tmp;
1093 }
1094 }
1095 }
1096 delete @$opts{@config_only} if @config_only;
1097 }
1098
1099 sub extract_metadata {
1100 my $id = shift or return (undef, undef, undef);
1101 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1102 \s([a-f\d\-]+)$/x);
1103 if (!defined $rev || !$uuid || !$url) {
1104 # some of the original repositories I made had
1105 # identifiers like this:
1106 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1107 }
1108 return ($url, $rev, $uuid);
1109 }
1110
1111 sub cmt_metadata {
1112 return extract_metadata((grep(/^git-svn-id: /,
1113 command(qw/cat-file commit/, shift)))[-1]);
1114 }
1115
1116 sub working_head_info {
1117 my ($head, $refs) = @_;
1118 my @args = ('log', '--no-color', '--first-parent');
1119 my ($fh, $ctx) = command_output_pipe(@args, $head);
1120 my $hash;
1121 my %max;
1122 while (<$fh>) {
1123 if ( m{^commit ($::sha1)$} ) {
1124 unshift @$refs, $hash if $hash and $refs;
1125 $hash = $1;
1126 next;
1127 }
1128 next unless s{^\s*(git-svn-id:)}{$1};
1129 my ($url, $rev, $uuid) = extract_metadata($_);
1130 if (defined $url && defined $rev) {
1131 next if $max{$url} and $max{$url} < $rev;
1132 if (my $gs = Git::SVN->find_by_url($url)) {
1133 my $c = $gs->rev_map_get($rev);
1134 if ($c && $c eq $hash) {
1135 close $fh; # break the pipe
1136 return ($url, $rev, $uuid, $gs);
1137 } else {
1138 $max{$url} ||= $gs->rev_map_max;
1139 }
1140 }
1141 }
1142 }
1143 command_close_pipe($fh, $ctx);
1144 (undef, undef, undef, undef);
1145 }
1146
1147 sub read_commit_parents {
1148 my ($parents, $c) = @_;
1149 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1150 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1151 @{$parents->{$c}} = split(/ /, $p);
1152 }
1153
1154 sub linearize_history {
1155 my ($gs, $refs) = @_;
1156 my %parents;
1157 foreach my $c (@$refs) {
1158 read_commit_parents(\%parents, $c);
1159 }
1160
1161 my @linear_refs;
1162 my %skip = ();
1163 my $last_svn_commit = $gs->last_commit;
1164 foreach my $c (reverse @$refs) {
1165 next if $c eq $last_svn_commit;
1166 last if $skip{$c};
1167
1168 unshift @linear_refs, $c;
1169 $skip{$c} = 1;
1170
1171 # we only want the first parent to diff against for linear
1172 # history, we save the rest to inject when we finalize the
1173 # svn commit
1174 my $fp_a = verify_ref("$c~1");
1175 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1176 if (!$fp_a || !$fp_b) {
1177 die "Commit $c\n",
1178 "has no parent commit, and therefore ",
1179 "nothing to diff against.\n",
1180 "You should be working from a repository ",
1181 "originally created by git-svn\n";
1182 }
1183 if ($fp_a ne $fp_b) {
1184 die "$c~1 = $fp_a, however parsing commit $c ",
1185 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1186 }
1187
1188 foreach my $p (@{$parents{$c}}) {
1189 $skip{$p} = 1;
1190 }
1191 }
1192 (\@linear_refs, \%parents);
1193 }
1194
1195 sub find_file_type_and_diff_status {
1196 my ($path) = @_;
1197 return ('dir', '') if $path eq '.';
1198
1199 my $diff_output =
1200 command_oneline(qw(diff --cached --name-status --), $path) || "";
1201 my $diff_status = (split(' ', $diff_output))[0] || "";
1202
1203 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1204
1205 return (undef, undef) if !$diff_status && !$ls_tree;
1206
1207 if ($diff_status eq "A") {
1208 return ("link", $diff_status) if -l $path;
1209 return ("dir", $diff_status) if -d $path;
1210 return ("file", $diff_status);
1211 }
1212
1213 my $mode = (split(' ', $ls_tree))[0] || "";
1214
1215 return ("link", $diff_status) if $mode eq "120000";
1216 return ("dir", $diff_status) if $mode eq "040000";
1217 return ("file", $diff_status);
1218 }
1219
1220 sub md5sum {
1221 my $arg = shift;
1222 my $ref = ref $arg;
1223 my $md5 = Digest::MD5->new();
1224 if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1225 $md5->addfile($arg) or croak $!;
1226 } elsif ($ref eq 'SCALAR') {
1227 $md5->add($$arg) or croak $!;
1228 } elsif (!$ref) {
1229 $md5->add($arg) or croak $!;
1230 } else {
1231 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1232 }
1233 return $md5->hexdigest();
1234 }
1235
1236 package Git::SVN;
1237 use strict;
1238 use warnings;
1239 use Fcntl qw/:DEFAULT :seek/;
1240 use constant rev_map_fmt => 'NH40';
1241 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1242 $_repack $_repack_flags $_use_svm_props $_head
1243 $_use_svnsync_props $no_reuse_existing $_minimize_url
1244 $_use_log_author/;
1245 use Carp qw/croak/;
1246 use File::Path qw/mkpath/;
1247 use File::Copy qw/copy/;
1248 use IPC::Open3;
1249
1250 my $_repack_nr;
1251 # properties that we do not log:
1252 my %SKIP_PROP;
1253 BEGIN {
1254 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1255 svn:special svn:executable
1256 svn:entry:committed-rev
1257 svn:entry:last-author
1258 svn:entry:uuid
1259 svn:entry:committed-date/;
1260
1261 # some options are read globally, but can be overridden locally
1262 # per [svn-remote "..."] section. Command-line options will *NOT*
1263 # override options set in an [svn-remote "..."] section
1264 no strict 'refs';
1265 for my $option (qw/follow_parent no_metadata use_svm_props
1266 use_svnsync_props/) {
1267 my $key = $option;
1268 $key =~ tr/_//d;
1269 my $prop = "-$option";
1270 *$option = sub {
1271 my ($self) = @_;
1272 return $self->{$prop} if exists $self->{$prop};
1273 my $k = "svn-remote.$self->{repo_id}.$key";
1274 eval { command_oneline(qw/config --get/, $k) };
1275 if ($@) {
1276 $self->{$prop} = ${"Git::SVN::_$option"};
1277 } else {
1278 my $v = command_oneline(qw/config --bool/,$k);
1279 $self->{$prop} = $v eq 'false' ? 0 : 1;
1280 }
1281 return $self->{$prop};
1282 }
1283 }
1284 }
1285
1286 my (%LOCKFILES, %INDEX_FILES);
1287 END {
1288 unlink keys %LOCKFILES if %LOCKFILES;
1289 unlink keys %INDEX_FILES if %INDEX_FILES;
1290 }
1291
1292 sub resolve_local_globs {
1293 my ($url, $fetch, $glob_spec) = @_;
1294 return unless defined $glob_spec;
1295 my $ref = $glob_spec->{ref};
1296 my $path = $glob_spec->{path};
1297 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1298 next unless m#^refs/remotes/$ref->{regex}$#;
1299 my $p = $1;
1300 my $pathname = desanitize_refname($path->full_path($p));
1301 my $refname = desanitize_refname($ref->full_path($p));
1302 if (my $existing = $fetch->{$pathname}) {
1303 if ($existing ne $refname) {
1304 die "Refspec conflict:\n",
1305 "existing: refs/remotes/$existing\n",
1306 " globbed: refs/remotes/$refname\n";
1307 }
1308 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1309 $u =~ s!^\Q$url\E(/|$)!! or die
1310 "refs/remotes/$refname: '$url' not found in '$u'\n";
1311 if ($pathname ne $u) {
1312 warn "W: Refspec glob conflict ",
1313 "(ref: refs/remotes/$refname):\n",
1314 "expected path: $pathname\n",
1315 " real path: $u\n",
1316 "Continuing ahead with $u\n";
1317 next;
1318 }
1319 } else {
1320 $fetch->{$pathname} = $refname;
1321 }
1322 }
1323 }
1324
1325 sub parse_revision_argument {
1326 my ($base, $head) = @_;
1327 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1328 return ($base, $head);
1329 }
1330 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1331 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1332 return ($head, $head) if ($::_revision eq 'HEAD');
1333 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1334 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1335 die "revision argument: $::_revision not understood by git-svn\n";
1336 }
1337
1338 sub fetch_all {
1339 my ($repo_id, $remotes) = @_;
1340 if (ref $repo_id) {
1341 my $gs = $repo_id;
1342 $repo_id = undef;
1343 $repo_id = $gs->{repo_id};
1344 }
1345 $remotes ||= read_all_remotes();
1346 my $remote = $remotes->{$repo_id} or
1347 die "[svn-remote \"$repo_id\"] unknown\n";
1348 my $fetch = $remote->{fetch};
1349 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1350 my (@gs, @globs);
1351 my $ra = Git::SVN::Ra->new($url);
1352 my $uuid = $ra->get_uuid;
1353 my $head = $ra->get_latest_revnum;
1354 my $base = defined $fetch ? $head : 0;
1355
1356 # read the max revs for wildcard expansion (branches/*, tags/*)
1357 foreach my $t (qw/branches tags/) {
1358 defined $remote->{$t} or next;
1359 push @globs, $remote->{$t};
1360 my $max_rev = eval { tmp_config(qw/--int --get/,
1361 "svn-remote.$repo_id.${t}-maxRev") };
1362 if (defined $max_rev && ($max_rev < $base)) {
1363 $base = $max_rev;
1364 } elsif (!defined $max_rev) {
1365 $base = 0;
1366 }
1367 }
1368
1369 if ($fetch) {
1370 foreach my $p (sort keys %$fetch) {
1371 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1372 my $lr = $gs->rev_map_max;
1373 if (defined $lr) {
1374 $base = $lr if ($lr < $base);
1375 }
1376 push @gs, $gs;
1377 }
1378 }
1379
1380 ($base, $head) = parse_revision_argument($base, $head);
1381 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1382 }
1383
1384 sub read_all_remotes {
1385 my $r = {};
1386 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1387 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1388 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1389 $local_ref =~ s{^/}{};
1390 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1391 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1392 $r->{$1}->{url} = $2;
1393 } elsif (m!^(.+)\.(branches|tags)=
1394 (.*):refs/remotes/(.+)\s*$/!x) {
1395 my ($p, $g) = ($3, $4);
1396 my $rs = $r->{$1}->{$2} = {
1397 t => $2,
1398 remote => $1,
1399 path => Git::SVN::GlobSpec->new($p),
1400 ref => Git::SVN::GlobSpec->new($g) };
1401 if (length($rs->{ref}->{right}) != 0) {
1402 die "The '*' glob character must be the last ",
1403 "character of '$g'\n";
1404 }
1405 }
1406 }
1407 $r;
1408 }
1409
1410 sub init_vars {
1411 if (defined $_repack) {
1412 $_repack = 1000 if ($_repack <= 0);
1413 $_repack_nr = $_repack;
1414 $_repack_flags ||= '-d';
1415 }
1416 }
1417
1418 sub verify_remotes_sanity {
1419 return unless -d $ENV{GIT_DIR};
1420 my %seen;
1421 foreach (command(qw/config -l/)) {
1422 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1423 if ($seen{$1}) {
1424 die "Remote ref refs/remote/$1 is tracked by",
1425 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1426 "Please resolve this ambiguity in ",
1427 "your git configuration file before ",
1428 "continuing\n";
1429 }
1430 $seen{$1} = $_;
1431 }
1432 }
1433 }
1434
1435 # we allow more chars than remotes2config.sh...
1436 sub sanitize_remote_name {
1437 my ($name) = @_;
1438 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1439 $name;
1440 }
1441
1442 sub find_existing_remote {
1443 my ($url, $remotes) = @_;
1444 return undef if $no_reuse_existing;
1445 my $existing;
1446 foreach my $repo_id (keys %$remotes) {
1447 my $u = $remotes->{$repo_id}->{url} or next;
1448 next if $u ne $url;
1449 $existing = $repo_id;
1450 last;
1451 }
1452 $existing;
1453 }
1454
1455 sub init_remote_config {
1456 my ($self, $url, $no_write) = @_;
1457 $url =~ s!/+$!!; # strip trailing slash
1458 my $r = read_all_remotes();
1459 my $existing = find_existing_remote($url, $r);
1460 if ($existing) {
1461 unless ($no_write) {
1462 print STDERR "Using existing ",
1463 "[svn-remote \"$existing\"]\n";
1464 }
1465 $self->{repo_id} = $existing;
1466 } elsif ($_minimize_url) {
1467 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1468 $existing = find_existing_remote($min_url, $r);
1469 if ($existing) {
1470 unless ($no_write) {
1471 print STDERR "Using existing ",
1472 "[svn-remote \"$existing\"]\n";
1473 }
1474 $self->{repo_id} = $existing;
1475 }
1476 if ($min_url ne $url) {
1477 unless ($no_write) {
1478 print STDERR "Using higher level of URL: ",
1479 "$url => $min_url\n";
1480 }
1481 my $old_path = $self->{path};
1482 $self->{path} = $url;
1483 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1484 if (length $old_path) {
1485 $self->{path} .= "/$old_path";
1486 }
1487 $url = $min_url;
1488 }
1489 }
1490 my $orig_url;
1491 if (!$existing) {
1492 # verify that we aren't overwriting anything:
1493 $orig_url = eval {
1494 command_oneline('config', '--get',
1495 "svn-remote.$self->{repo_id}.url")
1496 };
1497 if ($orig_url && ($orig_url ne $url)) {
1498 die "svn-remote.$self->{repo_id}.url already set: ",
1499 "$orig_url\nwanted to set to: $url\n";
1500 }
1501 }
1502 my ($xrepo_id, $xpath) = find_ref($self->refname);
1503 if (defined $xpath) {
1504 die "svn-remote.$xrepo_id.fetch already set to track ",
1505 "$xpath:refs/remotes/", $self->refname, "\n";
1506 }
1507 unless ($no_write) {
1508 command_noisy('config',
1509 "svn-remote.$self->{repo_id}.url", $url);
1510 $self->{path} =~ s{^/}{};
1511 command_noisy('config', '--add',
1512 "svn-remote.$self->{repo_id}.fetch",
1513 "$self->{path}:".$self->refname);
1514 }
1515 $self->{url} = $url;
1516 }
1517
1518 sub find_by_url { # repos_root and, path are optional
1519 my ($class, $full_url, $repos_root, $path) = @_;
1520
1521 return undef unless defined $full_url;
1522 remove_username($full_url);
1523 remove_username($repos_root) if defined $repos_root;
1524 my $remotes = read_all_remotes();
1525 if (defined $full_url && defined $repos_root && !defined $path) {
1526 $path = $full_url;
1527 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1528 }
1529 foreach my $repo_id (keys %$remotes) {
1530 my $u = $remotes->{$repo_id}->{url} or next;
1531 remove_username($u);
1532 next if defined $repos_root && $repos_root ne $u;
1533
1534 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1535 foreach (qw/branches tags/) {
1536 resolve_local_globs($u, $fetch,
1537 $remotes->{$repo_id}->{$_});
1538 }
1539 my $p = $path;
1540 unless (defined $p) {
1541 $p = $full_url;
1542 $p =~ s#^\Q$u\E(?:/|$)## or next;
1543 }
1544 foreach my $f (keys %$fetch) {
1545 next if $f ne $p;
1546 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1547 }
1548 }
1549 undef;
1550 }
1551
1552 sub init {
1553 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1554 my $self = _new($class, $repo_id, $ref_id, $path);
1555 if (defined $url) {
1556 $self->init_remote_config($url, $no_write);
1557 }
1558 $self;
1559 }
1560
1561 sub find_ref {
1562 my ($ref_id) = @_;
1563 foreach (command(qw/config -l/)) {
1564 next unless m!^svn-remote\.(.+)\.fetch=
1565 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1566 my ($repo_id, $path, $ref) = ($1, $2, $3);
1567 if ($ref eq $ref_id) {
1568 $path = '' if ($path =~ m#^\./?#);
1569 return ($repo_id, $path);
1570 }
1571 }
1572 (undef, undef, undef);
1573 }
1574
1575 sub new {
1576 my ($class, $ref_id, $repo_id, $path) = @_;
1577 if (defined $ref_id && !defined $repo_id && !defined $path) {
1578 ($repo_id, $path) = find_ref($ref_id);
1579 if (!defined $repo_id) {
1580 die "Could not find a \"svn-remote.*.fetch\" key ",
1581 "in the repository configuration matching: ",
1582 "refs/remotes/$ref_id\n";
1583 }
1584 }
1585 my $self = _new($class, $repo_id, $ref_id, $path);
1586 if (!defined $self->{path} || !length $self->{path}) {
1587 my $fetch = command_oneline('config', '--get',
1588 "svn-remote.$repo_id.fetch",
1589 ":refs/remotes/$ref_id\$") or
1590 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1591 "\":refs/remotes/$ref_id\$\" in config\n";
1592 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1593 }
1594 $self->{url} = command_oneline('config', '--get',
1595 "svn-remote.$repo_id.url") or
1596 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1597 $self->rebuild;
1598 $self;
1599 }
1600
1601 sub refname {
1602 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1603
1604 # It cannot end with a slash /, we'll throw up on this because
1605 # SVN can't have directories with a slash in their name, either:
1606 if ($refname =~ m{/$}) {
1607 die "ref: '$refname' ends with a trailing slash, this is ",
1608 "not permitted by git nor Subversion\n";
1609 }
1610
1611 # It cannot have ASCII control character space, tilde ~, caret ^,
1612 # colon :, question-mark ?, asterisk *, space, or open bracket [
1613 # anywhere.
1614 #
1615 # Additionally, % must be escaped because it is used for escaping
1616 # and we want our escaped refname to be reversible
1617 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1618
1619 # no slash-separated component can begin with a dot .
1620 # /.* becomes /%2E*
1621 $refname =~ s{/\.}{/%2E}g;
1622
1623 # It cannot have two consecutive dots .. anywhere
1624 # .. becomes %2E%2E
1625 $refname =~ s{\.\.}{%2E%2E}g;
1626
1627 return $refname;
1628 }
1629
1630 sub desanitize_refname {
1631 my ($refname) = @_;
1632 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1633 return $refname;
1634 }
1635
1636 sub svm_uuid {
1637 my ($self) = @_;
1638 return $self->{svm}->{uuid} if $self->svm;
1639 $self->ra;
1640 unless ($self->{svm}) {
1641 die "SVM UUID not cached, and reading remotely failed\n";
1642 }
1643 $self->{svm}->{uuid};
1644 }
1645
1646 sub svm {
1647 my ($self) = @_;
1648 return $self->{svm} if $self->{svm};
1649 my $svm;
1650 # see if we have it in our config, first:
1651 eval {
1652 my $section = "svn-remote.$self->{repo_id}";
1653 $svm = {
1654 source => tmp_config('--get', "$section.svm-source"),
1655 uuid => tmp_config('--get', "$section.svm-uuid"),
1656 replace => tmp_config('--get', "$section.svm-replace"),
1657 }
1658 };
1659 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1660 $self->{svm} = $svm;
1661 }
1662 $self->{svm};
1663 }
1664
1665 sub _set_svm_vars {
1666 my ($self, $ra) = @_;
1667 return $ra if $self->svm;
1668
1669 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1670 "(svm:source, svm:uuid) ",
1671 "from the following URLs:\n" );
1672 sub read_svm_props {
1673 my ($self, $ra, $path, $r) = @_;
1674 my $props = ($ra->get_dir($path, $r))[2];
1675 my $src = $props->{'svm:source'};
1676 my $uuid = $props->{'svm:uuid'};
1677 return undef if (!$src || !$uuid);
1678
1679 chomp($src, $uuid);
1680
1681 $uuid =~ m{^[0-9a-f\-]{30,}$}
1682 or die "doesn't look right - svm:uuid is '$uuid'\n";
1683
1684 # the '!' is used to mark the repos_root!/relative/path
1685 $src =~ s{/?!/?}{/};
1686 $src =~ s{/+$}{}; # no trailing slashes please
1687 # username is of no interest
1688 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1689
1690 my $replace = $ra->{url};
1691 $replace .= "/$path" if length $path;
1692
1693 my $section = "svn-remote.$self->{repo_id}";
1694 tmp_config("$section.svm-source", $src);
1695 tmp_config("$section.svm-replace", $replace);
1696 tmp_config("$section.svm-uuid", $uuid);
1697 $self->{svm} = {
1698 source => $src,
1699 uuid => $uuid,
1700 replace => $replace
1701 };
1702 }
1703
1704 my $r = $ra->get_latest_revnum;
1705 my $path = $self->{path};
1706 my %tried;
1707 while (length $path) {
1708 unless ($tried{"$self->{url}/$path"}) {
1709 return $ra if $self->read_svm_props($ra, $path, $r);
1710 $tried{"$self->{url}/$path"} = 1;
1711 }
1712 $path =~ s#/?[^/]+$##;
1713 }
1714 die "Path: '$path' should be ''\n" if $path ne '';
1715 return $ra if $self->read_svm_props($ra, $path, $r);
1716 $tried{"$self->{url}/$path"} = 1;
1717
1718 if ($ra->{repos_root} eq $self->{url}) {
1719 die @err, (map { " $_\n" } keys %tried), "\n";
1720 }
1721
1722 # nope, make sure we're connected to the repository root:
1723 my $ok;
1724 my @tried_b;
1725 $path = $ra->{svn_path};
1726 $ra = Git::SVN::Ra->new($ra->{repos_root});
1727 while (length $path) {
1728 unless ($tried{"$ra->{url}/$path"}) {
1729 $ok = $self->read_svm_props($ra, $path, $r);
1730 last if $ok;
1731 $tried{"$ra->{url}/$path"} = 1;
1732 }
1733 $path =~ s#/?[^/]+$##;
1734 }
1735 die "Path: '$path' should be ''\n" if $path ne '';
1736 $ok ||= $self->read_svm_props($ra, $path, $r);
1737 $tried{"$ra->{url}/$path"} = 1;
1738 if (!$ok) {
1739 die @err, (map { " $_\n" } keys %tried), "\n";
1740 }
1741 Git::SVN::Ra->new($self->{url});
1742 }
1743
1744 sub svnsync {
1745 my ($self) = @_;
1746 return $self->{svnsync} if $self->{svnsync};
1747
1748 if ($self->no_metadata) {
1749 die "Can't have both 'noMetadata' and ",
1750 "'useSvnsyncProps' options set!\n";
1751 }
1752 if ($self->rewrite_root) {
1753 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1754 "options set!\n";
1755 }
1756
1757 my $svnsync;
1758 # see if we have it in our config, first:
1759 eval {
1760 my $section = "svn-remote.$self->{repo_id}";
1761
1762 my $url = tmp_config('--get', "$section.svnsync-url");
1763 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1764 die "doesn't look right - svn:sync-from-url is '$url'\n";
1765
1766 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1767 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1768 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1769
1770 $svnsync = { url => $url, uuid => $uuid }
1771 };
1772 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1773 return $self->{svnsync} = $svnsync;
1774 }
1775
1776 my $err = "useSvnsyncProps set, but failed to read " .
1777 "svnsync property: svn:sync-from-";
1778 my $rp = $self->ra->rev_proplist(0);
1779
1780 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1781 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1782 die "doesn't look right - svn:sync-from-url is '$url'\n";
1783
1784 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1785 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1786 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1787
1788 my $section = "svn-remote.$self->{repo_id}";
1789 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1790 tmp_config('--add', "$section.svnsync-url", $url);
1791 return $self->{svnsync} = { url => $url, uuid => $uuid };
1792 }
1793
1794 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1795 # remote lookup (useful for 'git svn log').
1796 sub ra_uuid {
1797 my ($self) = @_;
1798 unless ($self->{ra_uuid}) {
1799 my $key = "svn-remote.$self->{repo_id}.uuid";
1800 my $uuid = eval { tmp_config('--get', $key) };
1801 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1802 $self->{ra_uuid} = $uuid;
1803 } else {
1804 die "ra_uuid called without URL\n" unless $self->{url};
1805 $self->{ra_uuid} = $self->ra->get_uuid;
1806 tmp_config('--add', $key, $self->{ra_uuid});
1807 }
1808 }
1809 $self->{ra_uuid};
1810 }
1811
1812 sub _set_repos_root {
1813 my ($self, $repos_root) = @_;
1814 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1815 $repos_root ||= $self->ra->{repos_root};
1816 tmp_config($k, $repos_root);
1817 $repos_root;
1818 }
1819
1820 sub repos_root {
1821 my ($self) = @_;
1822 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1823 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1824 }
1825
1826 sub ra {
1827 my ($self) = shift;
1828 my $ra = Git::SVN::Ra->new($self->{url});
1829 $self->_set_repos_root($ra->{repos_root});
1830 if ($self->use_svm_props && !$self->{svm}) {
1831 if ($self->no_metadata) {
1832 die "Can't have both 'noMetadata' and ",
1833 "'useSvmProps' options set!\n";
1834 } elsif ($self->use_svnsync_props) {
1835 die "Can't have both 'useSvnsyncProps' and ",
1836 "'useSvmProps' options set!\n";
1837 }
1838 $ra = $self->_set_svm_vars($ra);
1839 $self->{-want_revprops} = 1;
1840 }
1841 $ra;
1842 }
1843
1844 sub rel_path {
1845 my ($self) = @_;
1846 my $repos_root = $self->ra->{repos_root};
1847 return $self->{path} if ($self->{url} eq $repos_root);
1848 my $url = $self->{url} .
1849 (length $self->{path} ? "/$self->{path}" : $self->{path});
1850 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1851 $url;
1852 }
1853
1854 # prop_walk(PATH, REV, SUB)
1855 # -------------------------
1856 # Recursively traverse PATH at revision REV and invoke SUB for each
1857 # directory that contains a SVN property. SUB will be invoked as
1858 # follows: &SUB(gs, path, props); where `gs' is this instance of
1859 # Git::SVN, `path' the path to the directory where the properties
1860 # `props' were found. The `path' will be relative to point of checkout,
1861 # that is, if url://repo/trunk is the current Git branch, and that
1862 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1863 # as `path' (note the trailing `/').
1864 sub prop_walk {
1865 my ($self, $path, $rev, $sub) = @_;
1866
1867 $path =~ s#^/##;
1868 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1869 $path =~ s#^/*#/#g;
1870 my $p = $path;
1871 # Strip the irrelevant part of the path.
1872 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1873 # Ensure the path is terminated by a `/'.
1874 $p =~ s#/*$#/#;
1875
1876 # The properties contain all the internal SVN stuff nobody
1877 # (usually) cares about.
1878 my $interesting_props = 0;
1879 foreach (keys %{$props}) {
1880 # If it doesn't start with `svn:', it must be a
1881 # user-defined property.
1882 ++$interesting_props and next if $_ !~ /^svn:/;
1883 # FIXME: Fragile, if SVN adds new public properties,
1884 # this needs to be updated.
1885 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1886 |eol-style|mime-type
1887 |externals|needs-lock)$/x;
1888 }
1889 &$sub($self, $p, $props) if $interesting_props;
1890
1891 foreach (sort keys %$dirent) {
1892 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1893 $self->prop_walk($path . '/' . $_, $rev, $sub);
1894 }
1895 }
1896
1897 sub last_rev { ($_[0]->last_rev_commit)[0] }
1898 sub last_commit { ($_[0]->last_rev_commit)[1] }
1899
1900 # returns the newest SVN revision number and newest commit SHA1
1901 sub last_rev_commit {
1902 my ($self) = @_;
1903 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1904 return ($self->{last_rev}, $self->{last_commit});
1905 }
1906 my $c = ::verify_ref($self->refname.'^0');
1907 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1908 my $rev = (::cmt_metadata($c))[1];
1909 if (defined $rev) {
1910 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1911 return ($rev, $c);
1912 }
1913 }
1914 my $map_path = $self->map_path;
1915 unless (-e $map_path) {
1916 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1917 return (undef, undef);
1918 }
1919 my ($rev, $commit) = $self->rev_map_max(1);
1920 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1921 return ($rev, $commit);
1922 }
1923
1924 sub get_fetch_range {
1925 my ($self, $min, $max) = @_;
1926 $max ||= $self->ra->get_latest_revnum;
1927 $min ||= $self->rev_map_max;
1928 (++$min, $max);
1929 }
1930
1931 sub tmp_config {
1932 my (@args) = @_;
1933 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1934 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1935 if (! -f $config && -f $old_def_config) {
1936 rename $old_def_config, $config or
1937 die "Failed rename $old_def_config => $config: $!\n";
1938 }
1939 my $old_config = $ENV{GIT_CONFIG};
1940 $ENV{GIT_CONFIG} = $config;
1941 $@ = undef;
1942 my @ret = eval {
1943 unless (-f $config) {
1944 mkfile($config);
1945 open my $fh, '>', $config or
1946 die "Can't open $config: $!\n";
1947 print $fh "; This file is used internally by ",
1948 "git-svn\n" or die
1949 "Couldn't write to $config: $!\n";
1950 print $fh "; You should not have to edit it\n" or
1951 die "Couldn't write to $config: $!\n";
1952 close $fh or die "Couldn't close $config: $!\n";
1953 }
1954 command('config', @args);
1955 };
1956 my $err = $@;
1957 if (defined $old_config) {
1958 $ENV{GIT_CONFIG} = $old_config;
1959 } else {
1960 delete $ENV{GIT_CONFIG};
1961 }
1962 die $err if $err;
1963 wantarray ? @ret : $ret[0];
1964 }
1965
1966 sub tmp_index_do {
1967 my ($self, $sub) = @_;
1968 my $old_index = $ENV{GIT_INDEX_FILE};
1969 $ENV{GIT_INDEX_FILE} = $self->{index};
1970 $@ = undef;
1971 my @ret = eval {
1972 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1973 mkpath([$dir]) unless -d $dir;
1974 &$sub;
1975 };
1976 my $err = $@;
1977 if (defined $old_index) {
1978 $ENV{GIT_INDEX_FILE} = $old_index;
1979 } else {
1980 delete $ENV{GIT_INDEX_FILE};
1981 }
1982 die $err if $err;
1983 wantarray ? @ret : $ret[0];
1984 }
1985
1986 sub assert_index_clean {
1987 my ($self, $treeish) = @_;
1988
1989 $self->tmp_index_do(sub {
1990 command_noisy('read-tree', $treeish) unless -e $self->{index};
1991 my $x = command_oneline('write-tree');
1992 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1993 /^tree ($::sha1)/mo);
1994 return if $y eq $x;
1995
1996 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1997 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1998 command_noisy('read-tree', $treeish);
1999 $x = command_oneline('write-tree');
2000 if ($y ne $x) {
2001 ::fatal "trees ($treeish) $y != $x\n",
2002 "Something is seriously wrong...";
2003 }
2004 });
2005 }
2006
2007 sub get_commit_parents {
2008 my ($self, $log_entry) = @_;
2009 my (%seen, @ret, @tmp);
2010 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2011 if (my $ip = $self->{inject_parents}) {
2012 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2013 push @tmp, $commit;
2014 }
2015 }
2016 if (my $cur = ::verify_ref($self->refname.'^0')) {
2017 push @tmp, $cur;
2018 }
2019 if (my $ipd = $self->{inject_parents_dcommit}) {
2020 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2021 push @tmp, @$commit;
2022 }
2023 }
2024 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2025 while (my $p = shift @tmp) {
2026 next if $seen{$p};
2027 $seen{$p} = 1;
2028 push @ret, $p;
2029 # MAXPARENT is defined to 16 in commit-tree.c:
2030 last if @ret >= 16;
2031 }
2032 if (@tmp) {
2033 die "r$log_entry->{revision}: No room for parents:\n\t",
2034 join("\n\t", @tmp), "\n";
2035 }
2036 @ret;
2037 }
2038
2039 sub rewrite_root {
2040 my ($self) = @_;
2041 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2042 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2043 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2044 if ($rwr) {
2045 $rwr =~ s#/+$##;
2046 if ($rwr !~ m#^[a-z\+]+://#) {
2047 die "$rwr is not a valid URL (key: $k)\n";
2048 }
2049 }
2050 $self->{-rewrite_root} = $rwr;
2051 }
2052
2053 sub metadata_url {
2054 my ($self) = @_;
2055 ($self->rewrite_root || $self->{url}) .
2056 (length $self->{path} ? '/' . $self->{path} : '');
2057 }
2058
2059 sub full_url {
2060 my ($self) = @_;
2061 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2062 }
2063
2064
2065 sub set_commit_header_env {
2066 my ($log_entry) = @_;
2067 my %env;
2068 foreach my $ned (qw/NAME EMAIL DATE/) {
2069 foreach my $ac (qw/AUTHOR COMMITTER/) {
2070 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2071 }
2072 }
2073
2074 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2075 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2076 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2077
2078 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2079 ? $log_entry->{commit_name}
2080 : $log_entry->{name};
2081 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2082 ? $log_entry->{commit_email}
2083 : $log_entry->{email};
2084 \%env;
2085 }
2086
2087 sub restore_commit_header_env {
2088 my ($env) = @_;
2089 foreach my $ned (qw/NAME EMAIL DATE/) {
2090 foreach my $ac (qw/AUTHOR COMMITTER/) {
2091 my $k = "GIT_${ac}_${ned}";
2092 if (defined $env->{$k}) {
2093 $ENV{$k} = $env->{$k};
2094 } else {
2095 delete $ENV{$k};
2096 }
2097 }
2098 }
2099 }
2100
2101 sub do_git_commit {
2102 my ($self, $log_entry) = @_;
2103 my $lr = $self->last_rev;
2104 if (defined $lr && $lr >= $log_entry->{revision}) {
2105 die "Last fetched revision of ", $self->refname,
2106 " was r$lr, but we are about to fetch: ",
2107 "r$log_entry->{revision}!\n";
2108 }
2109 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2110 croak "$log_entry->{revision} = $c already exists! ",
2111 "Why are we refetching it?\n";
2112 }
2113 my $old_env = set_commit_header_env($log_entry);
2114 my $tree = $log_entry->{tree};
2115 if (!defined $tree) {
2116 $tree = $self->tmp_index_do(sub {
2117 command_oneline('write-tree') });
2118 }
2119 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2120
2121 my @exec = ('git-commit-tree', $tree);
2122 foreach ($self->get_commit_parents($log_entry)) {
2123 push @exec, '-p', $_;
2124 }
2125 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2126 or croak $!;
2127 print $msg_fh $log_entry->{log} or croak $!;
2128 restore_commit_header_env($old_env);
2129 unless ($self->no_metadata) {
2130 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2131 or croak $!;
2132 }
2133 $msg_fh->flush == 0 or croak $!;
2134 close $msg_fh or croak $!;
2135 chomp(my $commit = do { local $/; <$out_fh> });
2136 close $out_fh or croak $!;
2137 waitpid $pid, 0;
2138 croak $? if $?;
2139 if ($commit !~ /^$::sha1$/o) {
2140 die "Failed to commit, invalid sha1: $commit\n";
2141 }
2142
2143 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2144
2145 $self->{last_rev} = $log_entry->{revision};
2146 $self->{last_commit} = $commit;
2147 print "r$log_entry->{revision}";
2148 if (defined $log_entry->{svm_revision}) {
2149 print " (\@$log_entry->{svm_revision})";
2150 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2151 0, $self->svm_uuid);
2152 }
2153 print " = $commit ($self->{ref_id})\n";
2154 if (defined $_repack && (--$_repack_nr == 0)) {
2155 $_repack_nr = $_repack;
2156 # repack doesn't use any arguments with spaces in them, does it?
2157 print "Running git repack $_repack_flags ...\n";
2158 command_noisy('repack', split(/\s+/, $_repack_flags));
2159 print "Done repacking\n";
2160 }
2161 return $commit;
2162 }
2163
2164 sub match_paths {
2165 my ($self, $paths, $r) = @_;
2166 return 1 if $self->{path} eq '';
2167 if (my $path = $paths->{"/$self->{path}"}) {
2168 return ($path->{action} eq 'D') ? 0 : 1;
2169 }
2170 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2171 if (grep /$self->{path_regex}/, keys %$paths) {
2172 return 1;
2173 }
2174 my $c = '';
2175 foreach (split m#/#, $self->{path}) {
2176 $c .= "/$_";
2177 next unless ($paths->{$c} &&
2178 ($paths->{$c}->{action} =~ /^[AR]$/));
2179 if ($self->ra->check_path($self->{path}, $r) ==
2180 $SVN::Node::dir) {
2181 return 1;
2182 }
2183 }
2184 return 0;
2185 }
2186
2187 sub find_parent_branch {
2188 my ($self, $paths, $rev) = @_;
2189 return undef unless $self->follow_parent;
2190 unless (defined $paths) {
2191 my $err_handler = $SVN::Error::handler;
2192 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2193 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2194 $paths =
2195 Git::SVN::Ra::dup_changed_paths($_[0]) });
2196 $SVN::Error::handler = $err_handler;
2197 }
2198 return undef unless defined $paths;
2199
2200 # look for a parent from another branch:
2201 my @b_path_components = split m#/#, $self->rel_path;
2202 my @a_path_components;
2203 my $i;
2204 while (@b_path_components) {
2205 $i = $paths->{'/'.join('/', @b_path_components)};
2206 last if $i && defined $i->{copyfrom_path};
2207 unshift(@a_path_components, pop(@b_path_components));
2208 }
2209 return undef unless defined $i && defined $i->{copyfrom_path};
2210 my $branch_from = $i->{copyfrom_path};
2211 if (@a_path_components) {
2212 print STDERR "branch_from: $branch_from => ";
2213 $branch_from .= '/'.join('/', @a_path_components);
2214 print STDERR $branch_from, "\n";
2215 }
2216 my $r = $i->{copyfrom_rev};
2217 my $repos_root = $self->ra->{repos_root};
2218 my $url = $self->ra->{url};
2219 my $new_url = $repos_root . $branch_from;
2220 print STDERR "Found possible branch point: ",
2221 "$new_url => ", $self->full_url, ", $r\n";
2222 $branch_from =~ s#^/##;
2223 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2224 unless ($gs) {
2225 my $ref_id = $self->{ref_id};
2226 $ref_id =~ s/\@\d+$//;
2227 $ref_id .= "\@$r";
2228 # just grow a tail if we're not unique enough :x
2229 $ref_id .= '-' while find_ref($ref_id);
2230 print STDERR "Initializing parent: $ref_id\n";
2231 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
2232 }
2233 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2234 if (!defined $r0 || !defined $parent) {
2235 my ($base, $head) = parse_revision_argument(0, $r);
2236 if ($base <= $r) {
2237 $gs->fetch($base, $r);
2238 }
2239 ($r0, $parent) = $gs->last_rev_commit;
2240 }
2241 if (defined $r0 && defined $parent) {
2242 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2243 my $ed;
2244 if ($self->ra->can_do_switch) {
2245 $self->assert_index_clean($parent);
2246 print STDERR "Following parent with do_switch\n";
2247 # do_switch works with svn/trunk >= r22312, but that
2248 # is not included with SVN 1.4.3 (the latest version
2249 # at the moment), so we can't rely on it
2250 $self->{last_commit} = $parent;
2251 $ed = SVN::Git::Fetcher->new($self);
2252 $gs->ra->gs_do_switch($r0, $rev, $gs,
2253 $self->full_url, $ed)
2254 or die "SVN connection failed somewhere...\n";
2255 } elsif ($self->ra->trees_match($new_url, $r0,
2256 $self->full_url, $rev)) {
2257 print STDERR "Trees match:\n",
2258 " $new_url\@$r0\n",
2259 " ${\$self->full_url}\@$rev\n",
2260 "Following parent with no changes\n";
2261 $self->tmp_index_do(sub {
2262 command_noisy('read-tree', $parent);
2263 });
2264 $self->{last_commit} = $parent;
2265 } else {
2266 print STDERR "Following parent with do_update\n";
2267 $ed = SVN::Git::Fetcher->new($self);
2268 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2269 or die "SVN connection failed somewhere...\n";
2270 }
2271 print STDERR "Successfully followed parent\n";
2272 return $self->make_log_entry($rev, [$parent], $ed);
2273 }
2274 return undef;
2275 }
2276
2277 sub do_fetch {
2278 my ($self, $paths, $rev) = @_;
2279 my $ed;
2280 my ($last_rev, @parents);
2281 if (my $lc = $self->last_commit) {
2282 # we can have a branch that was deleted, then re-added
2283 # under the same name but copied from another path, in
2284 # which case we'll have multiple parents (we don't
2285 # want to break the original ref, nor lose copypath info):
2286 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2287 push @{$log_entry->{parents}}, $lc;
2288 return $log_entry;
2289 }
2290 $ed = SVN::Git::Fetcher->new($self);
2291 $last_rev = $self->{last_rev};
2292 $ed->{c} = $lc;
2293 @parents = ($lc);
2294 } else {
2295 $last_rev = $rev;
2296 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2297 return $log_entry;
2298 }
2299 $ed = SVN::Git::Fetcher->new($self);
2300 }
2301 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2302 die "SVN connection failed somewhere...\n";
2303 }
2304 $self->make_log_entry($rev, \@parents, $ed);
2305 }
2306
2307 sub get_untracked {
2308 my ($self, $ed) = @_;
2309 my @out;
2310 my $h = $ed->{empty};
2311 foreach (sort keys %$h) {
2312 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2313 push @out, " $act: " . uri_encode($_);
2314 warn "W: $act: $_\n";
2315 }
2316 foreach my $t (qw/dir_prop file_prop/) {
2317 $h = $ed->{$t} or next;
2318 foreach my $path (sort keys %$h) {
2319 my $ppath = $path eq '' ? '.' : $path;
2320 foreach my $prop (sort keys %{$h->{$path}}) {
2321 next if $SKIP_PROP{$prop};
2322 my $v = $h->{$path}->{$prop};
2323 my $t_ppath_prop = "$t: " .
2324 uri_encode($ppath) . ' ' .
2325 uri_encode($prop);
2326 if (defined $v) {
2327 push @out, " +$t_ppath_prop " .
2328 uri_encode($v);
2329 } else {
2330 push @out, " -$t_ppath_prop";
2331 }
2332 }
2333 }
2334 }
2335 foreach my $t (qw/absent_file absent_directory/) {
2336 $h = $ed->{$t} or next;
2337 foreach my $parent (sort keys %$h) {
2338 foreach my $path (sort @{$h->{$parent}}) {
2339 push @out, " $t: " .
2340 uri_encode("$parent/$path");
2341 warn "W: $t: $parent/$path ",
2342 "Insufficient permissions?\n";
2343 }
2344 }
2345 }
2346 \@out;
2347 }
2348
2349 sub parse_svn_date {
2350 my $date = shift || return '+0000 1970-01-01 00:00:00';
2351 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2352 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2353 croak "Unable to parse date: $date\n";
2354 "+0000 $Y-$m-$d $H:$M:$S";
2355 }
2356
2357 sub check_author {
2358 my ($author) = @_;
2359 if (!defined $author || length $author == 0) {
2360 $author = '(no author)';
2361 }
2362 if (defined $::_authors && ! defined $::users{$author}) {
2363 die "Author: $author not defined in $::_authors file\n";
2364 }
2365 $author;
2366 }
2367
2368 sub make_log_entry {
2369 my ($self, $rev, $parents, $ed) = @_;
2370 my $untracked = $self->get_untracked($ed);
2371
2372 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2373 print $un "r$rev\n" or croak $!;
2374 print $un $_, "\n" foreach @$untracked;
2375 my %log_entry = ( parents => $parents || [], revision => $rev,
2376 log => '');
2377
2378 my $headrev;
2379 my $logged = delete $self->{logged_rev_props};
2380 if (!$logged || $self->{-want_revprops}) {
2381 my $rp = $self->ra->rev_proplist($rev);
2382 foreach (sort keys %$rp) {
2383 my $v = $rp->{$_};
2384 if (/^svn:(author|date|log)$/) {
2385 $log_entry{$1} = $v;
2386 } elsif ($_ eq 'svm:headrev') {
2387 $headrev = $v;
2388 } else {
2389 print $un " rev_prop: ", uri_encode($_), ' ',
2390 uri_encode($v), "\n";
2391 }
2392 }
2393 } else {
2394 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2395 }
2396 close $un or croak $!;
2397
2398 $log_entry{date} = parse_svn_date($log_entry{date});
2399 $log_entry{log} .= "\n";
2400 my $author = $log_entry{author} = check_author($log_entry{author});
2401 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2402 : ($author, undef);
2403
2404 my ($commit_name, $commit_email) = ($name, $email);
2405 if ($_use_log_author) {
2406 my $name_field;
2407 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2408 $name_field = $1;
2409 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2410 $name_field = $1;
2411 }
2412 if (!defined $name_field) {
2413 #
2414 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2415 ($name, $email) = ($1, $2);
2416 } elsif ($name_field =~ /(.*)@/) {
2417 ($name, $email) = ($1, $name_field);
2418 } else {
2419 ($name, $email) = ($name_field, 'unknown');
2420 }
2421 }
2422 if (defined $headrev && $self->use_svm_props) {
2423 if ($self->rewrite_root) {
2424 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2425 "options set!\n";
2426 }
2427 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2428 # we don't want "SVM: initializing mirror for junk" ...
2429 return undef if $r == 0;
2430 my $svm = $self->svm;
2431 if ($uuid ne $svm->{uuid}) {
2432 die "UUID mismatch on SVM path:\n",
2433 "expected: $svm->{uuid}\n",
2434 " got: $uuid\n";
2435 }
2436 my $full_url = $self->full_url;
2437 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2438 die "Failed to replace '$svm->{replace}' with ",
2439 "'$svm->{source}' in $full_url\n";
2440 # throw away username for storing in records
2441 remove_username($full_url);
2442 $log_entry{metadata} = "$full_url\@$r $uuid";
2443 $log_entry{svm_revision} = $r;
2444 $email ||= "$author\@$uuid";
2445 $commit_email ||= "$author\@$uuid";
2446 } elsif ($self->use_svnsync_props) {
2447 my $full_url = $self->svnsync->{url};
2448 $full_url .= "/$self->{path}" if length $self->{path};
2449 remove_username($full_url);
2450 my $uuid = $self->svnsync->{uuid};
2451 $log_entry{metadata} = "$full_url\@$rev $uuid";
2452 $email ||= "$author\@$uuid";
2453 $commit_email ||= "$author\@$uuid";
2454 } else {
2455 my $url = $self->metadata_url;
2456 remove_username($url);
2457 $log_entry{metadata} = "$url\@$rev " .
2458 $self->ra->get_uuid;
2459 $email ||= "$author\@" . $self->ra->get_uuid;
2460 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2461 }
2462 $log_entry{name} = $name;
2463 $log_entry{email} = $email;
2464 $log_entry{commit_name} = $commit_name;
2465 $log_entry{commit_email} = $commit_email;
2466 \%log_entry;
2467 }
2468
2469 sub fetch {
2470 my ($self, $min_rev, $max_rev, @parents) = @_;
2471 my ($last_rev, $last_commit) = $self->last_rev_commit;
2472 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2473 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2474 }
2475
2476 sub set_tree_cb {
2477 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2478 $self->{inject_parents} = { $rev => $tree };
2479 $self->fetch(undef, undef);
2480 }
2481
2482 sub set_tree {
2483 my ($self, $tree) = (shift, shift);
2484 my $log_entry = ::get_commit_entry($tree);
2485 unless ($self->{last_rev}) {
2486 fatal("Must have an existing revision to commit");
2487 }
2488 my %ed_opts = ( r => $self->{last_rev},
2489 log => $log_entry->{log},
2490 ra => $self->ra,
2491 tree_a => $self->{last_commit},
2492 tree_b => $tree,
2493 editor_cb => sub {
2494 $self->set_tree_cb($log_entry, $tree, @_) },
2495 svn_path => $self->{path} );
2496 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2497 print "No changes\nr$self->{last_rev} = $tree\n";
2498 }
2499 }
2500
2501 sub rebuild_from_rev_db {
2502 my ($self, $path) = @_;
2503 my $r = -1;
2504 open my $fh, '<', $path or croak "open: $!";
2505 while (<$fh>) {
2506 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2507 chomp($_);
2508 ++$r;
2509 next if $_ eq ('0' x 40);
2510 $self->rev_map_set($r, $_);
2511 print "r$r = $_\n";
2512 }
2513 close $fh or croak "close: $!";
2514 unlink $path or croak "unlink: $!";
2515 }
2516
2517 sub rebuild {
2518 my ($self) = @_;
2519 my $map_path = $self->map_path;
2520 return if (-e $map_path && ! -z $map_path);
2521 return unless ::verify_ref($self->refname.'^0');
2522 if ($self->use_svm_props || $self->no_metadata) {
2523 my $rev_db = $self->rev_db_path;
2524 $self->rebuild_from_rev_db($rev_db);
2525 if ($self->use_svm_props) {
2526 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2527 $self->rebuild_from_rev_db($svm_rev_db);
2528 }
2529 $self->unlink_rev_db_symlink;
2530 return;
2531 }
2532 print "Rebuilding $map_path ...\n";
2533 my ($log, $ctx) =
2534 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2535 $self->refname, '--');
2536 my $full_url = $self->full_url;
2537 remove_username($full_url);
2538 my $svn_uuid = $self->ra_uuid;
2539 my $c;
2540 while (<$log>) {
2541 if ( m{^commit ($::sha1)$} ) {
2542 $c = $1;
2543 next;
2544 }
2545 next unless s{^\s*(git-svn-id:)}{$1};
2546 my ($url, $rev, $uuid) = ::extract_metadata($_);
2547 remove_username($url);
2548
2549 # ignore merges (from set-tree)
2550 next if (!defined $rev || !$uuid);
2551
2552 # if we merged or otherwise started elsewhere, this is
2553 # how we break out of it
2554 if (($uuid ne $svn_uuid) ||
2555 ($full_url && $url && ($url ne $full_url))) {
2556 next;
2557 }
2558
2559 $self->rev_map_set($rev, $c);
2560 print "r$rev = $c\n";
2561 }
2562 command_close_pipe($log, $ctx);
2563 print "Done rebuilding $map_path\n";
2564 my $rev_db_path = $self->rev_db_path;
2565 if (-f $self->rev_db_path) {
2566 unlink $self->rev_db_path or croak "unlink: $!";
2567 }
2568 $self->unlink_rev_db_symlink;
2569 }
2570
2571 # rev_map:
2572 # Tie::File seems to be prone to offset errors if revisions get sparse,
2573 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2574 # one of my favorite modules is out :< Next up would be one of the DBM
2575 # modules, but I'm not sure which is most portable...
2576 #
2577 # This is the replacement for the rev_db format, which was too big
2578 # and inefficient for large repositories with a lot of sparse history
2579 # (mainly tags)
2580 #
2581 # The format is this:
2582 # - 24 bytes for every record,
2583 # * 4 bytes for the integer representing an SVN revision number
2584 # * 20 bytes representing the sha1 of a git commit
2585 # - No empty padding records like the old format
2586 # (except the last record, which can be overwritten)
2587 # - new records are written append-only since SVN revision numbers
2588 # increase monotonically
2589 # - lookups on SVN revision number are done via a binary search
2590 # - Piping the file to xxd -c24 is a good way of dumping it for
2591 # viewing or editing (piped back through xxd -r), should the need
2592 # ever arise.
2593 # - The last record can be padding revision with an all-zero sha1
2594 # This is used to optimize fetch performance when using multiple
2595 # "fetch" directives in .git/config
2596 #
2597 # These files are disposable unless noMetadata or useSvmProps is set
2598
2599 sub _rev_map_set {
2600 my ($fh, $rev, $commit) = @_;
2601
2602 my $size = (stat($fh))[7];
2603 ($size % 24) == 0 or croak "inconsistent size: $size";
2604
2605 my $wr_offset = 0;
2606 if ($size > 0) {
2607 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2608 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2609 $read == 24 or croak "read only $read bytes (!= 24)";
2610 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2611 if ($last_commit eq ('0' x40)) {
2612 if ($size >= 48) {
2613 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2614 $read = sysread($fh, $buf, 24) or
2615 croak "read: $!";
2616 $read == 24 or
2617 croak "read only $read bytes (!= 24)";
2618 ($last_rev, $last_commit) =
2619 unpack(rev_map_fmt, $buf);
2620 if ($last_commit eq ('0' x40)) {
2621 croak "inconsistent .rev_map\n";
2622 }
2623 }
2624 if ($last_rev >= $rev) {
2625 croak "last_rev is higher!: $last_rev >= $rev";
2626 }
2627 $wr_offset = -24;
2628 }
2629 }
2630 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2631 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2632 croak "write: $!";
2633 }
2634
2635 sub mkfile {
2636 my ($path) = @_;
2637 unless (-e $path) {
2638 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2639 mkpath([$dir]) unless -d $dir;
2640 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2641 close $fh or die "Couldn't close (create) $path: $!\n";
2642 }
2643 }
2644
2645 sub rev_map_set {
2646 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2647 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2648 my $db = $self->map_path($uuid);
2649 my $db_lock = "$db.lock";
2650 my $sig;
2651 if ($update_ref) {
2652 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2653 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2654 }
2655 mkfile($db);
2656
2657 $LOCKFILES{$db_lock} = 1;
2658 my $sync;
2659 # both of these options make our .rev_db file very, very important
2660 # and we can't afford to lose it because rebuild() won't work
2661 if ($self->use_svm_props || $self->no_metadata) {
2662 $sync = 1;
2663 copy($db, $db_lock) or die "rev_map_set(@_): ",
2664 "Failed to copy: ",
2665 "$db => $db_lock ($!)\n";
2666 } else {
2667 rename $db, $db_lock or die "rev_map_set(@_): ",
2668 "Failed to rename: ",
2669 "$db => $db_lock ($!)\n";
2670 }
2671
2672 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2673 or croak "Couldn't open $db_lock: $!\n";
2674 _rev_map_set($fh, $rev, $commit);
2675 if ($sync) {
2676 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2677 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2678 }
2679 close $fh or croak $!;
2680 if ($update_ref) {
2681 $_head = $self;
2682 command_noisy('update-ref', '-m', "r$rev",
2683 $self->refname, $commit);
2684 }
2685 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2686 "$db_lock => $db ($!)\n";
2687 delete $LOCKFILES{$db_lock};
2688 if ($update_ref) {
2689 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2690 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2691 kill $sig, $$ if defined $sig;
2692 }
2693 }
2694
2695 # If want_commit, this will return an array of (rev, commit) where
2696 # commit _must_ be a valid commit in the archive.
2697 # Otherwise, it'll return the max revision (whether or not the
2698 # commit is valid or just a 0x40 placeholder).
2699 sub rev_map_max {
2700 my ($self, $want_commit) = @_;
2701 $self->rebuild;
2702 my $map_path = $self->map_path;
2703 stat $map_path or return $want_commit ? (0, undef) : 0;
2704 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2705 my $size = (stat($fh))[7];
2706 ($size % 24) == 0 or croak "inconsistent size: $size";
2707
2708 if ($size == 0) {
2709 close $fh or croak "close: $!";
2710 return $want_commit ? (0, undef) : 0;
2711 }
2712
2713 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2714 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2715 my ($r, $c) = unpack(rev_map_fmt, $buf);
2716 if ($want_commit && $c eq ('0' x40)) {
2717 if ($size < 48) {
2718 return $want_commit ? (0, undef) : 0;
2719 }
2720 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2721 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2722 ($r, $c) = unpack(rev_map_fmt, $buf);
2723 if ($c eq ('0'x40)) {
2724 croak "Penultimate record is all-zeroes in $map_path";
2725 }
2726 }
2727 close $fh or croak "close: $!";
2728 $want_commit ? ($r, $c) : $r;
2729 }
2730
2731 sub rev_map_get {
2732 my ($self, $rev, $uuid) = @_;
2733 my $map_path = $self->map_path($uuid);
2734 return undef unless -e $map_path;
2735
2736 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2737 my $size = (stat($fh))[7];
2738 ($size % 24) == 0 or croak "inconsistent size: $size";
2739
2740 if ($size == 0) {
2741 close $fh or croak "close: $fh";
2742 return undef;
2743 }
2744
2745 my ($l, $u) = (0, $size - 24);
2746 my ($r, $c, $buf);
2747
2748 while ($l <= $u) {
2749 my $i = int(($l/24 + $u/24) / 2) * 24;
2750 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2751 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2752 my ($r, $c) = unpack('NH40', $buf);
2753
2754 if ($r < $rev) {
2755 $l = $i + 24;
2756 } elsif ($r > $rev) {
2757 $u = $i - 24;
2758 } else { # $r == $rev
2759 close($fh) or croak "close: $!";
2760 return $c eq ('0' x 40) ? undef : $c;
2761 }
2762 }
2763 close($fh) or croak "close: $!";
2764 undef;
2765 }
2766
2767 # Finds the first svn revision that exists on (if $eq_ok is true) or
2768 # before $rev for the current branch. It will not search any lower
2769 # than $min_rev. Returns the git commit hash and svn revision number
2770 # if found, else (undef, undef).
2771 sub find_rev_before {
2772 my ($self, $rev, $eq_ok, $min_rev) = @_;
2773 --$rev unless $eq_ok;
2774 $min_rev ||= 1;
2775 while ($rev >= $min_rev) {
2776 if (my $c = $self->rev_map_get($rev)) {
2777 return ($rev, $c);
2778 }
2779 --$rev;
2780 }
2781 return (undef, undef);
2782 }
2783
2784 # Finds the first svn revision that exists on (if $eq_ok is true) or
2785 # after $rev for the current branch. It will not search any higher
2786 # than $max_rev. Returns the git commit hash and svn revision number
2787 # if found, else (undef, undef).
2788 sub find_rev_after {
2789 my ($self, $rev, $eq_ok, $max_rev) = @_;
2790 ++$rev unless $eq_ok;
2791 $max_rev ||= $self->rev_map_max;
2792 while ($rev <= $max_rev) {
2793 if (my $c = $self->rev_map_get($rev)) {
2794 return ($rev, $c);
2795 }
2796 ++$rev;
2797 }
2798 return (undef, undef);
2799 }
2800
2801 sub _new {
2802 my ($class, $repo_id, $ref_id, $path) = @_;
2803 unless (defined $repo_id && length $repo_id) {
2804 $repo_id = $Git::SVN::default_repo_id;
2805 }
2806 unless (defined $ref_id && length $ref_id) {
2807 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2808 }
2809 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2810 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2811 $_[3] = $path = '' unless (defined $path);
2812 mkpath(["$ENV{GIT_DIR}/svn"]);
2813 bless {
2814 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2815 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2816 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2817 }
2818
2819 # for read-only access of old .rev_db formats
2820 sub unlink_rev_db_symlink {
2821 my ($self) = @_;
2822 my $link = $self->rev_db_path;
2823 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2824 if (-l $link) {
2825 unlink $link or croak "unlink: $link failed!";
2826 }
2827 }
2828
2829 sub rev_db_path {
2830 my ($self, $uuid) = @_;
2831 my $db_path = $self->map_path($uuid);
2832 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2833 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2834 $db_path;
2835 }
2836
2837 # the new replacement for .rev_db
2838 sub map_path {
2839 my ($self, $uuid) = @_;
2840 $uuid ||= $self->ra_uuid;
2841 "$self->{map_root}.$uuid";
2842 }
2843
2844 sub uri_encode {
2845 my ($f) = @_;
2846 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2847 $f
2848 }
2849
2850 sub remove_username {
2851 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2852 }
2853
2854 package Git::SVN::Prompt;
2855 use strict;
2856 use warnings;
2857 require SVN::Core;
2858 use vars qw/$_no_auth_cache $_username/;
2859
2860 sub simple {
2861 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2862 $may_save = undef if $_no_auth_cache;
2863 $default_username = $_username if defined $_username;
2864 if (defined $default_username && length $default_username) {
2865 if (defined $realm && length $realm) {
2866 print STDERR "Authentication realm: $realm\n";
2867 STDERR->flush;
2868 }
2869 $cred->username($default_username);
2870 } else {
2871 username($cred, $realm, $may_save, $pool);
2872 }
2873 $cred->password(_read_password("Password for '" .
2874 $cred->username . "': ", $realm));
2875 $cred->may_save($may_save);
2876 $SVN::_Core::SVN_NO_ERROR;
2877 }
2878
2879 sub ssl_server_trust {
2880 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2881 $may_save = undef if $_no_auth_cache;
2882 print STDERR "Error validating server certificate for '$realm':\n";
2883 {
2884 no warnings 'once';
2885 # All variables SVN::Auth::SSL::* are used only once,
2886 # so we're shutting up Perl warnings about this.
2887 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2888 print STDERR " - The certificate is not issued ",
2889 "by a trusted authority. Use the\n",
2890 " fingerprint to validate ",
2891 "the certificate manually!\n";
2892 }
2893 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2894 print STDERR " - The certificate hostname ",
2895 "does not match.\n";
2896 }
2897 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2898 print STDERR " - The certificate is not yet valid.\n";
2899 }
2900 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2901 print STDERR " - The certificate has expired.\n";
2902 }
2903 if ($failures & $SVN::Auth::SSL::OTHER) {
2904 print STDERR " - The certificate has ",
2905 "an unknown error.\n";
2906 }
2907 } # no warnings 'once'
2908 printf STDERR
2909 "Certificate information:\n".
2910 " - Hostname: %s\n".
2911 " - Valid: from %s until %s\n".
2912 " - Issuer: %s\n".
2913 " - Fingerprint: %s\n",
2914 map $cert_info->$_, qw(hostname valid_from valid_until
2915 issuer_dname fingerprint);
2916 my $choice;
2917 prompt:
2918 print STDERR $may_save ?
2919 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2920 "(R)eject or accept (t)emporarily? ";
2921 STDERR->flush;
2922 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2923 if ($choice =~ /^t$/i) {
2924 $cred->may_save(undef);
2925 } elsif ($choice =~ /^r$/i) {
2926 return -1;
2927 } elsif ($may_save && $choice =~ /^p$/i) {
2928 $cred->may_save($may_save);
2929 } else {
2930 goto prompt;
2931 }
2932 $cred->accepted_failures($failures);
2933 $SVN::_Core::SVN_NO_ERROR;
2934 }
2935
2936 sub ssl_client_cert {
2937 my ($cred, $realm, $may_save, $pool) = @_;
2938 $may_save = undef if $_no_auth_cache;
2939 print STDERR "Client certificate filename: ";
2940 STDERR->flush;
2941 chomp(my $filename = <STDIN>);
2942 $cred->cert_file($filename);
2943 $cred->may_save($may_save);
2944 $SVN::_Core::SVN_NO_ERROR;
2945 }
2946
2947 sub ssl_client_cert_pw {
2948 my ($cred, $realm, $may_save, $pool) = @_;
2949 $may_save = undef if $_no_auth_cache;
2950 $cred->password(_read_password("Password: ", $realm));
2951 $cred->may_save($may_save);
2952 $SVN::_Core::SVN_NO_ERROR;
2953 }
2954
2955 sub username {
2956 my ($cred, $realm, $may_save, $pool) = @_;
2957 $may_save = undef if $_no_auth_cache;
2958 if (defined $realm && length $realm) {
2959 print STDERR "Authentication realm: $realm\n";
2960 }
2961 my $username;
2962 if (defined $_username) {
2963 $username = $_username;
2964 } else {
2965 print STDERR "Username: ";
2966 STDERR->flush;
2967 chomp($username = <STDIN>);
2968 }
2969 $cred->username($username);
2970 $cred->may_save($may_save);
2971 $SVN::_Core::SVN_NO_ERROR;
2972 }
2973
2974 sub _read_password {
2975 my ($prompt, $realm) = @_;
2976 print STDERR $prompt;
2977 STDERR->flush;
2978 require Term::ReadKey;
2979 Term::ReadKey::ReadMode('noecho');
2980 my $password = '';
2981 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2982 last if $key =~ /[\012\015]/; # \n\r
2983 $password .= $key;
2984 }
2985 Term::ReadKey::ReadMode('restore');
2986 print STDERR "\n";
2987 STDERR->flush;
2988 $password;
2989 }
2990
2991 package SVN::Git::Fetcher;
2992 use vars qw/@ISA/;
2993 use strict;
2994 use warnings;
2995 use Carp qw/croak/;
2996 use IO::File qw//;
2997
2998 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2999 sub new {
3000 my ($class, $git_svn) = @_;
3001 my $self = SVN::Delta::Editor->new;
3002 bless $self, $class;
3003 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3004 $self->{empty} = {};
3005 $self->{dir_prop} = {};
3006 $self->{file_prop} = {};
3007 $self->{absent_dir} = {};
3008 $self->{absent_file} = {};
3009 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3010 $self;
3011 }
3012
3013 sub set_path_strip {
3014 my ($self, $path) = @_;
3015 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3016 }
3017
3018 sub open_root {
3019 { path => '' };
3020 }
3021
3022 sub open_directory {
3023 my ($self, $path, $pb, $rev) = @_;
3024 { path => $path };
3025 }
3026
3027 sub git_path {
3028 my ($self, $path) = @_;
3029 if ($self->{path_strip}) {
3030 $path =~ s!$self->{path_strip}!! or
3031 die "Failed to strip path '$path' ($self->{path_strip})\n";
3032 }
3033 $path;
3034 }
3035
3036 sub delete_entry {
3037 my ($self, $path, $rev, $pb) = @_;
3038
3039 my $gpath = $self->git_path($path);
3040 return undef if ($gpath eq '');
3041
3042 # remove entire directories.
3043 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3044 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3045 -r --name-only -z/,
3046 $self->{c}, '--', $gpath);
3047 local $/ = "\0";
3048 while (<$ls>) {
3049 chomp;
3050 $self->{gii}->remove($_);
3051 print "\tD\t$_\n" unless $::_q;
3052 }
3053 print "\tD\t$gpath/\n" unless $::_q;
3054 command_close_pipe($ls, $ctx);
3055 $self->{empty}->{$path} = 0
3056 } else {
3057 $self->{gii}->remove($gpath);
3058 print "\tD\t$gpath\n" unless $::_q;
3059 }
3060 undef;
3061 }
3062
3063 sub open_file {
3064 my ($self, $path, $pb, $rev) = @_;
3065 my $gpath = $self->git_path($path);
3066 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3067 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3068 unless (defined $mode && defined $blob) {
3069 die "$path was not found in commit $self->{c} (r$rev)\n";
3070 }
3071 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3072 pool => SVN::Pool->new, action => 'M' };
3073 }
3074
3075 sub add_file {
3076 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3077 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3078 delete $self->{empty}->{$dir};
3079 { path => $path, mode_a => 100644, mode_b => 100644,
3080 pool => SVN::Pool->new, action => 'A' };
3081 }
3082
3083 sub add_directory {
3084 my ($self, $path, $cp_path, $cp_rev) = @_;
3085 my $gpath = $self->git_path($path);
3086 if ($gpath eq '') {
3087 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3088 -r --name-only -z/,
3089 $self->{c});
3090 local $/ = "\0";
3091 while (<$ls>) {
3092 chomp;
3093 $self->{gii}->remove($_);
3094 print "\tD\t$_\n" unless $::_q;
3095 }
3096 command_close_pipe($ls, $ctx);
3097 $self->{empty}->{$path} = 0;
3098 }
3099 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3100 delete $self->{empty}->{$dir};
3101 $self->{empty}->{$path} = 1;
3102 { path => $path };
3103 }
3104
3105 sub change_dir_prop {
3106 my ($self, $db, $prop, $value) = @_;
3107 $self->{dir_prop}->{$db->{path}} ||= {};
3108 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3109 undef;
3110 }
3111
3112 sub absent_directory {
3113 my ($self, $path, $pb) = @_;
3114 $self->{absent_dir}->{$pb->{path}} ||= [];
3115 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3116 undef;
3117 }
3118
3119 sub absent_file {
3120 my ($self, $path, $pb) = @_;
3121 $self->{absent_file}->{$pb->{path}} ||= [];
3122 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3123 undef;
3124 }
3125
3126 sub change_file_prop {
3127 my ($self, $fb, $prop, $value) = @_;
3128 if ($prop eq 'svn:executable') {
3129 if ($fb->{mode_b} != 120000) {
3130 $fb->{mode_b} = defined $value ? 100755 : 100644;
3131 }
3132 } elsif ($prop eq 'svn:special') {
3133 $fb->{mode_b} = defined $value ? 120000 : 100644;
3134 } else {
3135 $self->{file_prop}->{$fb->{path}} ||= {};
3136 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3137 }
3138 undef;
3139 }
3140
3141 sub apply_textdelta {
3142 my ($self, $fb, $exp) = @_;
3143 my $fh = IO::File->new_tmpfile;
3144 $fh->autoflush(1);
3145 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3146 # (but $base does not,) so dup() it for reading in close_file
3147 open my $dup, '<&', $fh or croak $!;
3148 my $base = IO::File->new_tmpfile;
3149 $base->autoflush(1);
3150 if ($fb->{blob}) {
3151 defined (my $pid = fork) or croak $!;
3152 if (!$pid) {
3153 open STDOUT, '>&', $base or croak $!;
3154 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3155 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3156 }
3157 waitpid $pid, 0;
3158 croak $? if $?;
3159
3160 if (defined $exp) {
3161 seek $base, 0, 0 or croak $!;
3162 my $got = ::md5sum($base);
3163 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3164 "expected: $exp\n",
3165 " got: $got\n" if ($got ne $exp);
3166 }
3167 }
3168 seek $base, 0, 0 or croak $!;
3169 $fb->{fh} = $dup;
3170 $fb->{base} = $base;
3171 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3172 }
3173
3174 sub close_file {
3175 my ($self, $fb, $exp) = @_;
3176 my $hash;
3177 my $path = $self->git_path($fb->{path});
3178 if (my $fh = $fb->{fh}) {
3179 if (defined $exp) {
3180 seek($fh, 0, 0) or croak $!;
3181 my $got = ::md5sum($fh);
3182 if ($got ne $exp) {
3183 die "Checksum mismatch: $path\n",
3184 "expected: $exp\n got: $got\n";
3185 }
3186 }
3187 sysseek($fh, 0, 0) or croak $!;
3188 if ($fb->{mode_b} == 120000) {
3189 eval {
3190 sysread($fh, my $buf, 5) == 5 or croak $!;
3191 $buf eq 'link ' or die "$path has mode 120000",
3192 " but is not a link";
3193 };
3194 if ($@) {
3195 warn "$@\n";
3196 sysseek($fh, 0, 0) or croak $!;
3197 }
3198 }
3199 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3200 if (!$pid) {
3201 open STDIN, '<&', $fh or croak $!;
3202 exec qw/git-hash-object -w --stdin/ or croak $!;
3203 }
3204 chomp($hash = do { local $/; <$out> });
3205 close $out or croak $!;
3206 close $fh or croak $!;
3207 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3208 close $fb->{base} or croak $!;
3209 } else {
3210 $hash = $fb->{blob} or die "no blob information\n";
3211 }
3212 $fb->{pool}->clear;
3213 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3214 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3215 undef;
3216 }
3217
3218 sub abort_edit {
3219 my $self = shift;
3220 $self->{nr} = $self->{gii}->{nr};
3221 delete $self->{gii};
3222 $self->SUPER::abort_edit(@_);
3223 }
3224
3225 sub close_edit {
3226 my $self = shift;
3227 $self->{git_commit_ok} = 1;
3228 $self->{nr} = $self->{gii}->{nr};
3229 delete $self->{gii};
3230 $self->SUPER::close_edit(@_);
3231 }
3232
3233 package SVN::Git::Editor;
3234 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3235 use strict;
3236 use warnings;
3237 use Carp qw/croak/;
3238 use IO::File;
3239
3240 sub new {
3241 my ($class, $opts) = @_;
3242 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3243 die "$_ required!\n" unless (defined $opts->{$_});
3244 }
3245
3246 my $pool = SVN::Pool->new;
3247 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3248 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3249 $opts->{r}, $mods);
3250
3251 # $opts->{ra} functions should not be used after this:
3252 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3253 $opts->{editor_cb}, $pool);
3254 my $self = SVN::Delta::Editor->new(@ce, $pool);
3255 bless $self, $class;
3256 foreach (qw/svn_path r tree_a tree_b/) {
3257 $self->{$_} = $opts->{$_};
3258 }
3259 $self->{url} = $opts->{ra}->{url};
3260 $self->{mods} = $mods;
3261 $self->{types} = $types;
3262 $self->{pool} = $pool;
3263 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3264 $self->{rm} = { };
3265 $self->{path_prefix} = length $self->{svn_path} ?
3266 "$self->{svn_path}/" : '';
3267 return $self;
3268 }
3269
3270 sub generate_diff {
3271 my ($tree_a, $tree_b) = @_;
3272 my @diff_tree = qw(diff-tree -z -r);
3273 if ($_cp_similarity) {
3274 push @diff_tree, "-C$_cp_similarity";
3275 } else {
3276 push @diff_tree, '-C';
3277 }
3278 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3279 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3280 push @diff_tree, $tree_a, $tree_b;
3281 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3282 local $/ = "\0";
3283 my $state = 'meta';
3284 my @mods;
3285 while (<$diff_fh>) {
3286 chomp $_; # this gets rid of the trailing "\0"
3287 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3288 $::sha1\s($::sha1)\s
3289 ([MTCRAD])\d*$/xo) {
3290 push @mods, { mode_a => $1, mode_b => $2,
3291 sha1_b => $3, chg => $4 };
3292 if ($4 =~ /^(?:C|R)$/) {
3293 $state = 'file_a';
3294 } else {
3295 $state = 'file_b';
3296 }
3297 } elsif ($state eq 'file_a') {
3298 my $x = $mods[$#mods] or croak "Empty array\n";
3299 if ($x->{chg} !~ /^(?:C|R)$/) {
3300 croak "Error parsing $_, $x->{chg}\n";
3301 }
3302 $x->{file_a} = $_;
3303 $state = 'file_b';
3304 } elsif ($state eq 'file_b') {
3305 my $x = $mods[$#mods] or croak "Empty array\n";
3306 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3307 croak "Error parsing $_, $x->{chg}\n";
3308 }
3309 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3310 croak "Error parsing $_, $x->{chg}\n";
3311 }
3312 $x->{file_b} = $_;
3313 $state = 'meta';
3314 } else {
3315 croak "Error parsing $_\n";
3316 }
3317 }
3318 command_close_pipe($diff_fh, $ctx);
3319 \@mods;
3320 }
3321
3322 sub check_diff_paths {
3323 my ($ra, $pfx, $rev, $mods) = @_;
3324 my %types;
3325 $pfx .= '/' if length $pfx;
3326
3327 sub type_diff_paths {
3328 my ($ra, $types, $path, $rev) = @_;
3329 my @p = split m#/+#, $path;
3330 my $c = shift @p;
3331 unless (defined $types->{$c}) {
3332 $types->{$c} = $ra->check_path($c, $rev);
3333 }
3334 while (@p) {
3335 $c .= '/' . shift @p;
3336 next if defined $types->{$c};
3337 $types->{$c} = $ra->check_path($c, $rev);
3338 }
3339 }
3340
3341 foreach my $m (@$mods) {
3342 foreach my $f (qw/file_a file_b/) {
3343 next unless defined $m->{$f};
3344 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3345 if (length $pfx.$dir && ! defined $types{$dir}) {
3346 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3347 }
3348 }
3349 }
3350 \%types;
3351 }
3352
3353 sub split_path {
3354 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3355 }
3356
3357 sub repo_path {
3358 my ($self, $path) = @_;
3359 $self->{path_prefix}.(defined $path ? $path : '');
3360 }
3361
3362 sub url_path {
3363 my ($self, $path) = @_;
3364 if ($self->{url} =~ m#^https?://#) {
3365 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3366 }
3367 $self->{url} . '/' . $self->repo_path($path);
3368 }
3369
3370 sub rmdirs {
3371 my ($self) = @_;
3372 my $rm = $self->{rm};
3373 delete $rm->{''}; # we never delete the url we're tracking
3374 return unless %$rm;
3375
3376 foreach (keys %$rm) {
3377 my @d = split m#/#, $_;
3378 my $c = shift @d;
3379 $rm->{$c} = 1;
3380 while (@d) {
3381 $c .= '/' . shift @d;
3382 $rm->{$c} = 1;
3383 }
3384 }
3385 delete $rm->{$self->{svn_path}};
3386 delete $rm->{''}; # we never delete the url we're tracking
3387 return unless %$rm;
3388
3389 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3390 $self->{tree_b});
3391 local $/ = "\0";
3392 while (<$fh>) {
3393 chomp;
3394 my @dn = split m#/#, $_;
3395 while (pop @dn) {
3396 delete $rm->{join '/', @dn};
3397 }
3398 unless (%$rm) {
3399 close $fh;
3400 return;
3401 }
3402 }
3403 command_close_pipe($fh, $ctx);
3404
3405 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3406 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3407 $self->close_directory($bat->{$d}, $p);
3408 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3409 print "\tD+\t$d/\n" unless $::_q;
3410 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3411 delete $bat->{$d};
3412 }
3413 }
3414
3415 sub open_or_add_dir {
3416 my ($self, $full_path, $baton) = @_;
3417 my $t = $self->{types}->{$full_path};
3418 if (!defined $t) {
3419 die "$full_path not known in r$self->{r} or we have a bug!\n";
3420 }
3421 {
3422 no warnings 'once';
3423 # SVN::Node::none and SVN::Node::file are used only once,
3424 # so we're shutting up Perl's warnings about them.
3425 if ($t == $SVN::Node::none) {
3426 return $self->add_directory($full_path, $baton,
3427 undef, -1, $self->{pool});
3428 } elsif ($t == $SVN::Node::dir) {
3429 return $self->open_directory($full_path, $baton,
3430 $self->{r}, $self->{pool});
3431 } # no warnings 'once'
3432 print STDERR "$full_path already exists in repository at ",
3433 "r$self->{r} and it is not a directory (",
3434 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3435 } # no warnings 'once'
3436 exit 1;
3437 }
3438
3439 sub ensure_path {
3440 my ($self, $path) = @_;
3441 my $bat = $self->{bat};
3442 my $repo_path = $self->repo_path($path);
3443 return $bat->{''} unless (length $repo_path);
3444 my @p = split m#/+#, $repo_path;
3445 my $c = shift @p;
3446 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3447 while (@p) {
3448 my $c0 = $c;
3449 $c .= '/' . shift @p;
3450 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3451 }
3452 return $bat->{$c};
3453 }
3454
3455 sub A {
3456 my ($self, $m) = @_;
3457 my ($dir, $file) = split_path($m->{file_b});
3458 my $pbat = $self->ensure_path($dir);
3459 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3460 undef, -1);
3461 print "\tA\t$m->{file_b}\n" unless $::_q;
3462 $self->chg_file($fbat, $m);
3463 $self->close_file($fbat,undef,$self->{pool});
3464 }
3465
3466 sub C {
3467 my ($self, $m) = @_;
3468 my ($dir, $file) = split_path($m->{file_b});
3469 my $pbat = $self->ensure_path($dir);
3470 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3471 $self->url_path($m->{file_a}), $self->{r});
3472 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3473 $self->chg_file($fbat, $m);
3474 $self->close_file($fbat,undef,$self->{pool});
3475 }
3476
3477 sub delete_entry {
3478 my ($self, $path, $pbat) = @_;
3479 my $rpath = $self->repo_path($path);
3480 my ($dir, $file) = split_path($rpath);
3481 $self->{rm}->{$dir} = 1;
3482 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3483 }
3484
3485 sub R {
3486 my ($self, $m) = @_;
3487 my ($dir, $file) = split_path($m->{file_b});
3488 my $pbat = $self->ensure_path($dir);
3489 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3490 $self->url_path($m->{file_a}), $self->{r});
3491 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3492 $self->chg_file($fbat, $m);
3493 $self->close_file($fbat,undef,$self->{pool});
3494
3495 ($dir, $file) = split_path($m->{file_a});
3496 $pbat = $self->ensure_path($dir);
3497 $self->delete_entry($m->{file_a}, $pbat);
3498 }
3499
3500 sub M {
3501 my ($self, $m) = @_;
3502 my ($dir, $file) = split_path($m->{file_b});
3503 my $pbat = $self->ensure_path($dir);
3504 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3505 $pbat,$self->{r},$self->{pool});
3506 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3507 $self->chg_file($fbat, $m);
3508 $self->close_file($fbat,undef,$self->{pool});
3509 }
3510
3511 sub T { shift->M(@_) }
3512
3513 sub change_file_prop {
3514 my ($self, $fbat, $pname, $pval) = @_;
3515 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3516 }
3517
3518 sub chg_file {
3519 my ($self, $fbat, $m) = @_;
3520 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3521 $self->change_file_prop($fbat,'svn:executable','*');
3522 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3523 $self->change_file_prop($fbat,'svn:executable',undef);
3524 }
3525 my $fh = IO::File->new_tmpfile or croak $!;
3526 if ($m->{mode_b} =~ /^120/) {
3527 print $fh 'link ' or croak $!;
3528 $self->change_file_prop($fbat,'svn:special','*');
3529 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3530 $self->change_file_prop($fbat,'svn:special',undef);
3531 }
3532 defined(my $pid = fork) or croak $!;
3533 if (!$pid) {
3534 open STDOUT, '>&', $fh or croak $!;
3535 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3536 }
3537 waitpid $pid, 0;
3538 croak $? if $?;
3539 $fh->flush == 0 or croak $!;
3540 seek $fh, 0, 0 or croak $!;
3541
3542 my $exp = ::md5sum($fh);
3543 seek $fh, 0, 0 or croak $!;
3544
3545 my $pool = SVN::Pool->new;
3546 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3547 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3548 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3549 $pool->clear;
3550
3551 close $fh or croak $!;
3552 }
3553
3554 sub D {
3555 my ($self, $m) = @_;
3556 my ($dir, $file) = split_path($m->{file_b});
3557 my $pbat = $self->ensure_path($dir);
3558 print "\tD\t$m->{file_b}\n" unless $::_q;
3559 $self->delete_entry($m->{file_b}, $pbat);
3560 }
3561
3562 sub close_edit {
3563 my ($self) = @_;
3564 my ($p,$bat) = ($self->{pool}, $self->{bat});
3565 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3566 next if $_ eq '';
3567 $self->close_directory($bat->{$_}, $p);
3568 }
3569 $self->close_directory($bat->{''}, $p);
3570 $self->SUPER::close_edit($p);
3571 $p->clear;
3572 }
3573
3574 sub abort_edit {
3575 my ($self) = @_;
3576 $self->SUPER::abort_edit($self->{pool});
3577 }
3578
3579 sub DESTROY {
3580 my $self = shift;
3581 $self->SUPER::DESTROY(@_);
3582 $self->{pool}->clear;
3583 }
3584
3585 # this drives the editor
3586 sub apply_diff {
3587 my ($self) = @_;
3588 my $mods = $self->{mods};
3589 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3590 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3591 my $f = $m->{chg};
3592 if (defined $o{$f}) {
3593 $self->$f($m);
3594 } else {
3595 fatal("Invalid change type: $f");
3596 }
3597 }
3598 $self->rmdirs if $_rmdir;
3599 if (@$mods == 0) {
3600 $self->abort_edit;
3601 } else {
3602 $self->close_edit;
3603 }
3604 return scalar @$mods;
3605 }
3606
3607 package Git::SVN::Ra;
3608 use vars qw/@ISA $config_dir $_log_window_size/;
3609 use strict;
3610 use warnings;
3611 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3612
3613 BEGIN {
3614 # enforce temporary pool usage for some simple functions
3615 no strict 'refs';
3616 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3617 my $SUPER = "SUPER::$f";
3618 *$f = sub {
3619 my $self = shift;
3620 my $pool = SVN::Pool->new;
3621 my @ret = $self->$SUPER(@_,$pool);
3622 $pool->clear;
3623 wantarray ? @ret : $ret[0];
3624 };
3625 }
3626 }
3627
3628 sub _auth_providers () {
3629 [
3630 SVN::Client::get_simple_provider(),
3631 SVN::Client::get_ssl_server_trust_file_provider(),
3632 SVN::Client::get_simple_prompt_provider(
3633 \&Git::SVN::Prompt::simple, 2),
3634 SVN::Client::get_ssl_client_cert_file_provider(),
3635 SVN::Client::get_ssl_client_cert_prompt_provider(
3636 \&Git::SVN::Prompt::ssl_client_cert, 2),
3637 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3638 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3639 SVN::Client::get_username_provider(),
3640 SVN::Client::get_ssl_server_trust_prompt_provider(
3641 \&Git::SVN::Prompt::ssl_server_trust),
3642 SVN::Client::get_username_prompt_provider(
3643 \&Git::SVN::Prompt::username, 2)
3644 ]
3645 }
3646
3647 sub escape_uri_only {
3648 my ($uri) = @_;
3649 my @tmp;
3650 foreach (split m{/}, $uri) {
3651 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3652 push @tmp, $_;
3653 }
3654 join('/', @tmp);
3655 }
3656
3657 sub escape_url {
3658 my ($url) = @_;
3659 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3660 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3661 $url = "$scheme://$domain$uri";
3662 }
3663 $url;
3664 }
3665
3666 sub new {
3667 my ($class, $url) = @_;
3668 $url =~ s!/+$!!;
3669 return $RA if ($RA && $RA->{url} eq $url);
3670
3671 SVN::_Core::svn_config_ensure($config_dir, undef);
3672 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3673 my $config = SVN::Core::config_get_config($config_dir);
3674 $RA = undef;
3675 my $dont_store_passwords = 1;
3676 my $conf_t = ${$config}{'config'};
3677 {
3678 no warnings 'once';
3679 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3680 # produces warnings that variables are used only once.
3681 # I had not found the better way to shut them up, so
3682 # the warnings of type 'once' are disabled in this block.
3683 if (SVN::_Core::svn_config_get_bool($conf_t,
3684 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3685 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3686 1) == 0) {
3687 SVN::_Core::svn_auth_set_parameter($baton,
3688 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3689 bless (\$dont_store_passwords, "_p_void"));
3690 }
3691 if (SVN::_Core::svn_config_get_bool($conf_t,
3692 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3693 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3694 1) == 0) {
3695 $Git::SVN::Prompt::_no_auth_cache = 1;
3696 }
3697 } # no warnings 'once'
3698 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3699 config => $config,
3700 pool => SVN::Pool->new,
3701 auth_provider_callbacks => $callbacks);
3702 $self->{url} = $url;
3703 $self->{svn_path} = $url;
3704 $self->{repos_root} = $self->get_repos_root;
3705 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3706 $self->{cache} = { check_path => { r => 0, data => {} },
3707 get_dir => { r => 0, data => {} } };
3708 $RA = bless $self, $class;
3709 }
3710
3711 sub check_path {
3712 my ($self, $path, $r) = @_;
3713 my $cache = $self->{cache}->{check_path};
3714 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3715 return $cache->{data}->{$path};
3716 }
3717 my $pool = SVN::Pool->new;
3718 my $t = $self->SUPER::check_path($path, $r, $pool);
3719 $pool->clear;
3720 if ($r != $cache->{r}) {
3721 %{$cache->{data}} = ();
3722 $cache->{r} = $r;
3723 }
3724 $cache->{data}->{$path} = $t;
3725 }
3726
3727 sub get_dir {
3728 my ($self, $dir, $r) = @_;
3729 my $cache = $self->{cache}->{get_dir};
3730 if ($r == $cache->{r}) {
3731 if (my $x = $cache->{data}->{$dir}) {
3732 return wantarray ? @$x : $x->[0];
3733 }
3734 }
3735 my $pool = SVN::Pool->new;
3736 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3737 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3738 $pool->clear;
3739 if ($r != $cache->{r}) {
3740 %{$cache->{data}} = ();
3741 $cache->{r} = $r;
3742 }
3743 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3744 wantarray ? (\%dirents, $r, $props) : \%dirents;
3745 }
3746
3747 sub DESTROY {
3748 # do not call the real DESTROY since we store ourselves in $RA
3749 }
3750
3751 sub get_log {
3752 my ($self, @args) = @_;
3753 my $pool = SVN::Pool->new;
3754 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3755 my $ret = $self->SUPER::get_log(@args, $pool);
3756 $pool->clear;
3757 $ret;
3758 }
3759
3760 sub trees_match {
3761 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3762 my $ctx = SVN::Client->new(auth => _auth_providers);
3763 my $out = IO::File->new_tmpfile;
3764
3765 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3766 # $ctx->diff(), so we'll create a default one
3767 my $pool = SVN::Pool->new_default_sub;
3768
3769 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3770 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3771 $out->flush;
3772 my $ret = (($out->stat)[7] == 0);
3773 close $out or croak $!;
3774
3775 $ret;
3776 }
3777
3778 sub get_commit_editor {
3779 my ($self, $log, $cb, $pool) = @_;
3780 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3781 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3782 }
3783
3784 sub gs_do_update {
3785 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3786 my $new = ($rev_a == $rev_b);
3787 my $path = $gs->{path};
3788
3789 if ($new && -e $gs->{index}) {
3790 unlink $gs->{index} or die
3791 "Couldn't unlink index: $gs->{index}: $!\n";
3792 }
3793 my $pool = SVN::Pool->new;
3794 $editor->set_path_strip($path);
3795 my (@pc) = split m#/#, $path;
3796 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3797 1, $editor, $pool);
3798 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3799
3800 # Since we can't rely on svn_ra_reparent being available, we'll
3801 # just have to do some magic with set_path to make it so
3802 # we only want a partial path.
3803 my $sp = '';
3804 my $final = join('/', @pc);
3805 while (@pc) {
3806 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3807 $sp .= '/' if length $sp;
3808 $sp .= shift @pc;
3809 }
3810 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3811
3812 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3813
3814 $reporter->finish_report($pool);
3815 $pool->clear;
3816 $editor->{git_commit_ok};
3817 }
3818
3819 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3820 # svn_ra_reparent didn't work before 1.4)
3821 sub gs_do_switch {
3822 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3823 my $path = $gs->{path};
3824 my $pool = SVN::Pool->new;
3825
3826 my $full_url = $self->{url};
3827 my $old_url = $full_url;
3828 $full_url .= '/' . escape_uri_only($path) if length $path;
3829 my ($ra, $reparented);
3830 if ($old_url ne $full_url) {
3831 if ($old_url !~ m#^svn(\+ssh)?://#) {
3832 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3833 $pool);
3834 $self->{url} = $full_url;
3835 $reparented = 1;
3836 } else {
3837 $_[0] = undef;
3838 $self = undef;
3839 $RA = undef;
3840 $ra = Git::SVN::Ra->new($full_url);
3841 $ra_invalid = 1;
3842 }
3843 }
3844 $ra ||= $self;
3845 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3846 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3847 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3848 $reporter->finish_report($pool);
3849
3850 if ($reparented) {
3851 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3852 $self->{url} = $old_url;
3853 }
3854
3855 $pool->clear;
3856 $editor->{git_commit_ok};
3857 }
3858
3859 sub longest_common_path {
3860 my ($gsv, $globs) = @_;
3861 my %common;
3862 my $common_max = scalar @$gsv;
3863
3864 foreach my $gs (@$gsv) {
3865 my @tmp = split m#/#, $gs->{path};
3866 my $p = '';
3867 foreach (@tmp) {
3868 $p .= length($p) ? "/$_" : $_;
3869 $common{$p} ||= 0;
3870 $common{$p}++;
3871 }
3872 }
3873 $globs ||= [];
3874 $common_max += scalar @$globs;
3875 foreach my $glob (@$globs) {
3876 my @tmp = split m#/#, $glob->{path}->{left};
3877 my $p = '';
3878 foreach (@tmp) {
3879 $p .= length($p) ? "/$_" : $_;
3880 $common{$p} ||= 0;
3881 $common{$p}++;
3882 }
3883 }
3884
3885 my $longest_path = '';
3886 foreach (sort {length $b <=> length $a} keys %common) {
3887 if ($common{$_} == $common_max) {
3888 $longest_path = $_;
3889 last;
3890 }
3891 }
3892 $longest_path;
3893 }
3894
3895 sub gs_fetch_loop_common {
3896 my ($self, $base, $head, $gsv, $globs) = @_;
3897 return if ($base > $head);
3898 my $inc = $_log_window_size;
3899 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3900 my $longest_path = longest_common_path($gsv, $globs);
3901 my $ra_url = $self->{url};
3902 while (1) {
3903 my %revs;
3904 my $err;
3905 my $err_handler = $SVN::Error::handler;
3906 $SVN::Error::handler = sub {
3907 ($err) = @_;
3908 skip_unknown_revs($err);
3909 };
3910 sub _cb {
3911 my ($paths, $r, $author, $date, $log) = @_;
3912 [ dup_changed_paths($paths),
3913 { author => $author, date => $date, log => $log } ];
3914 }
3915 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3916 sub { $revs{$_[1]} = _cb(@_) });
3917 if ($err && $max >= $head) {
3918 print STDERR "Path '$longest_path' ",
3919 "was probably deleted:\n",
3920 $err->expanded_message,
3921 "\nWill attempt to follow ",
3922 "revisions r$min .. r$max ",
3923 "committed before the deletion\n";
3924 my $hi = $max;
3925 while (--$hi >= $min) {
3926 my $ok;
3927 $self->get_log([$longest_path], $min, $hi,
3928 0, 1, 1, sub {
3929 $ok ||= $_[1];
3930 $revs{$_[1]} = _cb(@_) });
3931 if ($ok) {
3932 print STDERR "r$min .. r$ok OK\n";
3933 last;
3934 }
3935 }
3936 }
3937 $SVN::Error::handler = $err_handler;
3938
3939 my %exists = map { $_->{path} => $_ } @$gsv;
3940 foreach my $r (sort {$a <=> $b} keys %revs) {
3941 my ($paths, $logged) = @{$revs{$r}};
3942
3943 foreach my $gs ($self->match_globs(\%exists, $paths,
3944 $globs, $r)) {
3945 if ($gs->rev_map_max >= $r) {
3946 next;
3947 }
3948 next unless $gs->match_paths($paths, $r);
3949 $gs->{logged_rev_props} = $logged;
3950 if (my $last_commit = $gs->last_commit) {
3951 $gs->assert_index_clean($last_commit);
3952 }
3953 my $log_entry = $gs->do_fetch($paths, $r);
3954 if ($log_entry) {
3955 $gs->do_git_commit($log_entry);
3956 }
3957 $INDEX_FILES{$gs->{index}} = 1;
3958 }
3959 foreach my $g (@$globs) {
3960 my $k = "svn-remote.$g->{remote}." .
3961 "$g->{t}-maxRev";
3962 Git::SVN::tmp_config($k, $r);
3963 }
3964 if ($ra_invalid) {
3965 $_[0] = undef;
3966 $self = undef;
3967 $RA = undef;
3968 $self = Git::SVN::Ra->new($ra_url);
3969 $ra_invalid = undef;
3970 }
3971 }
3972 # pre-fill the .rev_db since it'll eventually get filled in
3973 # with '0' x40 if something new gets committed
3974 foreach my $gs (@$gsv) {
3975 next if $gs->rev_map_max >= $max;
3976 next if defined $gs->rev_map_get($max);
3977 $gs->rev_map_set($max, 0 x40);
3978 }
3979 foreach my $g (@$globs) {
3980 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3981 Git::SVN::tmp_config($k, $max);
3982 }
3983 last if $max >= $head;
3984 $min = $max + 1;
3985 $max += $inc;
3986 $max = $head if ($max > $head);
3987 }
3988 }
3989
3990 sub match_globs {
3991 my ($self, $exists, $paths, $globs, $r) = @_;
3992
3993 sub get_dir_check {
3994 my ($self, $exists, $g, $r) = @_;
3995 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3996 return unless scalar @x == 3;
3997 my $dirents = $x[0];
3998 foreach my $de (keys %$dirents) {
3999 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4000 my $p = $g->{path}->full_path($de);
4001 next if $exists->{$p};
4002 next if (length $g->{path}->{right} &&
4003 ($self->check_path($p, $r) !=
4004 $SVN::Node::dir));
4005 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4006 $g->{ref}->full_path($de), 1);
4007 }
4008 }
4009 foreach my $g (@$globs) {
4010 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4011 if ($path->{action} =~ /^[AR]$/) {
4012 get_dir_check($self, $exists, $g, $r);
4013 }
4014 }
4015 foreach (keys %$paths) {
4016 if (/$g->{path}->{left_regex}/ &&
4017 !/$g->{path}->{regex}/) {
4018 next if $paths->{$_}->{action} !~ /^[AR]$/;
4019 get_dir_check($self, $exists, $g, $r);
4020 }
4021 next unless /$g->{path}->{regex}/;
4022 my $p = $1;
4023 my $pathname = $g->{path}->full_path($p);
4024 next if $exists->{$pathname};
4025 next if ($self->check_path($pathname, $r) !=
4026 $SVN::Node::dir);
4027 $exists->{$pathname} = Git::SVN->init(
4028 $self->{url}, $pathname, undef,
4029 $g->{ref}->full_path($p), 1);
4030 }
4031 my $c = '';
4032 foreach (split m#/#, $g->{path}->{left}) {
4033 $c .= "/$_";
4034 next unless ($paths->{$c} &&
4035 ($paths->{$c}->{action} =~ /^[AR]$/));
4036 get_dir_check($self, $exists, $g, $r);
4037 }
4038 }
4039 values %$exists;
4040 }
4041
4042 sub minimize_url {
4043 my ($self) = @_;
4044 return $self->{url} if ($self->{url} eq $self->{repos_root});
4045 my $url = $self->{repos_root};
4046 my @components = split(m!/!, $self->{svn_path});
4047 my $c = '';
4048 do {
4049 $url .= "/$c" if length $c;
4050 eval { (ref $self)->new($url)->get_latest_revnum };
4051 } while ($@ && ($c = shift @components));
4052 $url;
4053 }
4054
4055 sub can_do_switch {
4056 my $self = shift;
4057 unless (defined $can_do_switch) {
4058 my $pool = SVN::Pool->new;
4059 my $rep = eval {
4060 $self->do_switch(1, '', 0, $self->{url},
4061 SVN::Delta::Editor->new, $pool);
4062 };
4063 if ($@) {
4064 $can_do_switch = 0;
4065 } else {
4066 $rep->abort_report($pool);
4067 $can_do_switch = 1;
4068 }
4069 $pool->clear;
4070 }
4071 $can_do_switch;
4072 }
4073
4074 sub skip_unknown_revs {
4075 my ($err) = @_;
4076 my $errno = $err->apr_err();
4077 # Maybe the branch we're tracking didn't
4078 # exist when the repo started, so it's
4079 # not an error if it doesn't, just continue
4080 #
4081 # Wonderfully consistent library, eh?
4082 # 160013 - svn:// and file://
4083 # 175002 - http(s)://
4084 # 175007 - http(s):// (this repo required authorization, too...)
4085 # More codes may be discovered later...
4086 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4087 my $err_key = $err->expanded_message;
4088 # revision numbers change every time, filter them out
4089 $err_key =~ s/\d+/\0/g;
4090 $err_key = "$errno\0$err_key";
4091 unless ($ignored_err{$err_key}) {
4092 warn "W: Ignoring error from SVN, path probably ",
4093 "does not exist: ($errno): ",
4094 $err->expanded_message,"\n";
4095 warn "W: Do not be alarmed at the above message ",
4096 "git-svn is just searching aggressively for ",
4097 "old history.\n",
4098 "This may take a while on large repositories\n";
4099 $ignored_err{$err_key} = 1;
4100 }
4101 return;
4102 }
4103 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4104 }
4105
4106 # svn_log_changed_path_t objects passed to get_log are likely to be
4107 # overwritten even if only the refs are copied to an external variable,
4108 # so we should dup the structures in their entirety. Using an externally
4109 # passed pool (instead of our temporary and quickly cleared pool in
4110 # Git::SVN::Ra) does not help matters at all...
4111 sub dup_changed_paths {
4112 my ($paths) = @_;
4113 return undef unless $paths;
4114 my %ret;
4115 foreach my $p (keys %$paths) {
4116 my $i = $paths->{$p};
4117 my %s = map { $_ => $i->$_ }
4118 qw/copyfrom_path copyfrom_rev action/;
4119 $ret{$p} = \%s;
4120 }
4121 \%ret;
4122 }
4123
4124 package Git::SVN::Log;
4125 use strict;
4126 use warnings;
4127 use POSIX qw/strftime/;
4128 use constant commit_log_separator => ('-' x 72) . "\n";
4129 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4130 %rusers $show_commit $incremental/;
4131 my $l_fmt;
4132
4133 sub cmt_showable {
4134 my ($c) = @_;
4135 return 1 if defined $c->{r};
4136
4137 # big commit message got truncated by the 16k pretty buffer in rev-list
4138 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4139 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4140 @{$c->{l}} = ();
4141 my @log = command(qw/cat-file commit/, $c->{c});
4142
4143 # shift off the headers
4144 shift @log while ($log[0] ne '');
4145 shift @log;
4146
4147 # TODO: make $c->{l} not have a trailing newline in the future
4148 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4149
4150 (undef, $c->{r}, undef) = ::extract_metadata(
4151 (grep(/^git-svn-id: /, @log))[-1]);
4152 }
4153 return defined $c->{r};
4154 }
4155
4156 sub log_use_color {
4157 return $color || Git->repository->get_colorbool('color.diff');
4158 }
4159
4160 sub git_svn_log_cmd {
4161 my ($r_min, $r_max, @args) = @_;
4162 my $head = 'HEAD';
4163 my (@files, @log_opts);
4164 foreach my $x (@args) {
4165 if ($x eq '--' || @files) {
4166 push @files, $x;
4167 } else {
4168 if (::verify_ref("$x^0")) {
4169 $head = $x;
4170 } else {
4171 push @log_opts, $x;
4172 }
4173 }
4174 }
4175
4176 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4177 $gs ||= Git::SVN->_new;
4178 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4179 $gs->refname);
4180 push @cmd, '-r' unless $non_recursive;
4181 push @cmd, qw/--raw --name-status/ if $verbose;
4182 push @cmd, '--color' if log_use_color();
4183 push @cmd, @log_opts;
4184 if (defined $r_max && $r_max == $r_min) {
4185 push @cmd, '--max-count=1';
4186 if (my $c = $gs->rev_map_get($r_max)) {
4187 push @cmd, $c;
4188 }
4189 } elsif (defined $r_max) {
4190 if ($r_max < $r_min) {
4191 ($r_min, $r_max) = ($r_max, $r_min);
4192 }
4193 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4194 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4195 # If there are no commits in the range, both $c_max and $c_min
4196 # will be undefined. If there is at least 1 commit in the
4197 # range, both will be defined.
4198 return () if !defined $c_min || !defined $c_max;
4199 if ($c_min eq $c_max) {
4200 push @cmd, '--max-count=1', $c_min;
4201 } else {
4202 push @cmd, '--boundary', "$c_min..$c_max";
4203 }
4204 }
4205 return (@cmd, @files);
4206 }
4207
4208 # adapted from pager.c
4209 sub config_pager {
4210 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4211 if (!defined $pager) {
4212 $pager = 'less';
4213 } elsif (length $pager == 0 || $pager eq 'cat') {
4214 $pager = undef;
4215 }
4216 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4217 }
4218
4219 sub run_pager {
4220 return unless -t *STDOUT && defined $pager;
4221 pipe my $rfd, my $wfd or return;
4222 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4223 if (!$pid) {
4224 open STDOUT, '>&', $wfd or
4225 ::fatal "Can't redirect to stdout: $!";
4226 return;
4227 }
4228 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4229 $ENV{LESS} ||= 'FRSX';
4230 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4231 }
4232
4233 sub format_svn_date {
4234 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4235 }
4236
4237 sub parse_git_date {
4238 my ($t, $tz) = @_;
4239 # Date::Parse isn't in the standard Perl distro :(
4240 if ($tz =~ s/^\+//) {
4241 $t += tz_to_s_offset($tz);
4242 } elsif ($tz =~ s/^\-//) {
4243 $t -= tz_to_s_offset($tz);
4244 }
4245 return $t;
4246 }
4247
4248 sub set_local_timezone {
4249 if (defined $TZ) {
4250 $ENV{TZ} = $TZ;
4251 } else {
4252 delete $ENV{TZ};
4253 }
4254 }
4255
4256 sub tz_to_s_offset {
4257 my ($tz) = @_;
4258 $tz =~ s/(\d\d)$//;
4259 return ($1 * 60) + ($tz * 3600);
4260 }
4261
4262 sub get_author_info {
4263 my ($dest, $author, $t, $tz) = @_;
4264 $author =~ s/(?:^\s*|\s*$)//g;
4265 $dest->{a_raw} = $author;
4266 my $au;
4267 if ($::_authors) {
4268 $au = $rusers{$author} || undef;
4269 }
4270 if (!$au) {
4271 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4272 }
4273 $dest->{t} = $t;
4274 $dest->{tz} = $tz;
4275 $dest->{a} = $au;
4276 $dest->{t_utc} = parse_git_date($t, $tz);
4277 }
4278
4279 sub process_commit {
4280 my ($c, $r_min, $r_max, $defer) = @_;
4281 if (defined $r_min && defined $r_max) {
4282 if ($r_min == $c->{r} && $r_min == $r_max) {
4283 show_commit($c);
4284 return 0;
4285 }
4286 return 1 if $r_min == $r_max;
4287 if ($r_min < $r_max) {
4288 # we need to reverse the print order
4289 return 0 if (defined $limit && --$limit < 0);
4290 push @$defer, $c;
4291 return 1;
4292 }
4293 if ($r_min != $r_max) {
4294 return 1 if ($r_min < $c->{r});
4295 return 1 if ($r_max > $c->{r});
4296 }
4297 }
4298 return 0 if (defined $limit && --$limit < 0);
4299 show_commit($c);
4300 return 1;
4301 }
4302
4303 sub show_commit {
4304 my $c = shift;
4305 if ($oneline) {
4306 my $x = "\n";
4307 if (my $l = $c->{l}) {
4308 while ($l->[0] =~ /^\s*$/) { shift @$l }
4309 $x = $l->[0];
4310 }
4311 $l_fmt ||= 'A' . length($c->{r});
4312 print 'r',pack($l_fmt, $c->{r}),' | ';
4313 print "$c->{c} | " if $show_commit;
4314 print $x;
4315 } else {
4316 show_commit_normal($c);
4317 }
4318 }
4319
4320 sub show_commit_changed_paths {
4321 my ($c) = @_;
4322 return unless $c->{changed};
4323 print "Changed paths:\n", @{$c->{changed}};
4324 }
4325
4326 sub show_commit_normal {
4327 my ($c) = @_;
4328 print commit_log_separator, "r$c->{r} | ";
4329 print "$c->{c} | " if $show_commit;
4330 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4331 my $nr_line = 0;
4332
4333 if (my $l = $c->{l}) {
4334 while ($l->[$#$l] eq "\n" && $#$l > 0
4335 && $l->[($#$l - 1)] eq "\n") {
4336 pop @$l;
4337 }
4338 $nr_line = scalar @$l;
4339 if (!$nr_line) {
4340 print "1 line\n\n\n";
4341 } else {
4342 if ($nr_line == 1) {
4343 $nr_line = '1 line';
4344 } else {
4345 $nr_line .= ' lines';
4346 }
4347 print $nr_line, "\n";
4348 show_commit_changed_paths($c);
4349 print "\n";
4350 print $_ foreach @$l;
4351 }
4352 } else {
4353 print "1 line\n";
4354 show_commit_changed_paths($c);
4355 print "\n";
4356
4357 }
4358 foreach my $x (qw/raw stat diff/) {
4359 if ($c->{$x}) {
4360 print "\n";
4361 print $_ foreach @{$c->{$x}}
4362 }
4363 }
4364 }
4365
4366 sub cmd_show_log {
4367 my (@args) = @_;
4368 my ($r_min, $r_max);
4369 my $r_last = -1; # prevent dupes
4370 set_local_timezone();
4371 if (defined $::_revision) {
4372 if ($::_revision =~ /^(\d+):(\d+)$/) {
4373 ($r_min, $r_max) = ($1, $2);
4374 } elsif ($::_revision =~ /^\d+$/) {
4375 $r_min = $r_max = $::_revision;
4376 } else {
4377 ::fatal "-r$::_revision is not supported, use ",
4378 "standard 'git log' arguments instead";
4379 }
4380 }
4381
4382 config_pager();
4383 @args = git_svn_log_cmd($r_min, $r_max, @args);
4384 if (!@args) {
4385 print commit_log_separator unless $incremental || $oneline;
4386 return;
4387 }
4388 my $log = command_output_pipe(@args);
4389 run_pager();
4390 my (@k, $c, $d, $stat);
4391 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4392 while (<$log>) {
4393 if (/^${esc_color}commit -?($::sha1_short)/o) {
4394 my $cmt = $1;
4395 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4396 $r_last = $c->{r};
4397 process_commit($c, $r_min, $r_max, \@k) or
4398 goto out;
4399 }
4400 $d = undef;
4401 $c = { c => $cmt };
4402 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4403 get_author_info($c, $1, $2, $3);
4404 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4405 # ignore
4406 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4407 push @{$c->{raw}}, $_;
4408 } elsif (/^${esc_color}[ACRMDT]\t/) {
4409 # we could add $SVN->{svn_path} here, but that requires
4410 # remote access at the moment (repo_path_split)...
4411 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4412 push @{$c->{changed}}, $_;
4413 } elsif (/^${esc_color}diff /o) {
4414 $d = 1;
4415 push @{$c->{diff}}, $_;
4416 } elsif ($d) {
4417 push @{$c->{diff}}, $_;
4418 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4419 $esc_color*[\+\-]*$esc_color$/x) {
4420 $stat = 1;
4421 push @{$c->{stat}}, $_;
4422 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4423 push @{$c->{stat}}, $_;
4424 $stat = undef;
4425 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4426 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4427 } elsif (s/^${esc_color} //o) {
4428 push @{$c->{l}}, $_;
4429 }
4430 }
4431 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4432 $r_last = $c->{r};
4433 process_commit($c, $r_min, $r_max, \@k);
4434 }
4435 if (@k) {
4436 ($r_min, $r_max) = ($r_max, $r_min);
4437 process_commit($_, $r_min, $r_max) foreach reverse @k;
4438 }
4439 out:
4440 close $log;
4441 print commit_log_separator unless $incremental || $oneline;
4442 }
4443
4444 package Git::SVN::Migration;
4445 # these version numbers do NOT correspond to actual version numbers
4446 # of git nor git-svn. They are just relative.
4447 #
4448 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4449 #
4450 # v1 layout: .git/$id/info/url, refs/remotes/$id
4451 #
4452 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4453 #
4454 # v3 layout: .git/svn/$id, refs/remotes/$id
4455 # - info/url may remain for backwards compatibility
4456 # - this is what we migrate up to this layout automatically,
4457 # - this will be used by git svn init on single branches
4458 # v3.1 layout (auto migrated):
4459 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4460 # for backwards compatibility
4461 #
4462 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4463 # - this is only created for newly multi-init-ed
4464 # repositories. Similar in spirit to the
4465 # --use-separate-remotes option in git-clone (now default)
4466 # - we do not automatically migrate to this (following
4467 # the example set by core git)
4468 #
4469 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4470 # - newer, more-efficient format that uses 24-bytes per record
4471 # with no filler space.
4472 # - use xxd -c24 < .rev_map.$UUID to view and debug
4473 # - This is a one-way migration, repositories updated to the
4474 # new format will not be able to use old git-svn without
4475 # rebuilding the .rev_db. Rebuilding the rev_db is not
4476 # possible if noMetadata or useSvmProps are set; but should
4477 # be no problem for users that use the (sensible) defaults.
4478 use strict;
4479 use warnings;
4480 use Carp qw/croak/;
4481 use File::Path qw/mkpath/;
4482 use File::Basename qw/dirname basename/;
4483 use vars qw/$_minimize/;
4484
4485 sub migrate_from_v0 {
4486 my $git_dir = $ENV{GIT_DIR};
4487 return undef unless -d $git_dir;
4488 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4489 my $migrated = 0;
4490 while (<$fh>) {
4491 chomp;
4492 my ($id, $orig_ref) = ($_, $_);
4493 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4494 next unless -f "$git_dir/$id/info/url";
4495 my $new_ref = "refs/remotes/$id";
4496 if (::verify_ref("$new_ref^0")) {
4497 print STDERR "W: $orig_ref is probably an old ",
4498 "branch used by an ancient version of ",
4499 "git-svn.\n",
4500 "However, $new_ref also exists.\n",
4501 "We will not be able ",
4502 "to use this branch until this ",
4503 "ambiguity is resolved.\n";
4504 next;
4505 }
4506 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4507 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4508 command_noisy('update-ref', $new_ref, $orig_ref);
4509 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4510 $migrated++;
4511 }
4512 command_close_pipe($fh, $ctx);
4513 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4514 $migrated;
4515 }
4516
4517 sub migrate_from_v1 {
4518 my $git_dir = $ENV{GIT_DIR};
4519 my $migrated = 0;
4520 return $migrated unless -d $git_dir;
4521 my $svn_dir = "$git_dir/svn";
4522
4523 # just in case somebody used 'svn' as their $id at some point...
4524 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4525
4526 print STDERR "Migrating from a git-svn v1 layout...\n";
4527 mkpath([$svn_dir]);
4528 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4529 "$svn_dir\n\t(required for this version ",
4530 "($::VERSION) of git-svn) does not. exist\n";
4531 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4532 while (<$fh>) {
4533 my $x = $_;
4534 next unless $x =~ s#^refs/remotes/##;
4535 chomp $x;
4536 next unless -f "$git_dir/$x/info/url";
4537 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4538 next unless $u;
4539 my $dn = dirname("$git_dir/svn/$x");
4540 mkpath([$dn]) unless -d $dn;
4541 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4542 mkpath(["$git_dir/svn/svn"]);
4543 print STDERR " - $git_dir/$x/info => ",
4544 "$git_dir/svn/$x/info\n";
4545 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4546 croak "$!: $x";
4547 # don't worry too much about these, they probably
4548 # don't exist with repos this old (save for index,
4549 # and we can easily regenerate that)
4550 foreach my $f (qw/unhandled.log index .rev_db/) {
4551 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4552 }
4553 } else {
4554 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4555 rename "$git_dir/$x", "$git_dir/svn/$x" or
4556 croak "$!: $x";
4557 }
4558 $migrated++;
4559 }
4560 command_close_pipe($fh, $ctx);
4561 print STDERR "Done migrating from a git-svn v1 layout\n";
4562 $migrated;
4563 }
4564
4565 sub read_old_urls {
4566 my ($l_map, $pfx, $path) = @_;
4567 my @dir;
4568 foreach (<$path/*>) {
4569 if (-r "$_/info/url") {
4570 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4571 my $ref_id = $pfx . basename $_;
4572 my $url = ::file_to_s("$_/info/url");
4573 $l_map->{$ref_id} = $url;
4574 } elsif (-d $_) {
4575 push @dir, $_;
4576 }
4577 }
4578 foreach (@dir) {
4579 my $x = $_;
4580 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4581 read_old_urls($l_map, $x, $_);
4582 }
4583 }
4584
4585 sub migrate_from_v2 {
4586 my @cfg = command(qw/config -l/);
4587 return if grep /^svn-remote\..+\.url=/, @cfg;
4588 my %l_map;
4589 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4590 my $migrated = 0;
4591
4592 foreach my $ref_id (sort keys %l_map) {
4593 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4594 if ($@) {
4595 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4596 }
4597 $migrated++;
4598 }
4599 $migrated;
4600 }
4601
4602 sub minimize_connections {
4603 my $r = Git::SVN::read_all_remotes();
4604 my $new_urls = {};
4605 my $root_repos = {};
4606 foreach my $repo_id (keys %$r) {
4607 my $url = $r->{$repo_id}->{url} or next;
4608 my $fetch = $r->{$repo_id}->{fetch} or next;
4609 my $ra = Git::SVN::Ra->new($url);
4610
4611 # skip existing cases where we already connect to the root
4612 if (($ra->{url} eq $ra->{repos_root}) ||
4613 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4614 $repo_id)) {
4615 $root_repos->{$ra->{url}} = $repo_id;
4616 next;
4617 }
4618
4619 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4620 my $root_path = $ra->{url};
4621 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4622 foreach my $path (keys %$fetch) {
4623 my $ref_id = $fetch->{$path};
4624 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4625
4626 # make sure we can read when connecting to
4627 # a higher level of a repository
4628 my ($last_rev, undef) = $gs->last_rev_commit;
4629 if (!defined $last_rev) {
4630 $last_rev = eval {
4631 $root_ra->get_latest_revnum;
4632 };
4633 next if $@;
4634 }
4635 my $new = $root_path;
4636 $new .= length $path ? "/$path" : '';
4637 eval {
4638 $root_ra->get_log([$new], $last_rev, $last_rev,
4639 0, 0, 1, sub { });
4640 };
4641 next if $@;
4642 $new_urls->{$ra->{repos_root}}->{$new} =
4643 { ref_id => $ref_id,
4644 old_repo_id => $repo_id,
4645 old_path => $path };
4646 }
4647 }
4648
4649 my @emptied;
4650 foreach my $url (keys %$new_urls) {
4651 # see if we can re-use an existing [svn-remote "repo_id"]
4652 # instead of creating a(n ugly) new section:
4653 my $repo_id = $root_repos->{$url} ||
4654 Git::SVN::sanitize_remote_name($url);
4655
4656 my $fetch = $new_urls->{$url};
4657 foreach my $path (keys %$fetch) {
4658 my $x = $fetch->{$path};
4659 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4660 my $pfx = "svn-remote.$x->{old_repo_id}";
4661
4662 my $old_fetch = quotemeta("$x->{old_path}:".
4663 "refs/remotes/$x->{ref_id}");
4664 command_noisy(qw/config --unset/,
4665 "$pfx.fetch", '^'. $old_fetch . '$');
4666 delete $r->{$x->{old_repo_id}}->
4667 {fetch}->{$x->{old_path}};
4668 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4669 command_noisy(qw/config --unset/,
4670 "$pfx.url");
4671 push @emptied, $x->{old_repo_id}
4672 }
4673 }
4674 }
4675 if (@emptied) {
4676 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4677 "$ENV{GIT_DIR}/config";
4678 print STDERR <<EOF;
4679 The following [svn-remote] sections in your config file ($file) are empty
4680 and can be safely removed:
4681 EOF
4682 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4683 }
4684 }
4685
4686 sub migration_check {
4687 migrate_from_v0();
4688 migrate_from_v1();
4689 migrate_from_v2();
4690 minimize_connections() if $_minimize;
4691 }
4692
4693 package Git::IndexInfo;
4694 use strict;
4695 use warnings;
4696 use Git qw/command_input_pipe command_close_pipe/;
4697
4698 sub new {
4699 my ($class) = @_;
4700 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4701 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4702 }
4703
4704 sub remove {
4705 my ($self, $path) = @_;
4706 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4707 return ++$self->{nr};
4708 }
4709 undef;
4710 }
4711
4712 sub update {
4713 my ($self, $mode, $hash, $path) = @_;
4714 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4715 return ++$self->{nr};
4716 }
4717 undef;
4718 }
4719
4720 sub DESTROY {
4721 my ($self) = @_;
4722 command_close_pipe($self->{gui}, $self->{ctx});
4723 }
4724
4725 package Git::SVN::GlobSpec;
4726 use strict;
4727 use warnings;
4728
4729 sub new {
4730 my ($class, $glob) = @_;
4731 my $re = $glob;
4732 $re =~ s!/+$!!g; # no need for trailing slashes
4733 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4734 my ($left, $right) = ($1, $2);
4735 if ($nr > 1) {
4736 die "Only one '*' wildcard expansion ",
4737 "is supported (got $nr): '$glob'\n";
4738 } elsif ($nr == 0) {
4739 die "One '*' is needed for glob: '$glob'\n";
4740 }
4741 $re = quotemeta($left) . $re . quotemeta($right);
4742 if (length $left && !($left =~ s!/+$!!g)) {
4743 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4744 }
4745 if (length $right && !($right =~ s!^/+!!g)) {
4746 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4747 }
4748 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4749 bless { left => $left, right => $right, left_regex => $left_re,
4750 regex => qr/$re/, glob => $glob }, $class;
4751 }
4752
4753 sub full_path {
4754 my ($self, $path) = @_;
4755 return (length $self->{left} ? "$self->{left}/" : '') .
4756 $path . (length $self->{right} ? "/$self->{right}" : '');
4757 }
4758
4759 __END__
4760
4761 Data structures:
4762
4763
4764 $remotes = { # returned by read_all_remotes()
4765 'svn' => {
4766 # svn-remote.svn.url=https://svn.musicpd.org
4767 url => 'https://svn.musicpd.org',
4768 # svn-remote.svn.fetch=mpd/trunk:trunk
4769 fetch => {
4770 'mpd/trunk' => 'trunk',
4771 },
4772 # svn-remote.svn.tags=mpd/tags/*:tags/*
4773 tags => {
4774 path => {
4775 left => 'mpd/tags',
4776 right => '',
4777 regex => qr!mpd/tags/([^/]+)$!,
4778 glob => 'tags/*',
4779 },
4780 ref => {
4781 left => 'tags',
4782 right => '',
4783 regex => qr!tags/([^/]+)$!,
4784 glob => 'tags/*',
4785 },
4786 }
4787 }
4788 };
4789
4790 $log_entry hashref as returned by libsvn_log_entry()
4791 {
4792 log => 'whitespace-formatted log entry
4793 ', # trailing newline is preserved
4794 revision => '8', # integer
4795 date => '2004-02-24T17:01:44.108345Z', # commit date
4796 author => 'committer name'
4797 };
4798
4799
4800 # this is generated by generate_diff();
4801 @mods = array of diff-index line hashes, each element represents one line
4802 of diff-index output
4803
4804 diff-index line ($m hash)
4805 {
4806 mode_a => first column of diff-index output, no leading ':',
4807 mode_b => second column of diff-index output,
4808 sha1_b => sha1sum of the final blob,
4809 chg => change type [MCRADT],
4810 file_a => original file name of a file (iff chg is 'C' or 'R')
4811 file_b => new/current file name of a file (any chg)
4812 }
4813 ;
4814
4815 # retval of read_url_paths{,_all}();
4816 $l_map = {
4817 # repository root url
4818 'https://svn.musicpd.org' => {
4819 # repository path # GIT_SVN_ID
4820 'mpd/trunk' => 'trunk',
4821 'mpd/tags/0.11.5' => 'tags/0.11.5',
4822 },
4823 }
4824
4825 Notes:
4826 I don't trust the each() function on unless I created %hash myself
4827 because the internal iterator may not have started at base.
git-p4