git-svn.perl

   1 #!/usr/bin/perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008001;
   5 use warnings $ENV{GIT_PERL_FATAL_WARNINGS} ? qw(FATAL all) : ();
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $oid $oid_short $oid_length
   9                 $_revision $_repository
  10                 $_q $_authors $_authors_prog %users/;
  11 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  12 $VERSION = '@@GIT_VERSION@@';
  13
  14 use Carp qw/croak/;
  15 use File::Basename qw/dirname basename/;
  16 use File::Path qw/mkpath/;
  17 use File::Spec;
  18 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  19 use Memoize;
  20
  21 use Git::SVN;
  22 use Git::SVN::Editor;
  23 use Git::SVN::Fetcher;
  24 use Git::SVN::Ra;
  25 use Git::SVN::Prompt;
  26 use Git::SVN::Log;
  27 use Git::SVN::Migration;
  28
  29 use Git::SVN::Utils qw(
  30         fatal
  31         can_compress
  32         canonicalize_path
  33         canonicalize_url
  34         join_paths
  35         add_path_to_url
  36         join_paths
  37 );
  38
  39 use Git qw(
  40         git_cmd_try
  41         command
  42         command_oneline
  43         command_noisy
  44         command_output_pipe
  45         command_close_pipe
  46         command_bidi_pipe
  47         command_close_bidi_pipe
  48         get_record
  49 );
  50
  51 BEGIN {
  52         Memoize::memoize 'Git::config';
  53         Memoize::memoize 'Git::config_bool';
  54 }
  55
  56
  57 # From which subdir have we been invoked?
  58 my $cmd_dir_prefix = eval {
  59         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  60 } || '';
  61
  62 $Git::SVN::Ra::_log_window_size = 100;
  63
  64 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  65         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  66 }
  67
  68 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  69         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  70         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  71 }
  72
  73 $Git::SVN::Log::TZ = $ENV{TZ};
  74 $ENV{TZ} = 'UTC';
  75 $| = 1; # unbuffer STDOUT
  76
  77 # All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  78 # repository decides to close the connection which we expect to be kept alive.
  79 $SIG{PIPE} = 'IGNORE';
  80
  81 # Given a dot separated version number, "subtract" it from
  82 # the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  83 # is at least at the version the caller asked for.
  84 sub compare_svn_version {
  85         my (@ours) = split(/\./, $SVN::Core::VERSION);
  86         my (@theirs) = split(/\./, $_[0]);
  87         my ($i, $diff);
  88
  89         for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  90                 $diff = $ours[$i] - $theirs[$i];
  91                 return $diff if ($diff);
  92         }
  93         return 1 if ($i < @ours);
  94         return -1 if ($i < @theirs);
  95         return 0;
  96 }
  97
  98 sub _req_svn {
  99         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
 100         require SVN::Ra;
 101         require SVN::Delta;
 102         if (::compare_svn_version('1.1.0') < 0) {
 103                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 104         }
 105 }
 106
 107 $oid = qr/(?:[a-f\d]{40}(?:[a-f\d]{24})?)/;
 108 $oid_short = qr/[a-f\d]{4,64}/;
 109 $oid_length = 40;
 110 my ($_stdin, $_help, $_edit,
 111         $_message, $_file, $_branch_dest,
 112         $_template, $_shared,
 113         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 114         $_before, $_after,
 115         $_merge, $_strategy, $_rebase_merges, $_dry_run, $_parents, $_local,
 116         $_prefix, $_no_checkout, $_url, $_verbose,
 117         $_commit_url, $_tag, $_merge_info, $_interactive, $_set_svn_props);
 118
 119 # This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 120 sub opt_prefix { return $_prefix || '' }
 121
 122 $Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 123 $_q ||= 0;
 124 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 125                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
 126                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 127                     'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 128                     'include-paths=s' => \$Git::SVN::Fetcher::_include_regex,
 129                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 130 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 131                 'authors-file|A=s' => \$_authors,
 132                 'authors-prog=s' => \$_authors_prog,
 133                 'repack:i' => \$Git::SVN::_repack,
 134                 'noMetadata' => \$Git::SVN::_no_metadata,
 135                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 136                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 137                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 138                 'no-checkout' => \$_no_checkout,
 139                 'quiet|q+' => \$_q,
 140                 'repack-flags|repack-args|repack-opts=s' =>
 141                    \$Git::SVN::_repack_flags,
 142                 'use-log-author' => \$Git::SVN::_use_log_author,
 143                 'add-author-from' => \$Git::SVN::_add_author_from,
 144                 'localtime' => \$Git::SVN::_localtime,
 145                 %remote_opts );
 146
 147 my ($_trunk, @_tags, @_branches, $_stdlayout);
 148 my %icv;
 149 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 150                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 151                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 152                   'stdlayout|s' => \$_stdlayout,
 153                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 154                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 155                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 156                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 157                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 158                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 159                   %remote_opts );
 160 my %cmt_opts = ( 'edit|e' => \$_edit,
 161                 'rmdir' => \$Git::SVN::Editor::_rmdir,
 162                 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 163                 'l=i' => \$Git::SVN::Editor::_rename_limit,
 164                 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 165 );
 166
 167 my %cmd = (
 168         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 169                         { 'revision|r=s' => \$_revision,
 170                           'fetch-all|all' => \$_fetch_all,
 171                           'parent|p' => \$_fetch_parent,
 172                            %fc_opts } ],
 173         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 174                         { 'revision|r=s' => \$_revision,
 175                           'preserve-empty-dirs' =>
 176                                 \$Git::SVN::Fetcher::_preserve_empty_dirs,
 177                           'placeholder-filename=s' =>
 178                                 \$Git::SVN::Fetcher::_placeholder_filename,
 179                            %fc_opts, %init_opts } ],
 180         init => [ \&cmd_init, "Initialize a repo for tracking" .
 181                           " (requires URL argument)",
 182                           \%init_opts ],
 183         'multi-init' => [ \&cmd_multi_init,
 184                           "Deprecated alias for ".
 185                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 186                           \%init_opts ],
 187         dcommit => [ \&cmd_dcommit,
 188                      'Commit several diffs to merge with upstream',
 189                         { 'merge|m|M' => \$_merge,
 190                           'strategy|s=s' => \$_strategy,
 191                           'verbose|v' => \$_verbose,
 192                           'dry-run|n' => \$_dry_run,
 193                           'fetch-all|all' => \$_fetch_all,
 194                           'commit-url=s' => \$_commit_url,
 195                           'set-svn-props=s' => \$_set_svn_props,
 196                           'revision|r=i' => \$_revision,
 197                           'no-rebase' => \$_no_rebase,
 198                           'mergeinfo=s' => \$_merge_info,
 199                           'interactive|i' => \$_interactive,
 200                         %cmt_opts, %fc_opts } ],
 201         branch => [ \&cmd_branch,
 202                     'Create a branch in the SVN repository',
 203                     { 'message|m=s' => \$_message,
 204                       'destination|d=s' => \$_branch_dest,
 205                       'dry-run|n' => \$_dry_run,
 206                       'parents' => \$_parents,
 207                       'tag|t' => \$_tag,
 208                       'username=s' => \$Git::SVN::Prompt::_username,
 209                       'commit-url=s' => \$_commit_url } ],
 210         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 211                  'Create a tag in the SVN repository',
 212                  { 'message|m=s' => \$_message,
 213                    'destination|d=s' => \$_branch_dest,
 214                    'dry-run|n' => \$_dry_run,
 215                    'parents' => \$_parents,
 216                    'username=s' => \$Git::SVN::Prompt::_username,
 217                    'commit-url=s' => \$_commit_url } ],
 218         'set-tree' => [ \&cmd_set_tree,
 219                         "Set an SVN repository to a git tree-ish",
 220                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 221         'create-ignore' => [ \&cmd_create_ignore,
 222                              'Create a .gitignore per svn:ignore',
 223                              { 'revision|r=i' => \$_revision
 224                              } ],
 225         'mkdirs' => [ \&cmd_mkdirs ,
 226                       "recreate empty directories after a checkout",
 227                       { 'revision|r=i' => \$_revision } ],
 228         'propget' => [ \&cmd_propget,
 229                        'Print the value of a property on a file or directory',
 230                        { 'revision|r=i' => \$_revision } ],
 231         'propset' => [ \&cmd_propset,
 232                        'Set the value of a property on a file or directory - will be set on commit',
 233                        {} ],
 234         'proplist' => [ \&cmd_proplist,
 235                        'List all properties of a file or directory',
 236                        { 'revision|r=i' => \$_revision } ],
 237         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 238                         { 'revision|r=i' => \$_revision
 239                         } ],
 240         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 241                         { 'revision|r=i' => \$_revision
 242                         } ],
 243         'multi-fetch' => [ \&cmd_multi_fetch,
 244                            "Deprecated alias for $0 fetch --all",
 245                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 246         'migrate' => [ sub { },
 247                        # no-op, we automatically run this anyways,
 248                        'Migrate configuration/metadata/layout from
 249                         previous versions of git-svn',
 250                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 251                          %remote_opts } ],
 252         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 253                         { 'limit=i' => \$Git::SVN::Log::limit,
 254                           'revision|r=s' => \$_revision,
 255                           'verbose|v' => \$Git::SVN::Log::verbose,
 256                           'incremental' => \$Git::SVN::Log::incremental,
 257                           'oneline' => \$Git::SVN::Log::oneline,
 258                           'show-commit' => \$Git::SVN::Log::show_commit,
 259                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 260                           'authors-file|A=s' => \$_authors,
 261                           'color' => \$Git::SVN::Log::color,
 262                           'pager=s' => \$Git::SVN::Log::pager
 263                         } ],
 264         'find-rev' => [ \&cmd_find_rev,
 265                         "Translate between SVN revision numbers and tree-ish",
 266                         { 'B|before' => \$_before,
 267                           'A|after' => \$_after } ],
 268         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 269                         { 'merge|m|M' => \$_merge,
 270                           'verbose|v' => \$_verbose,
 271                           'strategy|s=s' => \$_strategy,
 272                           'local|l' => \$_local,
 273                           'fetch-all|all' => \$_fetch_all,
 274                           'dry-run|n' => \$_dry_run,
 275                           'rebase-merges|p' => \$_rebase_merges,
 276                           %fc_opts } ],
 277         'commit-diff' => [ \&cmd_commit_diff,
 278                            'Commit a diff between two trees',
 279                         { 'message|m=s' => \$_message,
 280                           'file|F=s' => \$_file,
 281                           'revision|r=s' => \$_revision,
 282                         %cmt_opts } ],
 283         'info' => [ \&cmd_info,
 284                     "Show info about the latest SVN revision
 285                      on the current branch",
 286                     { 'url' => \$_url, } ],
 287         'blame' => [ \&Git::SVN::Log::cmd_blame,
 288                     "Show what revision and author last modified each line of a file",
 289                     { 'git-format' => \$Git::SVN::Log::_git_format } ],
 290         'reset' => [ \&cmd_reset,
 291                      "Undo fetches back to the specified SVN revision",
 292                      { 'revision|r=s' => \$_revision,
 293                        'parent|p' => \$_fetch_parent } ],
 294         'gc' => [ \&cmd_gc,
 295                   "Compress unhandled.log files in .git/svn and remove " .
 296                   "index files in .git/svn",
 297                 {} ],
 298 );
 299
 300 my $term;
 301 sub term_init {
 302         require Term::ReadLine;
 303         $term = $ENV{"GIT_SVN_NOTTY"}
 304                         ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 305                         : new Term::ReadLine 'git-svn';
 306 }
 307
 308 my $cmd;
 309 for (my $i = 0; $i < @ARGV; $i++) {
 310         if (defined $cmd{$ARGV[$i]}) {
 311                 $cmd = $ARGV[$i];
 312                 splice @ARGV, $i, 1;
 313                 last;
 314         } elsif ($ARGV[$i] eq 'help') {
 315                 $cmd = $ARGV[$i+1];
 316                 usage(0);
 317         }
 318 };
 319
 320 # make sure we're always running at the top-level working directory
 321 if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 322         $ENV{GIT_DIR} ||= ".git";
 323         # catch the submodule case
 324         if (-f $ENV{GIT_DIR}) {
 325                 open(my $fh, '<', $ENV{GIT_DIR}) or
 326                         die "failed to open $ENV{GIT_DIR}: $!\n";
 327                 $ENV{GIT_DIR} = $1 if <$fh> =~ /^gitdir: (.+)$/;
 328         }
 329 } elsif ($cmd) {
 330         my ($git_dir, $cdup);
 331         git_cmd_try {
 332                 $git_dir = command_oneline([qw/rev-parse --git-dir/]);
 333         } "Unable to find .git directory\n";
 334         git_cmd_try {
 335                 $cdup = command_oneline(qw/rev-parse --show-cdup/);
 336                 chomp $cdup if ($cdup);
 337                 $cdup = "." unless ($cdup && length $cdup);
 338         } "Already at toplevel, but $git_dir not found\n";
 339         $ENV{GIT_DIR} = $git_dir;
 340         chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 341         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 342 }
 343
 344 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 345
 346 read_git_config(\%opts) if $ENV{GIT_DIR};
 347 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 348         Getopt::Long::Configure('pass_through');
 349 }
 350 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 351                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 352                     'id|i=s' => \$Git::SVN::default_ref_id,
 353                     'svn-remote|remote|R=s' => sub {
 354                        $Git::SVN::no_reuse_existing = 1;
 355                        $Git::SVN::default_repo_id = $_[1] });
 356 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 357
 358 usage(0) if $_help;
 359 version() if $_version;
 360 usage(1) unless defined $cmd;
 361 load_authors() if $_authors;
 362 if (defined $_authors_prog) {
 363         my $abs_file = File::Spec->rel2abs($_authors_prog);
 364         $_authors_prog = "'" . $abs_file . "'" if -x $abs_file;
 365 }
 366
 367 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 368         Git::SVN::Migration::migration_check();
 369 }
 370 Git::SVN::init_vars();
 371 eval {
 372         Git::SVN::verify_remotes_sanity();
 373         $cmd{$cmd}->[0]->(@ARGV);
 374         post_fetch_checkout();
 375 };
 376 fatal $@ if $@;
 377 exit 0;
 378
 379 ####################### primary functions ######################
 380 sub usage {
 381         my $exit = shift || 0;
 382         my $fd = $exit ? \*STDERR : \*STDOUT;
 383         print $fd <<"";
 384 git-svn - bidirectional operations between a single Subversion tree and git
 385 usage: git svn <command> [options] [arguments]\n
 386
 387         print $fd "Available commands:\n" unless $cmd;
 388
 389         foreach (sort keys %cmd) {
 390                 next if $cmd && $cmd ne $_;
 391                 next if /^multi-/; # don't show deprecated commands
 392                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 393                 foreach (sort keys %{$cmd{$_}->[2]}) {
 394                         # mixed-case options are for .git/config only
 395                         next if /[A-Z]/ && /^[a-z]+$/i;
 396                         # prints out arguments as they should be passed:
 397                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 398                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 399                                                         "--$_" : "-$_" }
 400                                                 split /\|/,$_)," $x\n";
 401                 }
 402         }
 403         print $fd <<"";
 404 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 405 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 406 one git repository and want to keep them separate.  See git-svn(1) for more
 407 information.
 408
 409         exit $exit;
 410 }
 411
 412 sub version {
 413         ::_req_svn();
 414         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 415         exit 0;
 416 }
 417
 418 sub ask {
 419         my ($prompt, %arg) = @_;
 420         my $valid_re = $arg{valid_re};
 421         my $default = $arg{default};
 422         my $resp;
 423         my $i = 0;
 424         term_init() unless $term;
 425
 426         if ( !( defined($term->IN)
 427             && defined( fileno($term->IN) )
 428             && defined( $term->OUT )
 429             && defined( fileno($term->OUT) ) ) ){
 430                 return defined($default) ? $default : undef;
 431         }
 432
 433         while ($i++ < 10) {
 434                 $resp = $term->readline($prompt);
 435                 if (!defined $resp) { # EOF
 436                         print "\n";
 437                         return defined $default ? $default : undef;
 438                 }
 439                 if ($resp eq '' and defined $default) {
 440                         return $default;
 441                 }
 442                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 443                         return $resp;
 444                 }
 445         }
 446         return undef;
 447 }
 448
 449 sub do_git_init_db {
 450         unless (-d $ENV{GIT_DIR}) {
 451                 my @init_db = ('init');
 452                 push @init_db, "--template=$_template" if defined $_template;
 453                 if (defined $_shared) {
 454                         if ($_shared =~ /[a-z]/) {
 455                                 push @init_db, "--shared=$_shared";
 456                         } else {
 457                                 push @init_db, "--shared";
 458                         }
 459                 }
 460                 command_noisy(@init_db);
 461                 $_repository = Git->repository(Repository => ".git");
 462         }
 463         my $set;
 464         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 465         foreach my $i (keys %icv) {
 466                 die "'$set' and '$i' cannot both be set\n" if $set;
 467                 next unless defined $icv{$i};
 468                 command_noisy('config', "$pfx.$i", $icv{$i});
 469                 $set = $i;
 470         }
 471         my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 472         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 473                 if defined $$ignore_paths_regex;
 474         my $include_paths_regex = \$Git::SVN::Fetcher::_include_regex;
 475         command_noisy('config', "$pfx.include-paths", $$include_paths_regex)
 476                 if defined $$include_paths_regex;
 477         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 478         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 479                 if defined $$ignore_refs_regex;
 480
 481         if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 482                 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 483                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 484                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 485         }
 486         load_object_format();
 487 }
 488
 489 sub init_subdir {
 490         my $repo_path = shift or return;
 491         mkpath([$repo_path]) unless -d $repo_path;
 492         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 493         $ENV{GIT_DIR} = '.git';
 494         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 495 }
 496
 497 sub cmd_clone {
 498         my ($url, $path) = @_;
 499         if (!$url) {
 500                 die "SVN repository location required ",
 501                     "as a command-line argument\n";
 502         } elsif (!defined $path &&
 503             (defined $_trunk || @_branches || @_tags ||
 504              defined $_stdlayout) &&
 505             $url !~ m#^[a-z\+]+://#) {
 506                 $path = $url;
 507         }
 508         $path = basename($url) if !defined $path || !length $path;
 509         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 510         cmd_init($url, $path);
 511         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 512             if $_authors;
 513         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 514 }
 515
 516 sub cmd_init {
 517         if (defined $_stdlayout) {
 518                 $_trunk = 'trunk' if (!defined $_trunk);
 519                 @_tags = 'tags' if (! @_tags);
 520                 @_branches = 'branches' if (! @_branches);
 521         }
 522         if (defined $_trunk || @_branches || @_tags) {
 523                 return cmd_multi_init(@_);
 524         }
 525         my $url = shift or die "SVN repository location required ",
 526                                "as a command-line argument\n";
 527         $url = canonicalize_url($url);
 528         init_subdir(@_);
 529         do_git_init_db();
 530
 531         if ($Git::SVN::_minimize_url eq 'unset') {
 532                 $Git::SVN::_minimize_url = 0;
 533         }
 534
 535         Git::SVN->init($url);
 536 }
 537
 538 sub cmd_fetch {
 539         if (grep /^\d+=./, @_) {
 540                 die "'<rev>=<commit>' fetch arguments are ",
 541                     "no longer supported.\n";
 542         }
 543         my ($remote) = @_;
 544         if (@_ > 1) {
 545                 die "usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 546         }
 547         $Git::SVN::no_reuse_existing = undef;
 548         if ($_fetch_parent) {
 549                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 550                 unless ($gs) {
 551                         die "Unable to determine upstream SVN information from ",
 552                             "working tree history\n";
 553                 }
 554                 # just fetch, don't checkout.
 555                 $_no_checkout = 'true';
 556                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 557         } elsif ($_fetch_all) {
 558                 cmd_multi_fetch();
 559         } else {
 560                 $remote ||= $Git::SVN::default_repo_id;
 561                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 562         }
 563 }
 564
 565 sub cmd_set_tree {
 566         my (@commits) = @_;
 567         if ($_stdin || !@commits) {
 568                 print "Reading from stdin...\n";
 569                 @commits = ();
 570                 while (<STDIN>) {
 571                         if (/\b($oid_short)\b/o) {
 572                                 unshift @commits, $1;
 573                         }
 574                 }
 575         }
 576         my @revs;
 577         foreach my $c (@commits) {
 578                 my @tmp = command('rev-parse',$c);
 579                 if (scalar @tmp == 1) {
 580                         push @revs, $tmp[0];
 581                 } elsif (scalar @tmp > 1) {
 582                         push @revs, reverse(command('rev-list',@tmp));
 583                 } else {
 584                         fatal "Failed to rev-parse $c";
 585                 }
 586         }
 587         my $gs = Git::SVN->new;
 588         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 589         $gs->fetch;
 590         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 591                 fatal "There are new revisions that were fetched ",
 592                       "and need to be merged (or acknowledged) ",
 593                       "before committing.\nlast rev: $r_last\n",
 594                       " current: $gs->{last_rev}";
 595         }
 596         $gs->set_tree($_) foreach @revs;
 597         print "Done committing ",scalar @revs," revisions to SVN\n";
 598         unlink $gs->{index};
 599 }
 600
 601 sub split_merge_info_range {
 602         my ($range) = @_;
 603         if ($range =~ /(\d+)-(\d+)/) {
 604                 return (int($1), int($2));
 605         } else {
 606                 return (int($range), int($range));
 607         }
 608 }
 609
 610 sub combine_ranges {
 611         my ($in) = @_;
 612
 613         my @fnums = ();
 614         my @arr = split(/,/, $in);
 615         for my $element (@arr) {
 616                 my ($start, $end) = split_merge_info_range($element);
 617                 push @fnums, $start;
 618         }
 619
 620         my @sorted = @arr [ sort {
 621                 $fnums[$a] <=> $fnums[$b]
 622         } 0..$#arr ];
 623
 624         my @return = ();
 625         my $last = -1;
 626         my $first = -1;
 627         for my $element (@sorted) {
 628                 my ($start, $end) = split_merge_info_range($element);
 629
 630                 if ($last == -1) {
 631                         $first = $start;
 632                         $last = $end;
 633                         next;
 634                 }
 635                 if ($start <= $last+1) {
 636                         if ($end > $last) {
 637                                 $last = $end;
 638                         }
 639                         next;
 640                 }
 641                 if ($first == $last) {
 642                         push @return, "$first";
 643                 } else {
 644                         push @return, "$first-$last";
 645                 }
 646                 $first = $start;
 647                 $last = $end;
 648         }
 649
 650         if ($first != -1) {
 651                 if ($first == $last) {
 652                         push @return, "$first";
 653                 } else {
 654                         push @return, "$first-$last";
 655                 }
 656         }
 657
 658         return join(',', @return);
 659 }
 660
 661 sub merge_revs_into_hash {
 662         my ($hash, $minfo) = @_;
 663         my @lines = split(' ', $minfo);
 664
 665         for my $line (@lines) {
 666                 my ($branchpath, $revs) = split(/:/, $line);
 667
 668                 if (exists($hash->{$branchpath})) {
 669                         # Merge the two revision sets
 670                         my $combined = "$hash->{$branchpath},$revs";
 671                         $hash->{$branchpath} = combine_ranges($combined);
 672                 } else {
 673                         # Just do range combining for consolidation
 674                         $hash->{$branchpath} = combine_ranges($revs);
 675                 }
 676         }
 677 }
 678
 679 sub merge_merge_info {
 680         my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_;
 681         my %result_hash = ();
 682
 683         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 684         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 685
 686         delete $result_hash{$ignore_branch} if $ignore_branch;
 687
 688         my $result = '';
 689         # Sort below is for consistency's sake
 690         for my $branchname (sort keys(%result_hash)) {
 691                 my $revlist = $result_hash{$branchname};
 692                 $result .= "$branchname:$revlist\n"
 693         }
 694         return $result;
 695 }
 696
 697 sub populate_merge_info {
 698         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 699
 700         my %parentshash;
 701         read_commit_parents(\%parentshash, $d);
 702         my @parents = @{$parentshash{$d}};
 703         if ($#parents > 0) {
 704                 # Merge commit
 705                 my $all_parents_ok = 1;
 706                 my $aggregate_mergeinfo = '';
 707                 my $rooturl = $gs->repos_root;
 708                 my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/;
 709
 710                 if (defined($rewritten_parent)) {
 711                         # Replace first parent with newly-rewritten version
 712                         shift @parents;
 713                         unshift @parents, $rewritten_parent;
 714                 }
 715
 716                 foreach my $parent (@parents) {
 717                         my ($branchurl, $svnrev, $paruuid) =
 718                                 cmt_metadata($parent);
 719
 720                         unless (defined($svnrev)) {
 721                                 # Should have been caught be preflight check
 722                                 fatal "merge commit $d has ancestor $parent, but that change "
 723                      ."does not have git-svn metadata!";
 724                         }
 725                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 726                                 fatal "commit $parent git-svn metadata changed mid-run!";
 727                         }
 728                         my $branchpath = $1;
 729
 730                         my $ra = Git::SVN::Ra->new($branchurl);
 731                         my (undef, undef, $props) =
 732                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 733                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 734                         unless (defined $par_mergeinfo) {
 735                                 $par_mergeinfo = '';
 736                         }
 737                         # Merge previous mergeinfo values
 738                         $aggregate_mergeinfo =
 739                                 merge_merge_info($aggregate_mergeinfo,
 740                                                                 $par_mergeinfo,
 741                                                                 $target_branch);
 742
 743                         next if $parent eq $parents[0]; # Skip first parent
 744                         # Add new changes being placed in tree by merge
 745                         my @cmd = (qw/rev-list --reverse/,
 746                                            $parent, qw/--not/);
 747                         foreach my $par (@parents) {
 748                                 unless ($par eq $parent) {
 749                                         push @cmd, $par;
 750                                 }
 751                         }
 752                         my @revsin = ();
 753                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 754                         while (<$revlist>) {
 755                                 my $irev = $_;
 756                                 chomp $irev;
 757                                 my (undef, $csvnrev, undef) =
 758                                         cmt_metadata($irev);
 759                                 unless (defined $csvnrev) {
 760                                         # A child is missing SVN annotations...
 761                                         # this might be OK, or might not be.
 762                                         warn "W:child $irev is merged into revision "
 763                                                  ."$d but does not have git-svn metadata. "
 764                                                  ."This means git-svn cannot determine the "
 765                                                  ."svn revision numbers to place into the "
 766                                                  ."svn:mergeinfo property. You must ensure "
 767                                                  ."a branch is entirely committed to "
 768                                                  ."SVN before merging it in order for "
 769                                                  ."svn:mergeinfo population to function "
 770                                                  ."properly";
 771                                 }
 772                                 push @revsin, $csvnrev;
 773                         }
 774                         command_close_pipe($revlist, $ctx);
 775
 776                         last unless $all_parents_ok;
 777
 778                         # We now have a list of all SVN revnos which are
 779                         # merged by this particular parent. Integrate them.
 780                         next if $#revsin == -1;
 781                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 782                         $aggregate_mergeinfo =
 783                                 merge_merge_info($aggregate_mergeinfo,
 784                                                                 $newmergeinfo,
 785                                                                 $target_branch);
 786                 }
 787                 if ($all_parents_ok and $aggregate_mergeinfo) {
 788                         return $aggregate_mergeinfo;
 789                 }
 790         }
 791
 792         return undef;
 793 }
 794
 795 sub dcommit_rebase {
 796         my ($is_last, $current, $fetched_ref, $svn_error) = @_;
 797         my @diff;
 798
 799         if ($svn_error) {
 800                 print STDERR "\nERROR from SVN:\n",
 801                                 $svn_error->expanded_message, "\n";
 802         }
 803         unless ($_no_rebase) {
 804                 # we always want to rebase against the current HEAD,
 805                 # not any head that was passed to us
 806                 @diff = command('diff-tree', $current,
 807                            $fetched_ref, '--');
 808                 my @finish;
 809                 if (@diff) {
 810                         @finish = rebase_cmd();
 811                         print STDERR "W: $current and ", $fetched_ref,
 812                                      " differ, using @finish:\n",
 813                                      join("\n", @diff), "\n";
 814                 } elsif ($is_last) {
 815                         print "No changes between ", $current, " and ",
 816                               $fetched_ref,
 817                               "\nResetting to the latest ",
 818                               $fetched_ref, "\n";
 819                         @finish = qw/reset --mixed/;
 820                 }
 821                 command_noisy(@finish, $fetched_ref) if @finish;
 822         }
 823         if ($svn_error) {
 824                 die "ERROR: Not all changes have been committed into SVN"
 825                         .($_no_rebase ? ".\n" : ", however the committed\n"
 826                         ."ones (if any) seem to be successfully integrated "
 827                         ."into the working tree.\n")
 828                         ."Please see the above messages for details.\n";
 829         }
 830         return @diff;
 831 }
 832
 833 sub cmd_dcommit {
 834         my $head = shift;
 835         command_noisy(qw/update-index --refresh/);
 836         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD --/) }
 837                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 838                 . "or stash them with `git stash'.\n";
 839         $head ||= 'HEAD';
 840
 841         my $old_head;
 842         if ($head ne 'HEAD') {
 843                 $old_head = eval {
 844                         command_oneline([qw/symbolic-ref -q HEAD/])
 845                 };
 846                 if ($old_head) {
 847                         $old_head =~ s{^refs/heads/}{};
 848                 } else {
 849                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 850                 }
 851                 command(['checkout', $head], STDERR => 0);
 852         }
 853
 854         my @refs;
 855         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 856         unless ($gs) {
 857                 die "Unable to determine upstream SVN information from ",
 858                     "$head history.\nPerhaps the repository is empty.";
 859         }
 860
 861         if (defined $_commit_url) {
 862                 $url = $_commit_url;
 863         } else {
 864                 $url = eval { command_oneline('config', '--get',
 865                               "svn-remote.$gs->{repo_id}.commiturl") };
 866                 if (!$url) {
 867                         $url = $gs->full_pushurl
 868                 }
 869         }
 870
 871         my $last_rev = $_revision if defined $_revision;
 872         if ($url) {
 873                 print "Committing to $url ...\n";
 874         }
 875         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 876         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 877                 warn "Attempting to commit more than one change while ",
 878                      "--no-rebase is enabled.\n",
 879                      "If these changes depend on each other, re-running ",
 880                      "without --no-rebase may be required."
 881         }
 882
 883         if (defined $_interactive){
 884                 my $ask_default = "y";
 885                 foreach my $d (@$linear_refs){
 886                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 887                         while (<$fh>){
 888                                 print $_;
 889                         }
 890                         command_close_pipe($fh, $ctx);
 891                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 892                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 893                                  default => $ask_default);
 894                         die "Commit this patch reply required" unless defined $_;
 895                         if (/^[nq]/i) {
 896                                 exit(0);
 897                         } elsif (/^a/i) {
 898                                 last;
 899                         }
 900                 }
 901         }
 902
 903         my $expect_url = $url;
 904
 905         my $push_merge_info = eval {
 906                 command_oneline(qw/config --get svn.pushmergeinfo/)
 907                 };
 908         if (not defined($push_merge_info)
 909                         or $push_merge_info eq "false"
 910                         or $push_merge_info eq "no"
 911                         or $push_merge_info eq "never") {
 912                 $push_merge_info = 0;
 913         }
 914
 915         unless (defined($_merge_info) || ! $push_merge_info) {
 916                 # Preflight check of changes to ensure no issues with mergeinfo
 917                 # This includes check for uncommitted-to-SVN parents
 918                 # (other than the first parent, which we will handle),
 919                 # information from different SVN repos, and paths
 920                 # which are not underneath this repository root.
 921                 my $rooturl = $gs->repos_root;
 922                 Git::SVN::remove_username($rooturl);
 923                 foreach my $d (@$linear_refs) {
 924                         my %parentshash;
 925                         read_commit_parents(\%parentshash, $d);
 926                         my @realparents = @{$parentshash{$d}};
 927                         if ($#realparents > 0) {
 928                                 # Merge commit
 929                                 shift @realparents; # Remove/ignore first parent
 930                                 foreach my $parent (@realparents) {
 931                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 932                                         unless (defined $paruuid) {
 933                                                 # A parent is missing SVN annotations...
 934                                                 # abort the whole operation.
 935                                                 fatal "$parent is merged into revision $d, "
 936                                                          ."but does not have git-svn metadata. "
 937                                                          ."Either dcommit the branch or use a "
 938                                                          ."local cherry-pick, FF merge, or rebase "
 939                                                          ."instead of an explicit merge commit.";
 940                                         }
 941
 942                                         unless ($paruuid eq $uuid) {
 943                                                 # Parent has SVN metadata from different repository
 944                                                 fatal "merge parent $parent for change $d has "
 945                                                          ."git-svn uuid $paruuid, while current change "
 946                                                          ."has uuid $uuid!";
 947                                         }
 948
 949                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 950                                                 # This branch is very strange indeed.
 951                                                 fatal "merge parent $parent for $d is on branch "
 952                                                          ."$branchurl, which is not under the "
 953                                                          ."git-svn root $rooturl!";
 954                                         }
 955                                 }
 956                         }
 957                 }
 958         }
 959
 960         my $rewritten_parent;
 961         my $current_head = command_oneline(qw/rev-parse HEAD/);
 962         Git::SVN::remove_username($expect_url);
 963         if (defined($_merge_info)) {
 964                 $_merge_info =~ tr{ }{\n};
 965         }
 966         while (1) {
 967                 my $d = shift @$linear_refs or last;
 968                 unless (defined $last_rev) {
 969                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 970                         unless (defined $last_rev) {
 971                                 fatal "Unable to extract revision information ",
 972                                       "from commit $d~1";
 973                         }
 974                 }
 975                 if ($_dry_run) {
 976                         print "diff-tree $d~1 $d\n";
 977                 } else {
 978                         my $cmt_rev;
 979
 980                         unless (defined($_merge_info) || ! $push_merge_info) {
 981                                 $_merge_info = populate_merge_info($d, $gs,
 982                                                              $uuid,
 983                                                              $linear_refs,
 984                                                              $rewritten_parent);
 985                         }
 986
 987                         my %ed_opts = ( r => $last_rev,
 988                                         log => get_commit_entry($d)->{log},
 989                                         ra => Git::SVN::Ra->new($url),
 990                                         config => SVN::Core::config_get_config(
 991                                                 $Git::SVN::Ra::config_dir
 992                                         ),
 993                                         tree_a => "$d~1",
 994                                         tree_b => $d,
 995                                         editor_cb => sub {
 996                                                print "Committed r$_[0]\n";
 997                                                $cmt_rev = $_[0];
 998                                         },
 999                                         mergeinfo => $_merge_info,
1000                                         svn_path => '');
1001
1002                         my $err_handler = $SVN::Error::handler;
1003                         $SVN::Error::handler = sub {
1004                                 my $err = shift;
1005                                 dcommit_rebase(1, $current_head, $gs->refname,
1006                                         $err);
1007                         };
1008
1009                         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1010                                 print "No changes\n$d~1 == $d\n";
1011                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
1012                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
1013                                                                $parents->{$d};
1014                         }
1015                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
1016                         $SVN::Error::handler = $err_handler;
1017                         $last_rev = $cmt_rev;
1018                         next if $_no_rebase;
1019
1020                         my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1021                                                 $gs->refname, undef);
1022
1023                         $rewritten_parent = command_oneline(qw/rev-parse/,
1024                                                         $gs->refname);
1025
1026                         if (@diff) {
1027                                 $current_head = command_oneline(qw/rev-parse
1028                                                                 HEAD/);
1029                                 @refs = ();
1030                                 my ($url_, $rev_, $uuid_, $gs_) =
1031                                               working_head_info('HEAD', \@refs);
1032                                 my ($linear_refs_, $parents_) =
1033                                               linearize_history($gs_, \@refs);
1034                                 if (scalar(@$linear_refs) !=
1035                                     scalar(@$linear_refs_)) {
1036                                         fatal "# of revisions changed ",
1037                                           "\nbefore:\n",
1038                                           join("\n", @$linear_refs),
1039                                           "\n\nafter:\n",
1040                                           join("\n", @$linear_refs_), "\n",
1041                                           'If you are attempting to commit ',
1042                                           "merges, try running:\n\t",
1043                                           'git rebase --interactive',
1044                                           '--rebase-merges ',
1045                                           $gs->refname,
1046                                           "\nBefore dcommitting";
1047                                 }
1048                                 if ($url_ ne $expect_url) {
1049                                         if ($url_ eq $gs->metadata_url) {
1050                                                 print
1051                                                   "Accepting rewritten URL:",
1052                                                   " $url_\n";
1053                                         } else {
1054                                                 fatal
1055                                                   "URL mismatch after rebase:",
1056                                                   " $url_ != $expect_url";
1057                                         }
1058                                 }
1059                                 if ($uuid_ ne $uuid) {
1060                                         fatal "uuid mismatch after rebase: ",
1061                                               "$uuid_ != $uuid";
1062                                 }
1063                                 # remap parents
1064                                 my (%p, @l, $i);
1065                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1066                                         my $new = $linear_refs_->[$i] or next;
1067                                         $p{$new} =
1068                                                 $parents->{$linear_refs->[$i]};
1069                                         push @l, $new;
1070                                 }
1071                                 $parents = \%p;
1072                                 $linear_refs = \@l;
1073                                 undef $last_rev;
1074                         }
1075                 }
1076         }
1077
1078         if ($old_head) {
1079                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1080                 my $new_is_symbolic = eval {
1081                         command_oneline(qw/symbolic-ref -q HEAD/);
1082                 };
1083                 if ($new_is_symbolic) {
1084                         print "dcommitted the branch ", $head, "\n";
1085                 } else {
1086                         print "dcommitted on a detached HEAD because you gave ",
1087                               "a revision argument.\n",
1088                               "The rewritten commit is: ", $new_head, "\n";
1089                 }
1090                 command(['checkout', $old_head], STDERR => 0);
1091         }
1092
1093         unlink $gs->{index};
1094 }
1095
1096 sub cmd_branch {
1097         my ($branch_name, $head) = @_;
1098
1099         unless (defined $branch_name && length $branch_name) {
1100                 die(($_tag ? "tag" : "branch") . " name required\n");
1101         }
1102         $head ||= 'HEAD';
1103
1104         my (undef, $rev, undef, $gs) = working_head_info($head);
1105         my $src = $gs->full_pushurl;
1106
1107         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1108         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1109         my $glob;
1110         if ($#{$allglobs} == 0) {
1111                 $glob = $allglobs->[0];
1112         } else {
1113                 unless(defined $_branch_dest) {
1114                         die "Multiple ",
1115                             $_tag ? "tag" : "branch",
1116                             " paths defined for Subversion repository.\n",
1117                             "You must specify where you want to create the ",
1118                             $_tag ? "tag" : "branch",
1119                             " with the --destination argument.\n";
1120                 }
1121                 foreach my $g (@{$allglobs}) {
1122                         my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1123                         if ($_branch_dest =~ /$re/) {
1124                                 $glob = $g;
1125                                 last;
1126                         }
1127                 }
1128                 unless (defined $glob) {
1129                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1130                         foreach my $g (@{$allglobs}) {
1131                                 $g->{path}->{left} =~ /$dest_re/ or next;
1132                                 if (defined $glob) {
1133                                         die "Ambiguous destination: ",
1134                                             $_branch_dest, "\nmatches both '",
1135                                             $glob->{path}->{left}, "' and '",
1136                                             $g->{path}->{left}, "'\n";
1137                                 }
1138                                 $glob = $g;
1139                         }
1140                         unless (defined $glob) {
1141                                 die "Unknown ",
1142                                     $_tag ? "tag" : "branch",
1143                                     " destination $_branch_dest\n";
1144                         }
1145                 }
1146         }
1147         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1148         my $url;
1149         if (defined $_commit_url) {
1150                 $url = $_commit_url;
1151         } else {
1152                 $url = eval { command_oneline('config', '--get',
1153                         "svn-remote.$gs->{repo_id}.commiturl") };
1154                 if (!$url) {
1155                         $url = $remote->{pushurl} || $remote->{url};
1156                 }
1157         }
1158         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1159
1160         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1161                 $src=~s/^http:/https:/;
1162         }
1163
1164         ::_req_svn();
1165         require SVN::Client;
1166
1167         my ($config, $baton, undef) = Git::SVN::Ra::prepare_config_once();
1168         my $ctx = SVN::Client->new(
1169                 auth => $baton,
1170                 config => $config,
1171                 log_msg => sub {
1172                         ${ $_[0] } = defined $_message
1173                                 ? $_message
1174                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1175                                 . $branch_name;
1176                 },
1177         );
1178
1179         eval {
1180                 $ctx->ls($dst, 'HEAD', 0);
1181         } and die "branch ${branch_name} already exists\n";
1182
1183         if ($_parents) {
1184                 mk_parent_dirs($ctx, $dst);
1185         }
1186
1187         print "Copying ${src} at r${rev} to ${dst}...\n";
1188         $ctx->copy($src, $rev, $dst)
1189                 unless $_dry_run;
1190
1191         # Release resources held by ctx before creating another SVN::Ra
1192         # so destruction is orderly.  This seems necessary with SVN 1.9.5
1193         # to avoid segfaults.
1194         $ctx = undef;
1195
1196         $gs->fetch_all;
1197 }
1198
1199 sub mk_parent_dirs {
1200         my ($ctx, $parent) = @_;
1201         $parent =~ s{/[^/]*$}{};
1202
1203         if (!eval{$ctx->ls($parent, 'HEAD', 0)}) {
1204                 mk_parent_dirs($ctx, $parent);
1205                 print "Creating parent folder ${parent} ...\n";
1206                 $ctx->mkdir($parent) unless $_dry_run;
1207         }
1208 }
1209
1210 sub cmd_find_rev {
1211         my $revision_or_hash = shift or die "SVN or git revision required ",
1212                                             "as a command-line argument\n";
1213         my $result;
1214         if ($revision_or_hash =~ /^r\d+$/) {
1215                 my $head = shift;
1216                 $head ||= 'HEAD';
1217                 my @refs;
1218                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1219                 unless ($gs) {
1220                         die "Unable to determine upstream SVN information from ",
1221                             "$head history\n";
1222                 }
1223                 my $desired_revision = substr($revision_or_hash, 1);
1224                 if ($_before) {
1225                         $result = $gs->find_rev_before($desired_revision, 1);
1226                 } elsif ($_after) {
1227                         $result = $gs->find_rev_after($desired_revision, 1);
1228                 } else {
1229                         $result = $gs->rev_map_get($desired_revision, $uuid);
1230                 }
1231         } else {
1232                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1233                 $result = $rev;
1234         }
1235         print "$result\n" if $result;
1236 }
1237
1238 sub auto_create_empty_directories {
1239         my ($gs) = @_;
1240         my $var = eval { command_oneline('config', '--get', '--bool',
1241                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1242         # By default, create empty directories by consulting the unhandled log,
1243         # but allow setting it to 'false' to skip it.
1244         return !($var && $var eq 'false');
1245 }
1246
1247 sub cmd_rebase {
1248         command_noisy(qw/update-index --refresh/);
1249         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1250         unless ($gs) {
1251                 die "Unable to determine upstream SVN information from ",
1252                     "working tree history\n";
1253         }
1254         if ($_dry_run) {
1255                 print "Remote Branch: " . $gs->refname . "\n";
1256                 print "SVN URL: " . $url . "\n";
1257                 return;
1258         }
1259         if (command(qw/diff-index HEAD --/)) {
1260                 print STDERR "Cannot rebase with uncommitted changes:\n";
1261                 command_noisy('status');
1262                 exit 1;
1263         }
1264         unless ($_local) {
1265                 # rebase will checkout for us, so no need to do it explicitly
1266                 $_no_checkout = 'true';
1267                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1268         }
1269         command_noisy(rebase_cmd(), $gs->refname);
1270         if (auto_create_empty_directories($gs)) {
1271                 $gs->mkemptydirs;
1272         }
1273 }
1274
1275 sub cmd_show_ignore {
1276         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1277         $gs ||= Git::SVN->new;
1278         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1279         $gs->prop_walk($gs->path, $r, sub {
1280                 my ($gs, $path, $props) = @_;
1281                 print STDOUT "\n# $path\n";
1282                 my $s = $props->{'svn:ignore'} or return;
1283                 $s =~ s/[\r\n]+/\n/g;
1284                 $s =~ s/^\n+//;
1285                 chomp $s;
1286                 $s =~ s#^#$path#gm;
1287                 print STDOUT "$s\n";
1288         });
1289 }
1290
1291 sub cmd_show_externals {
1292         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1293         $gs ||= Git::SVN->new;
1294         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1295         $gs->prop_walk($gs->path, $r, sub {
1296                 my ($gs, $path, $props) = @_;
1297                 print STDOUT "\n# $path\n";
1298                 my $s = $props->{'svn:externals'} or return;
1299                 $s =~ s/[\r\n]+/\n/g;
1300                 chomp $s;
1301                 $s =~ s#^#$path#gm;
1302                 print STDOUT "$s\n";
1303         });
1304 }
1305
1306 sub cmd_create_ignore {
1307         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1308         $gs ||= Git::SVN->new;
1309         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1310         $gs->prop_walk($gs->path, $r, sub {
1311                 my ($gs, $path, $props) = @_;
1312                 # $path is of the form /path/to/dir/
1313                 $path = '.' . $path;
1314                 # SVN can have attributes on empty directories,
1315                 # which git won't track
1316                 mkpath([$path]) unless -d $path;
1317                 my $ignore = $path . '.gitignore';
1318                 my $s = $props->{'svn:ignore'} or return;
1319                 open(GITIGNORE, '>', $ignore)
1320                   or fatal("Failed to open `$ignore' for writing: $!");
1321                 $s =~ s/[\r\n]+/\n/g;
1322                 $s =~ s/^\n+//;
1323                 chomp $s;
1324                 # Prefix all patterns so that the ignore doesn't apply
1325                 # to sub-directories.
1326                 $s =~ s#^#/#gm;
1327                 print GITIGNORE "$s\n";
1328                 close(GITIGNORE)
1329                   or fatal("Failed to close `$ignore': $!");
1330                 command_noisy('add', '-f', $ignore);
1331         });
1332 }
1333
1334 sub cmd_mkdirs {
1335         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1336         $gs ||= Git::SVN->new;
1337         $gs->mkemptydirs($_revision);
1338 }
1339
1340 # get_svnprops(PATH)
1341 # ------------------
1342 # Helper for cmd_propget and cmd_proplist below.
1343 sub get_svnprops {
1344         my $path = shift;
1345         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1346         $gs ||= Git::SVN->new;
1347
1348         # prefix THE PATH by the sub-directory from which the user
1349         # invoked us.
1350         $path = $cmd_dir_prefix . $path;
1351         fatal("No such file or directory: $path") unless -e $path;
1352         my $is_dir = -d $path ? 1 : 0;
1353         $path = join_paths($gs->path, $path);
1354
1355         # canonicalize the path (otherwise libsvn will abort or fail to
1356         # find the file)
1357         $path = canonicalize_path($path);
1358
1359         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1360         my $props;
1361         if ($is_dir) {
1362                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1363         }
1364         else {
1365                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1366         }
1367         return $props;
1368 }
1369
1370 # cmd_propget (PROP, PATH)
1371 # ------------------------
1372 # Print the SVN property PROP for PATH.
1373 sub cmd_propget {
1374         my ($prop, $path) = @_;
1375         $path = '.' if not defined $path;
1376         usage(1) if not defined $prop;
1377         my $props = get_svnprops($path);
1378         if (not defined $props->{$prop}) {
1379                 fatal("`$path' does not have a `$prop' SVN property.");
1380         }
1381         print $props->{$prop} . "\n";
1382 }
1383
1384 # cmd_propset (PROPNAME, PROPVAL, PATH)
1385 # ------------------------
1386 # Adjust the SVN property PROPNAME to PROPVAL for PATH.
1387 sub cmd_propset {
1388         my ($propname, $propval, $path) = @_;
1389         $path = '.' if not defined $path;
1390         $path = $cmd_dir_prefix . $path;
1391         usage(1) if not defined $propname;
1392         usage(1) if not defined $propval;
1393         my $file = basename($path);
1394         my $dn = dirname($path);
1395         my $cur_props = Git::SVN::Editor::check_attr( "svn-properties", $path );
1396         my @new_props;
1397         if (!$cur_props || $cur_props eq "unset" || $cur_props eq "" || $cur_props eq "set") {
1398                 push @new_props, "$propname=$propval";
1399         } else {
1400                 # TODO: handle combining properties better
1401                 my @props = split(/;/, $cur_props);
1402                 my $replaced_prop;
1403                 foreach my $prop (@props) {
1404                         # Parse 'name=value' syntax and set the property.
1405                         if ($prop =~ /([^=]+)=(.*)/) {
1406                                 my ($n,$v) = ($1,$2);
1407                                 if ($n eq $propname) {
1408                                         $v = $propval;
1409                                         $replaced_prop = 1;
1410                                 }
1411                                 push @new_props, "$n=$v";
1412                         }
1413                 }
1414                 if (!$replaced_prop) {
1415                         push @new_props, "$propname=$propval";
1416                 }
1417         }
1418         my $attrfile = "$dn/.gitattributes";
1419         open my $attrfh, '>>', $attrfile or die "Can't open $attrfile: $!\n";
1420         # TODO: don't simply append here if $file already has svn-properties
1421         my $new_props = join(';', @new_props);
1422         print $attrfh "$file svn-properties=$new_props\n" or
1423                 die "write to $attrfile: $!\n";
1424         close $attrfh or die "close $attrfile: $!\n";
1425 }
1426
1427 # cmd_proplist (PATH)
1428 # -------------------
1429 # Print the list of SVN properties for PATH.
1430 sub cmd_proplist {
1431         my $path = shift;
1432         $path = '.' if not defined $path;
1433         my $props = get_svnprops($path);
1434         print "Properties on '$path':\n";
1435         foreach (sort keys %{$props}) {
1436                 print "  $_\n";
1437         }
1438 }
1439
1440 sub cmd_multi_init {
1441         my $url = shift;
1442         unless (defined $_trunk || @_branches || @_tags) {
1443                 usage(1);
1444         }
1445
1446         $_prefix = 'origin/' unless defined $_prefix;
1447         if (defined $url) {
1448                 $url = canonicalize_url($url);
1449                 init_subdir(@_);
1450         }
1451         do_git_init_db();
1452         if (defined $_trunk) {
1453                 $_trunk =~ s#^/+##;
1454                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1455                 # try both old-style and new-style lookups:
1456                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1457                 unless ($gs_trunk) {
1458                         my ($trunk_url, $trunk_path) =
1459                                               complete_svn_url($url, $_trunk);
1460                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1461                                                    undef, $trunk_ref);
1462                 }
1463         }
1464         return unless @_branches || @_tags;
1465         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1466         foreach my $path (@_branches) {
1467                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1468         }
1469         foreach my $path (@_tags) {
1470                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1471         }
1472 }
1473
1474 sub cmd_multi_fetch {
1475         $Git::SVN::no_reuse_existing = undef;
1476         my $remotes = Git::SVN::read_all_remotes();
1477         foreach my $repo_id (sort keys %$remotes) {
1478                 if ($remotes->{$repo_id}->{url}) {
1479                         Git::SVN::fetch_all($repo_id, $remotes);
1480                 }
1481         }
1482 }
1483
1484 # this command is special because it requires no metadata
1485 sub cmd_commit_diff {
1486         my ($ta, $tb, $url) = @_;
1487         my $usage = "usage: $0 commit-diff -r<revision> ".
1488                     "<tree-ish> <tree-ish> [<URL>]";
1489         fatal($usage) if (!defined $ta || !defined $tb);
1490         my $svn_path = '';
1491         if (!defined $url) {
1492                 my $gs = eval { Git::SVN->new };
1493                 if (!$gs) {
1494                         fatal("Needed URL or usable git-svn --id in ",
1495                               "the command-line\n", $usage);
1496                 }
1497                 $url = $gs->url;
1498                 $svn_path = $gs->path;
1499         }
1500         unless (defined $_revision) {
1501                 fatal("-r|--revision is a required argument\n", $usage);
1502         }
1503         if (defined $_message && defined $_file) {
1504                 fatal("Both --message/-m and --file/-F specified ",
1505                       "for the commit message.\n",
1506                       "I have no idea what you mean");
1507         }
1508         if (defined $_file) {
1509                 $_message = file_to_s($_file);
1510         } else {
1511                 $_message ||= get_commit_entry($tb)->{log};
1512         }
1513         my $ra ||= Git::SVN::Ra->new($url);
1514         my $r = $_revision;
1515         if ($r eq 'HEAD') {
1516                 $r = $ra->get_latest_revnum;
1517         } elsif ($r !~ /^\d+$/) {
1518                 die "revision argument: $r not understood by git-svn\n";
1519         }
1520         my %ed_opts = ( r => $r,
1521                         log => $_message,
1522                         ra => $ra,
1523                         tree_a => $ta,
1524                         tree_b => $tb,
1525                         editor_cb => sub { print "Committed r$_[0]\n" },
1526                         svn_path => $svn_path );
1527         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1528                 print "No changes\n$ta == $tb\n";
1529         }
1530 }
1531
1532 sub cmd_info {
1533         my $path_arg = defined($_[0]) ? $_[0] : '.';
1534         my $path = $path_arg;
1535         if (File::Spec->file_name_is_absolute($path)) {
1536                 $path = canonicalize_path($path);
1537
1538                 my $toplevel = eval {
1539                         my @cmd = qw/rev-parse --show-toplevel/;
1540                         command_oneline(\@cmd, STDERR => 0);
1541                 };
1542
1543                 # remove $toplevel from the absolute path:
1544                 my ($vol, $dirs, $file) = File::Spec->splitpath($path);
1545                 my (undef, $tdirs, $tfile) = File::Spec->splitpath($toplevel);
1546                 my @dirs = File::Spec->splitdir($dirs);
1547                 my @tdirs = File::Spec->splitdir($tdirs);
1548                 pop @dirs if $dirs[-1] eq '';
1549                 pop @tdirs if $tdirs[-1] eq '';
1550                 push @dirs, $file;
1551                 push @tdirs, $tfile;
1552                 while (@tdirs && @dirs && $tdirs[0] eq $dirs[0]) {
1553                         shift @dirs;
1554                         shift @tdirs;
1555                 }
1556                 $dirs = File::Spec->catdir(@dirs);
1557                 $path = File::Spec->catpath($vol, $dirs);
1558
1559                 $path = canonicalize_path($path);
1560         } else {
1561                 $path = canonicalize_path($cmd_dir_prefix . $path);
1562         }
1563         if (exists $_[1]) {
1564                 die "Too many arguments specified\n";
1565         }
1566
1567         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1568
1569         if (!$file_type && !$diff_status) {
1570                 print STDERR "svn: '$path' is not under version control\n";
1571                 exit 1;
1572         }
1573
1574         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1575         unless ($gs) {
1576                 die "Unable to determine upstream SVN information from ",
1577                     "working tree history\n";
1578         }
1579
1580         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1581         $path = "." if $path eq "";
1582
1583         my $full_url = canonicalize_url( add_path_to_url( $url, $path ) );
1584
1585         if ($_url) {
1586                 print "$full_url\n";
1587                 return;
1588         }
1589
1590         my $result = "Path: $path_arg\n";
1591         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1592         $result .= "URL: $full_url\n";
1593
1594         eval {
1595                 my $repos_root = $gs->repos_root;
1596                 Git::SVN::remove_username($repos_root);
1597                 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1598         };
1599         if ($@) {
1600                 $result .= "Repository Root: (offline)\n";
1601         }
1602         ::_req_svn();
1603         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1604                 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1605         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1606
1607         $result .= "Node Kind: " .
1608                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1609
1610         my $schedule = $diff_status eq "A"
1611                        ? "add"
1612                        : ($diff_status eq "D" ? "delete" : "normal");
1613         $result .= "Schedule: $schedule\n";
1614
1615         if ($diff_status eq "A") {
1616                 print $result, "\n";
1617                 return;
1618         }
1619
1620         my ($lc_author, $lc_rev, $lc_date_utc);
1621         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
1622         my $log = command_output_pipe(@args);
1623         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1624         while (<$log>) {
1625                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1626                         $lc_author = $1;
1627                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1628                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1629                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1630                 }
1631         }
1632         close $log;
1633
1634         Git::SVN::Log::set_local_timezone();
1635
1636         $result .= "Last Changed Author: $lc_author\n";
1637         $result .= "Last Changed Rev: $lc_rev\n";
1638         $result .= "Last Changed Date: " .
1639                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1640
1641         if ($file_type ne "dir") {
1642                 my $text_last_updated_date =
1643                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1644                 $result .=
1645                     "Text Last Updated: " .
1646                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1647                     "\n";
1648                 my $checksum;
1649                 if ($diff_status eq "D") {
1650                         my ($fh, $ctx) =
1651                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1652                         if ($file_type eq "link") {
1653                                 my $file_name = <$fh>;
1654                                 $checksum = md5sum("link $file_name");
1655                         } else {
1656                                 $checksum = md5sum($fh);
1657                         }
1658                         command_close_pipe($fh, $ctx);
1659                 } elsif ($file_type eq "link") {
1660                         my $file_name =
1661                             command(qw(cat-file blob), "HEAD:$path");
1662                         $checksum =
1663                             md5sum("link " . $file_name);
1664                 } else {
1665                         open FILE, "<", $path or die $!;
1666                         $checksum = md5sum(\*FILE);
1667                         close FILE or die $!;
1668                 }
1669                 $result .= "Checksum: " . $checksum . "\n";
1670         }
1671
1672         print $result, "\n";
1673 }
1674
1675 sub cmd_reset {
1676         my $target = shift || $_revision or die "SVN revision required\n";
1677         $target = $1 if $target =~ /^r(\d+)$/;
1678         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1679         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1680         unless ($gs) {
1681                 die "Unable to determine upstream SVN information from ".
1682                     "history\n";
1683         }
1684         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1685         die "Cannot find SVN revision $target\n" unless defined($c);
1686         $gs->rev_map_set($r, $c, 'reset', $uuid);
1687         print "r$r = $c ($gs->{ref_id})\n";
1688 }
1689
1690 sub cmd_gc {
1691         require File::Find;
1692         if (!can_compress()) {
1693                 warn "Compress::Zlib could not be found; unhandled.log " .
1694                      "files will not be compressed.\n";
1695         }
1696         File::Find::find({ wanted => \&gc_directory, no_chdir => 1},
1697                          Git::SVN::svn_dir());
1698 }
1699
1700 ########################### utility functions #########################
1701
1702 sub rebase_cmd {
1703         my @cmd = qw/rebase/;
1704         push @cmd, '-v' if $_verbose;
1705         push @cmd, qw/--merge/ if $_merge;
1706         push @cmd, "--strategy=$_strategy" if $_strategy;
1707         push @cmd, "--rebase-merges" if $_rebase_merges;
1708         @cmd;
1709 }
1710
1711 sub post_fetch_checkout {
1712         return if $_no_checkout;
1713         return if verify_ref('HEAD^0');
1714         my $gs = $Git::SVN::_head or return;
1715
1716         # look for "trunk" ref if it exists
1717         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1718         my $fetch = $remote->{fetch};
1719         if ($fetch) {
1720                 foreach my $p (keys %$fetch) {
1721                         basename($fetch->{$p}) eq 'trunk' or next;
1722                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1723                         last;
1724                 }
1725         }
1726
1727         command_noisy(qw(update-ref HEAD), $gs->refname);
1728         return unless verify_ref('HEAD^0');
1729
1730         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1731         my $index = command_oneline(qw(rev-parse --git-path index));
1732         return if -f $index;
1733
1734         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1735         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1736         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1737         print STDERR "Checked out HEAD:\n  ",
1738                      $gs->full_url, " r", $gs->last_rev, "\n";
1739         if (auto_create_empty_directories($gs)) {
1740                 $gs->mkemptydirs($gs->last_rev);
1741         }
1742 }
1743
1744 sub complete_svn_url {
1745         my ($url, $path) = @_;
1746
1747         if ($path =~ m#^[a-z\+]+://#i) { # path is a URL
1748                 $path = canonicalize_url($path);
1749         } else {
1750                 $path = canonicalize_path($path);
1751                 if (!defined $url || $url !~ m#^[a-z\+]+://#i) {
1752                         fatal("E: '$path' is not a complete URL ",
1753                               "and a separate URL is not specified");
1754                 }
1755                 return ($url, $path);
1756         }
1757         return ($path, '');
1758 }
1759
1760 sub complete_url_ls_init {
1761         my ($ra, $repo_path, $switch, $pfx) = @_;
1762         unless ($repo_path) {
1763                 print STDERR "W: $switch not specified\n";
1764                 return;
1765         }
1766         if ($repo_path =~ m#^[a-z\+]+://#i) {
1767                 $repo_path = canonicalize_url($repo_path);
1768                 $ra = Git::SVN::Ra->new($repo_path);
1769                 $repo_path = '';
1770         } else {
1771                 $repo_path = canonicalize_path($repo_path);
1772                 $repo_path =~ s#^/+##;
1773                 unless ($ra) {
1774                         fatal("E: '$repo_path' is not a complete URL ",
1775                               "and a separate URL is not specified");
1776                 }
1777         }
1778         my $url = $ra->url;
1779         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1780         my $k = "svn-remote.$gs->{repo_id}.url";
1781         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1782         if ($orig_url && ($orig_url ne $gs->url)) {
1783                 die "$k already set: $orig_url\n",
1784                     "wanted to set to: $gs->url\n";
1785         }
1786         command_oneline('config', $k, $gs->url) unless $orig_url;
1787
1788         my $remote_path = join_paths( $gs->path, $repo_path );
1789         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1790         $remote_path =~ s#^/##g;
1791         $remote_path .= "/*" if $remote_path !~ /\*/;
1792         my ($n) = ($switch =~ /^--(\w+)/);
1793         if (length $pfx && $pfx !~ m#/$#) {
1794                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1795         }
1796         command_noisy('config',
1797                       '--add',
1798                       "svn-remote.$gs->{repo_id}.$n",
1799                       "$remote_path:refs/remotes/$pfx*" .
1800                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1801 }
1802
1803 sub verify_ref {
1804         my ($ref) = @_;
1805         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1806                                { STDERR => 0 }); };
1807 }
1808
1809 sub get_tree_from_treeish {
1810         my ($treeish) = @_;
1811         # $treeish can be a symbolic ref, too:
1812         my $type = command_oneline(qw/cat-file -t/, $treeish);
1813         my $expected;
1814         while ($type eq 'tag') {
1815                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1816         }
1817         if ($type eq 'commit') {
1818                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1819                                                     $treeish))[0];
1820                 ($expected) = ($expected =~ /^tree ($oid)$/o);
1821                 die "Unable to get tree from $treeish\n" unless $expected;
1822         } elsif ($type eq 'tree') {
1823                 $expected = $treeish;
1824         } else {
1825                 die "$treeish is a $type, expected tree, tag or commit\n";
1826         }
1827         return $expected;
1828 }
1829
1830 sub get_commit_entry {
1831         my ($treeish) = shift;
1832         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1833         my @git_path = qw(rev-parse --git-path);
1834         my $commit_editmsg = command_oneline(@git_path, 'COMMIT_EDITMSG');
1835         my $commit_msg = command_oneline(@git_path, 'COMMIT_MSG');
1836         open my $log_fh, '>', $commit_editmsg or croak $!;
1837
1838         my $type = command_oneline(qw/cat-file -t/, $treeish);
1839         if ($type eq 'commit' || $type eq 'tag') {
1840                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1841                                                          $type, $treeish);
1842                 my $in_msg = 0;
1843                 my $author;
1844                 my $saw_from = 0;
1845                 my $msgbuf = "";
1846                 while (<$msg_fh>) {
1847                         if (!$in_msg) {
1848                                 $in_msg = 1 if (/^$/);
1849                                 $author = $1 if (/^author (.*>)/);
1850                         } elsif (/^git-svn-id: /) {
1851                                 # skip this for now, we regenerate the
1852                                 # correct one on re-fetch anyways
1853                                 # TODO: set *:merge properties or like...
1854                         } else {
1855                                 if (/^From:/ || /^Signed-off-by:/) {
1856                                         $saw_from = 1;
1857                                 }
1858                                 $msgbuf .= $_;
1859                         }
1860                 }
1861                 $msgbuf =~ s/\s+$//s;
1862                 $msgbuf =~ s/\r\n/\n/sg; # SVN 1.6+ disallows CRLF
1863                 if ($Git::SVN::_add_author_from && defined($author)
1864                     && !$saw_from) {
1865                         $msgbuf .= "\n\nFrom: $author";
1866                 }
1867                 print $log_fh $msgbuf or croak $!;
1868                 command_close_pipe($msg_fh, $ctx);
1869         }
1870         close $log_fh or croak $!;
1871
1872         if ($_edit || ($type eq 'tree')) {
1873                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1874                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1875         }
1876         rename $commit_editmsg, $commit_msg or croak $!;
1877         {
1878                 require Encode;
1879                 # SVN requires messages to be UTF-8 when entering the repo
1880                 open $log_fh, '<', $commit_msg or croak $!;
1881                 binmode $log_fh;
1882                 chomp($log_entry{log} = get_record($log_fh, undef));
1883
1884                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1885                 my $msg = $log_entry{log};
1886
1887                 eval { $msg = Encode::decode($enc, $msg, 1) };
1888                 if ($@) {
1889                         die "Could not decode as $enc:\n", $msg,
1890                             "\nPerhaps you need to set i18n.commitencoding\n";
1891                 }
1892
1893                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1894                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1895
1896                 $log_entry{log} = $msg;
1897
1898                 close $log_fh or croak $!;
1899         }
1900         unlink $commit_msg;
1901         \%log_entry;
1902 }
1903
1904 sub s_to_file {
1905         my ($str, $file, $mode) = @_;
1906         open my $fd,'>',$file or croak $!;
1907         print $fd $str,"\n" or croak $!;
1908         close $fd or croak $!;
1909         chmod ($mode &~ umask, $file) if (defined $mode);
1910 }
1911
1912 sub file_to_s {
1913         my $file = shift;
1914         open my $fd,'<',$file or croak "$!: file: $file\n";
1915         local $/;
1916         my $ret = <$fd>;
1917         close $fd or croak $!;
1918         $ret =~ s/\s*$//s;
1919         return $ret;
1920 }
1921
1922 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1923 sub load_authors {
1924         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1925         my $log = $cmd eq 'log';
1926         while (<$authors>) {
1927                 chomp;
1928                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.*)>\s*$/;
1929                 my ($user, $name, $email) = ($1, $2, $3);
1930                 if ($log) {
1931                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1932                 } else {
1933                         $users{$user} = [$name, $email];
1934                 }
1935         }
1936         close $authors or croak $!;
1937 }
1938
1939 # convert GetOpt::Long specs for use by git-config
1940 sub read_git_config {
1941         my $opts = shift;
1942         my @config_only;
1943         foreach my $o (keys %$opts) {
1944                 # if we have mixedCase and a long option-only, then
1945                 # it's a config-only variable that we don't need for
1946                 # the command-line.
1947                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1948                 my $v = $opts->{$o};
1949                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1950                 $key =~ s/-//g;
1951                 my $arg = 'git config';
1952                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1953                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1954                 if (ref $v eq 'ARRAY') {
1955                         chomp(my @tmp = `$arg --get-all svn.$key`);
1956                         @$v = @tmp if @tmp;
1957                 } else {
1958                         chomp(my $tmp = `$arg --get svn.$key`);
1959                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1960                                 $$v = $tmp;
1961                         }
1962                 }
1963         }
1964         load_object_format();
1965         delete @$opts{@config_only} if @config_only;
1966 }
1967
1968 sub load_object_format {
1969         chomp(my $hash = `git config --get extensions.objectformat`);
1970         $::oid_length = 64 if $hash eq 'sha256';
1971 }
1972
1973 sub extract_metadata {
1974         my $id = shift or return (undef, undef, undef);
1975         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1976                                                         \s([a-f\d\-]+)$/ix);
1977         if (!defined $rev || !$uuid || !$url) {
1978                 # some of the original repositories I made had
1979                 # identifiers like this:
1980                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1981         }
1982         return ($url, $rev, $uuid);
1983 }
1984
1985 sub cmt_metadata {
1986         return extract_metadata((grep(/^git-svn-id: /,
1987                 command(qw/cat-file commit/, shift)))[-1]);
1988 }
1989
1990 sub cmt_sha2rev_batch {
1991         my %s2r;
1992         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1993         my $list = shift;
1994
1995         foreach my $sha (@{$list}) {
1996                 my $first = 1;
1997                 my $size = 0;
1998                 print $out $sha, "\n";
1999
2000                 while (my $line = <$in>) {
2001                         if ($first && $line =~ /^$::oid\smissing$/) {
2002                                 last;
2003                         } elsif ($first &&
2004                                $line =~ /^$::oid\scommit\s(\d+)$/) {
2005                                 $first = 0;
2006                                 $size = $1;
2007                                 next;
2008                         } elsif ($line =~ /^(git-svn-id: )/) {
2009                                 my (undef, $rev, undef) =
2010                                                       extract_metadata($line);
2011                                 $s2r{$sha} = $rev;
2012                         }
2013
2014                         $size -= length($line);
2015                         last if ($size == 0);
2016                 }
2017         }
2018
2019         command_close_bidi_pipe($pid, $in, $out, $ctx);
2020
2021         return \%s2r;
2022 }
2023
2024 sub working_head_info {
2025         my ($head, $refs) = @_;
2026         my @args = qw/rev-list --first-parent --pretty=medium/;
2027         my ($fh, $ctx) = command_output_pipe(@args, $head, "--");
2028         my $hash;
2029         my %max;
2030         while (<$fh>) {
2031                 if ( m{^commit ($::oid)$} ) {
2032                         unshift @$refs, $hash if $hash and $refs;
2033                         $hash = $1;
2034                         next;
2035                 }
2036                 next unless s{^\s*(git-svn-id:)}{$1};
2037                 my ($url, $rev, $uuid) = extract_metadata($_);
2038                 if (defined $url && defined $rev) {
2039                         next if $max{$url} and $max{$url} < $rev;
2040                         if (my $gs = Git::SVN->find_by_url($url)) {
2041                                 my $c = $gs->rev_map_get($rev, $uuid);
2042                                 if ($c && $c eq $hash) {
2043                                         close $fh; # break the pipe
2044                                         return ($url, $rev, $uuid, $gs);
2045                                 } else {
2046                                         $max{$url} ||= $gs->rev_map_max;
2047                                 }
2048                         }
2049                 }
2050         }
2051         command_close_pipe($fh, $ctx);
2052         (undef, undef, undef, undef);
2053 }
2054
2055 sub read_commit_parents {
2056         my ($parents, $c) = @_;
2057         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
2058         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
2059         @{$parents->{$c}} = split(/ /, $p);
2060 }
2061
2062 sub linearize_history {
2063         my ($gs, $refs) = @_;
2064         my %parents;
2065         foreach my $c (@$refs) {
2066                 read_commit_parents(\%parents, $c);
2067         }
2068
2069         my @linear_refs;
2070         my %skip = ();
2071         my $last_svn_commit = $gs->last_commit;
2072         foreach my $c (reverse @$refs) {
2073                 next if $c eq $last_svn_commit;
2074                 last if $skip{$c};
2075
2076                 unshift @linear_refs, $c;
2077                 $skip{$c} = 1;
2078
2079                 # we only want the first parent to diff against for linear
2080                 # history, we save the rest to inject when we finalize the
2081                 # svn commit
2082                 my $fp_a = verify_ref("$c~1");
2083                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
2084                 if (!$fp_a || !$fp_b) {
2085                         die "Commit $c\n",
2086                             "has no parent commit, and therefore ",
2087                             "nothing to diff against.\n",
2088                             "You should be working from a repository ",
2089                             "originally created by git-svn\n";
2090                 }
2091                 if ($fp_a ne $fp_b) {
2092                         die "$c~1 = $fp_a, however parsing commit $c ",
2093                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
2094                 }
2095
2096                 foreach my $p (@{$parents{$c}}) {
2097                         $skip{$p} = 1;
2098                 }
2099         }
2100         (\@linear_refs, \%parents);
2101 }
2102
2103 sub find_file_type_and_diff_status {
2104         my ($path) = @_;
2105         return ('dir', '') if $path eq '';
2106
2107         my $diff_output =
2108             command_oneline(qw(diff --cached --name-status --), $path) || "";
2109         my $diff_status = (split(' ', $diff_output))[0] || "";
2110
2111         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
2112
2113         return (undef, undef) if !$diff_status && !$ls_tree;
2114
2115         if ($diff_status eq "A") {
2116                 return ("link", $diff_status) if -l $path;
2117                 return ("dir", $diff_status) if -d $path;
2118                 return ("file", $diff_status);
2119         }
2120
2121         my $mode = (split(' ', $ls_tree))[0] || "";
2122
2123         return ("link", $diff_status) if $mode eq "120000";
2124         return ("dir", $diff_status) if $mode eq "040000";
2125         return ("file", $diff_status);
2126 }
2127
2128 sub md5sum {
2129         my $arg = shift;
2130         my $ref = ref $arg;
2131         require Digest::MD5;
2132         my $md5 = Digest::MD5->new();
2133         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2134                 $md5->addfile($arg) or croak $!;
2135         } elsif ($ref eq 'SCALAR') {
2136                 $md5->add($$arg) or croak $!;
2137         } elsif (!$ref) {
2138                 $md5->add($arg) or croak $!;
2139         } else {
2140                 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2141         }
2142         return $md5->hexdigest();
2143 }
2144
2145 sub gc_directory {
2146         if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2147                 my $out_filename = $_ . ".gz";
2148                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2149                 binmode $in_fh;
2150                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2151                                 die "Unable to open $out_filename: $!\n";
2152
2153                 my $res;
2154                 while ($res = sysread($in_fh, my $str, 1024)) {
2155                         $gz->gzwrite($str) or
2156                                 die "Unable to write: ".$gz->gzerror()."!\n";
2157                 }
2158                 no warnings 'once'; # $File::Find::name would warn
2159                 unlink $_ or die "unlink $File::Find::name: $!\n";
2160         } elsif (-f $_ && basename($_) eq "index") {
2161                 unlink $_ or die "unlink $_: $!\n";
2162         }
2163 }
2164
2165 __END__
2166
2167 Data structures:
2168
2169
2170 $remotes = { # returned by read_all_remotes()
2171         'svn' => {
2172                 # svn-remote.svn.url=https://svn.musicpd.org
2173                 url => 'https://svn.musicpd.org',
2174                 # svn-remote.svn.fetch=mpd/trunk:trunk
2175                 fetch => {
2176                         'mpd/trunk' => 'trunk',
2177                 },
2178                 # svn-remote.svn.tags=mpd/tags/*:tags/*
2179                 tags => {
2180                         path => {
2181                                 left => 'mpd/tags',
2182                                 right => '',
2183                                 regex => qr!mpd/tags/([^/]+)$!,
2184                                 glob => 'tags/*',
2185                         },
2186                         ref => {
2187                                 left => 'tags',
2188                                 right => '',
2189                                 regex => qr!tags/([^/]+)$!,
2190                                 glob => 'tags/*',
2191                         },
2192                 }
2193         }
2194 };
2195
2196 $log_entry hashref as returned by libsvn_log_entry()
2197 {
2198         log => 'whitespace-formatted log entry
2199 ',                                              # trailing newline is preserved
2200         revision => '8',                        # integer
2201         date => '2004-02-24T17:01:44.108345Z',  # commit date
2202         author => 'committer name'
2203 };
2204
2205
2206 # this is generated by generate_diff();
2207 @mods = array of diff-index line hashes, each element represents one line
2208         of diff-index output
2209
2210 diff-index line ($m hash)
2211 {
2212         mode_a => first column of diff-index output, no leading ':',
2213         mode_b => second column of diff-index output,
2214         sha1_b => sha1sum of the final blob,
2215         chg => change type [MCRADT],
2216         file_a => original file name of a file (iff chg is 'C' or 'R')
2217         file_b => new/current file name of a file (any chg)
2218 }
2219 ;
2220
2221 # retval of read_url_paths{,_all}();
2222 $l_map = {
2223         # repository root url
2224         'https://svn.musicpd.org' => {
2225                 # repository path               # GIT_SVN_ID
2226                 'mpd/trunk'             =>      'trunk',
2227                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2228         },
2229 }
2230
2231 Notes:
2232         I don't trust the each() function on unless I created %hash myself
2233         because the internal iterator may not have started at base.