git-cvsimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile tmpnam);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2 ENOENT);
  27 use IPC::Open2;
  28
  29 $SIG{'PIPE'}="IGNORE";
  30 $ENV{'TZ'}="UTC";
  31
  32 our ($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S,$opt_L, $opt_a);
  33 my (%conv_author_name, %conv_author_email);
  34
  35 sub usage() {
  36         print STDERR <<END;
  37 Usage: ${\basename $0}     # fetch/update GIT from CVS
  38        [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  39        [-p opts-for-cvsps] [-C GIT_repository] [-z fuzz] [-i] [-k] [-u]
  40        [-s subst] [-a] [-m] [-M regex] [-S regex] [CVS_module]
  41 END
  42         exit(1);
  43 }
  44
  45 sub read_author_info($) {
  46         my ($file) = @_;
  47         my $user;
  48         open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  49
  50         while (<$f>) {
  51                 # Expected format is this:
  52                 #   exon=Andreas Ericsson <ae@op5.se>
  53                 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  54                         $user = $1;
  55                         $conv_author_name{$user} = $2;
  56                         $conv_author_email{$user} = $3;
  57                 }
  58                 # However, we also read from CVSROOT/users format
  59                 # to ease migration.
  60                 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  61                         my $mapped;
  62                         ($user, $mapped) = ($1, $3);
  63                         if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  64                                 $conv_author_name{$user} = $1;
  65                                 $conv_author_email{$user} = $2;
  66                         }
  67                         elsif ($mapped =~ /^<?(.*)>?$/) {
  68                                 $conv_author_name{$user} = $user;
  69                                 $conv_author_email{$user} = $1;
  70                         }
  71                 }
  72                 # NEEDSWORK: Maybe warn on unrecognized lines?
  73         }
  74         close ($f);
  75 }
  76
  77 sub write_author_info($) {
  78         my ($file) = @_;
  79         open my $f, '>', $file or
  80           die("Failed to open $file for writing: $!");
  81
  82         foreach (keys %conv_author_name) {
  83                 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  84         }
  85         close ($f);
  86 }
  87
  88 getopts("hivmkuo:d:p:C:z:s:M:P:A:S:L:") or usage();
  89 usage if $opt_h;
  90
  91 @ARGV <= 1 or usage();
  92
  93 if ($opt_d) {
  94         $ENV{"CVSROOT"} = $opt_d;
  95 } elsif (-f 'CVS/Root') {
  96         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
  97         $opt_d = <$f>;
  98         chomp $opt_d;
  99         close $f;
 100         $ENV{"CVSROOT"} = $opt_d;
 101 } elsif ($ENV{"CVSROOT"}) {
 102         $opt_d = $ENV{"CVSROOT"};
 103 } else {
 104         die "CVSROOT needs to be set";
 105 }
 106 $opt_o ||= "origin";
 107 $opt_s ||= "-";
 108 $opt_a ||= 0;
 109
 110 my $git_tree = $opt_C;
 111 $git_tree ||= ".";
 112
 113 my $cvs_tree;
 114 if ($#ARGV == 0) {
 115         $cvs_tree = $ARGV[0];
 116 } elsif (-f 'CVS/Repository') {
 117         open my $f, '<', 'CVS/Repository' or
 118             die 'Failed to open CVS/Repository';
 119         $cvs_tree = <$f>;
 120         chomp $cvs_tree;
 121         close $f;
 122 } else {
 123         usage();
 124 }
 125
 126 our @mergerx = ();
 127 if ($opt_m) {
 128         @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
 129 }
 130 if ($opt_M) {
 131         push (@mergerx, qr/$opt_M/);
 132 }
 133
 134 # Remember UTC of our starting time
 135 # we'll want to avoid importing commits
 136 # that are too recent
 137 our $starttime = time();
 138
 139 select(STDERR); $|=1; select(STDOUT);
 140
 141
 142 package CVSconn;
 143 # Basic CVS dialog.
 144 # We're only interested in connecting and downloading, so ...
 145
 146 use File::Spec;
 147 use File::Temp qw(tempfile);
 148 use POSIX qw(strftime dup2);
 149
 150 sub new {
 151         my ($what,$repo,$subdir) = @_;
 152         $what=ref($what) if ref($what);
 153
 154         my $self = {};
 155         $self->{'buffer'} = "";
 156         bless($self,$what);
 157
 158         $repo =~ s#/+$##;
 159         $self->{'fullrep'} = $repo;
 160         $self->conn();
 161
 162         $self->{'subdir'} = $subdir;
 163         $self->{'lines'} = undef;
 164
 165         return $self;
 166 }
 167
 168 sub conn {
 169         my $self = shift;
 170         my $repo = $self->{'fullrep'};
 171         if ($repo =~ s/^:pserver(?:([^:]*)):(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 172                 my ($param,$user,$pass,$serv,$port) = ($1,$2,$3,$4,$5);
 173
 174                 my ($proxyhost,$proxyport);
 175                 if ($param && ($param =~ m/proxy=([^;]+)/)) {
 176                         $proxyhost = $1;
 177                         # Default proxyport, if not specified, is 8080.
 178                         $proxyport = 8080;
 179                         if ($ENV{"CVS_PROXY_PORT"}) {
 180                                 $proxyport = $ENV{"CVS_PROXY_PORT"};
 181                         }
 182                         if ($param =~ m/proxyport=([^;]+)/) {
 183                                 $proxyport = $1;
 184                         }
 185                 }
 186
 187                 $user="anonymous" unless defined $user;
 188                 my $rr2 = "-";
 189                 unless ($port) {
 190                         $rr2 = ":pserver:$user\@$serv:$repo";
 191                         $port=2401;
 192                 }
 193                 my $rr = ":pserver:$user\@$serv:$port$repo";
 194
 195                 unless ($pass) {
 196                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 197                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 198                                 while (<H>) {
 199                                         chomp;
 200                                         s/^\/\d+\s+//;
 201                                         my ($w,$p) = split(/\s/,$_,2);
 202                                         if ($w eq $rr or $w eq $rr2) {
 203                                                 $pass = $p;
 204                                                 last;
 205                                         }
 206                                 }
 207                         };
 208                 }
 209                 $pass="A" unless $pass;
 210
 211                 my ($s, $rep);
 212                 if ($proxyhost) {
 213
 214                         # Use a HTTP Proxy. Only works for HTTP proxies that
 215                         # don't require user authentication
 216                         #
 217                         # See: http://www.ietf.org/rfc/rfc2817.txt
 218
 219                         $s = IO::Socket::INET->new(PeerHost => $proxyhost, PeerPort => $proxyport);
 220                         die "Socket to $proxyhost: $!\n" unless defined $s;
 221                         $s->write("CONNECT $serv:$port HTTP/1.1\r\nHost: $serv:$port\r\n\r\n")
 222                                 or die "Write to $proxyhost: $!\n";
 223                         $s->flush();
 224
 225                         $rep = <$s>;
 226
 227                         # The answer should look like 'HTTP/1.x 2yy ....'
 228                         if (!($rep =~ m#^HTTP/1\.. 2[0-9][0-9]#)) {
 229                                 die "Proxy connect: $rep\n";
 230                         }
 231                         # Skip up to the empty line of the proxy server output
 232                         # including the response headers.
 233                         while ($rep = <$s>) {
 234                                 last if (!defined $rep ||
 235                                          $rep eq "\n" ||
 236                                          $rep eq "\r\n");
 237                         }
 238                 } else {
 239                         $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 240                         die "Socket to $serv: $!\n" unless defined $s;
 241                 }
 242
 243                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 244                         or die "Write to $serv: $!\n";
 245                 $s->flush();
 246
 247                 $rep = <$s>;
 248
 249                 if ($rep ne "I LOVE YOU\n") {
 250                         $rep="<unknown>" unless $rep;
 251                         die "AuthReply: $rep\n";
 252                 }
 253                 $self->{'socketo'} = $s;
 254                 $self->{'socketi'} = $s;
 255         } else { # local or ext: Fork off our own cvs server.
 256                 my $pr = IO::Pipe->new();
 257                 my $pw = IO::Pipe->new();
 258                 my $pid = fork();
 259                 die "Fork: $!\n" unless defined $pid;
 260                 my $cvs = 'cvs';
 261                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 262                 my $rsh = 'rsh';
 263                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 264
 265                 my @cvs = ($cvs, 'server');
 266                 my ($local, $user, $host);
 267                 $local = $repo =~ s/:local://;
 268                 if (!$local) {
 269                     $repo =~ s/:ext://;
 270                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 271                     ($user, $host) = ($1, $2);
 272                 }
 273                 if (!$local) {
 274                     if ($user) {
 275                         unshift @cvs, $rsh, '-l', $user, $host;
 276                     } else {
 277                         unshift @cvs, $rsh, $host;
 278                     }
 279                 }
 280
 281                 unless ($pid) {
 282                         $pr->writer();
 283                         $pw->reader();
 284                         dup2($pw->fileno(),0);
 285                         dup2($pr->fileno(),1);
 286                         $pr->close();
 287                         $pw->close();
 288                         exec(@cvs);
 289                 }
 290                 $pw->writer();
 291                 $pr->reader();
 292                 $self->{'socketo'} = $pw;
 293                 $self->{'socketi'} = $pr;
 294         }
 295         $self->{'socketo'}->write("Root $repo\n");
 296
 297         # Trial and error says that this probably is the minimum set
 298         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 299
 300         $self->{'socketo'}->write("valid-requests\n");
 301         $self->{'socketo'}->flush();
 302
 303         chomp(my $rep=$self->readline());
 304         if ($rep !~ s/^Valid-requests\s*//) {
 305                 $rep="<unknown>" unless $rep;
 306                 die "Expected Valid-requests from server, but got: $rep\n";
 307         }
 308         chomp(my $res=$self->readline());
 309         die "validReply: $res\n" if $res ne "ok";
 310
 311         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 312         $self->{'repo'} = $repo;
 313 }
 314
 315 sub readline {
 316         my ($self) = @_;
 317         return $self->{'socketi'}->getline();
 318 }
 319
 320 sub _file {
 321         # Request a file with a given revision.
 322         # Trial and error says this is a good way to do it. :-/
 323         my ($self,$fn,$rev) = @_;
 324         $self->{'socketo'}->write("Argument -N\n") or return undef;
 325         $self->{'socketo'}->write("Argument -P\n") or return undef;
 326         # -kk: Linus' version doesn't use it - defaults to off
 327         if ($opt_k) {
 328             $self->{'socketo'}->write("Argument -kk\n") or return undef;
 329         }
 330         $self->{'socketo'}->write("Argument -r\n") or return undef;
 331         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 332         $self->{'socketo'}->write("Argument --\n") or return undef;
 333         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 334         $self->{'socketo'}->write("Directory .\n") or return undef;
 335         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 336         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 337         $self->{'socketo'}->write("co\n") or return undef;
 338         $self->{'socketo'}->flush() or return undef;
 339         $self->{'lines'} = 0;
 340         return 1;
 341 }
 342 sub _line {
 343         # Read a line from the server.
 344         # ... except that 'line' may be an entire file. ;-)
 345         my ($self, $fh) = @_;
 346         die "Not in lines" unless defined $self->{'lines'};
 347
 348         my $line;
 349         my $res=0;
 350         while (defined($line = $self->readline())) {
 351                 # M U gnupg-cvs-rep/AUTHORS
 352                 # Updated gnupg-cvs-rep/
 353                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 354                 # /AUTHORS/1.1///T1.1
 355                 # u=rw,g=rw,o=rw
 356                 # 0
 357                 # ok
 358
 359                 if ($line =~ s/^(?:Created|Updated) //) {
 360                         $line = $self->readline(); # path
 361                         $line = $self->readline(); # Entries line
 362                         my $mode = $self->readline(); chomp $mode;
 363                         $self->{'mode'} = $mode;
 364                         defined (my $cnt = $self->readline())
 365                                 or die "EOF from server after 'Changed'\n";
 366                         chomp $cnt;
 367                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 368                         $line="";
 369                         $res = $self->_fetchfile($fh, $cnt);
 370                 } elsif ($line =~ s/^ //) {
 371                         print $fh $line;
 372                         $res += length($line);
 373                 } elsif ($line =~ /^M\b/) {
 374                         # output, do nothing
 375                 } elsif ($line =~ /^Mbinary\b/) {
 376                         my $cnt;
 377                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 378                         chomp $cnt;
 379                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 380                         $line="";
 381                         $res += $self->_fetchfile($fh, $cnt);
 382                 } else {
 383                         chomp $line;
 384                         if ($line eq "ok") {
 385                                 # print STDERR "S: ok (".length($res).")\n";
 386                                 return $res;
 387                         } elsif ($line =~ s/^E //) {
 388                                 # print STDERR "S: $line\n";
 389                         } elsif ($line =~ /^(Remove-entry|Removed) /i) {
 390                                 $line = $self->readline(); # filename
 391                                 $line = $self->readline(); # OK
 392                                 chomp $line;
 393                                 die "Unknown: $line" if $line ne "ok";
 394                                 return -1;
 395                         } else {
 396                                 die "Unknown: $line\n";
 397                         }
 398                 }
 399         }
 400         return undef;
 401 }
 402 sub file {
 403         my ($self,$fn,$rev) = @_;
 404         my $res;
 405
 406         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 407                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 408
 409         $self->_file($fn,$rev) and $res = $self->_line($fh);
 410
 411         if (!defined $res) {
 412             print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
 413             truncate $fh, 0;
 414             $self->conn();
 415             $self->_file($fn,$rev) or die "No file command send";
 416             $res = $self->_line($fh);
 417             die "Retry failed" unless defined $res;
 418         }
 419         close ($fh);
 420
 421         return ($name, $res);
 422 }
 423 sub _fetchfile {
 424         my ($self, $fh, $cnt) = @_;
 425         my $res = 0;
 426         my $bufsize = 1024 * 1024;
 427         while ($cnt) {
 428             if ($bufsize > $cnt) {
 429                 $bufsize = $cnt;
 430             }
 431             my $buf;
 432             my $num = $self->{'socketi'}->read($buf,$bufsize);
 433             die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 434             print $fh $buf;
 435             $res += $num;
 436             $cnt -= $num;
 437         }
 438         return $res;
 439 }
 440
 441
 442 package main;
 443
 444 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 445
 446
 447 sub pdate($) {
 448         my ($d) = @_;
 449         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 450                 or die "Unparseable date: $d\n";
 451         my $y=$1; $y-=1900 if $y>1900;
 452         return timegm($6||0,$5,$4,$3,$2-1,$y);
 453 }
 454
 455 sub pmode($) {
 456         my ($mode) = @_;
 457         my $m = 0;
 458         my $mm = 0;
 459         my $um = 0;
 460         for my $x(split(//,$mode)) {
 461                 if ($x eq ",") {
 462                         $m |= $mm&$um;
 463                         $mm = 0;
 464                         $um = 0;
 465                 } elsif ($x eq "u") { $um |= 0700;
 466                 } elsif ($x eq "g") { $um |= 0070;
 467                 } elsif ($x eq "o") { $um |= 0007;
 468                 } elsif ($x eq "r") { $mm |= 0444;
 469                 } elsif ($x eq "w") { $mm |= 0222;
 470                 } elsif ($x eq "x") { $mm |= 0111;
 471                 } elsif ($x eq "=") { # do nothing
 472                 } else { die "Unknown mode: $mode\n";
 473                 }
 474         }
 475         $m |= $mm&$um;
 476         return $m;
 477 }
 478
 479 sub getwd() {
 480         my $pwd = `pwd`;
 481         chomp $pwd;
 482         return $pwd;
 483 }
 484
 485 sub is_sha1 {
 486         my $s = shift;
 487         return $s =~ /^[a-f0-9]{40}$/;
 488 }
 489
 490 sub get_headref ($$) {
 491     my $name    = shift;
 492     my $git_dir = shift;
 493
 494     my $f = "$git_dir/refs/heads/$name";
 495     if (open(my $fh, $f)) {
 496             chomp(my $r = <$fh>);
 497             is_sha1($r) or die "Cannot get head id for $name ($r): $!";
 498             return $r;
 499     }
 500     die "unable to open $f: $!" unless $! == POSIX::ENOENT;
 501     return undef;
 502 }
 503
 504 -d $git_tree
 505         or mkdir($git_tree,0777)
 506         or die "Could not create $git_tree: $!";
 507 chdir($git_tree);
 508
 509 my $last_branch = "";
 510 my $orig_branch = "";
 511 my %branch_date;
 512 my $tip_at_start = undef;
 513
 514 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 515 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 516 $ENV{"GIT_DIR"} = $git_dir;
 517 my $orig_git_index;
 518 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 519
 520 my %index; # holds filenames of one index per branch
 521
 522 unless (-d $git_dir) {
 523         system("git-init");
 524         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 525         system("git-read-tree");
 526         die "Cannot init an empty tree: $?\n" if $?;
 527
 528         $last_branch = $opt_o;
 529         $orig_branch = "";
 530 } else {
 531         -f "$git_dir/refs/heads/$opt_o"
 532                 or die "Branch '$opt_o' does not exist.\n".
 533                        "Either use the correct '-o branch' option,\n".
 534                        "or import to a new repository.\n";
 535
 536         open(F, "git-symbolic-ref HEAD |") or
 537                 die "Cannot run git-symbolic-ref: $!\n";
 538         chomp ($last_branch = <F>);
 539         $last_branch = basename($last_branch);
 540         close(F);
 541         unless ($last_branch) {
 542                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 543                 $last_branch = "master";
 544         }
 545         $orig_branch = $last_branch;
 546         $tip_at_start = `git-rev-parse --verify HEAD`;
 547
 548         # Get the last import timestamps
 549         my $fmt = '($ref, $author) = (%(refname), %(author));';
 550         open(H, "git-for-each-ref --perl --format='$fmt' refs/heads |") or
 551                 die "Cannot run git-for-each-ref: $!\n";
 552         while (defined(my $entry = <H>)) {
 553                 my ($ref, $author);
 554                 eval($entry) || die "cannot eval refs list: $@";
 555                 my ($head) = ($ref =~ m|^refs/heads/(.*)|);
 556                 $author =~ /^.*\s(\d+)\s[-+]\d{4}$/;
 557                 $branch_date{$head} = $1;
 558         }
 559         close(H);
 560 }
 561
 562 -d $git_dir
 563         or die "Could not create git subdir ($git_dir).\n";
 564
 565 # now we read (and possibly save) author-info as well
 566 -f "$git_dir/cvs-authors" and
 567   read_author_info("$git_dir/cvs-authors");
 568 if ($opt_A) {
 569         read_author_info($opt_A);
 570         write_author_info("$git_dir/cvs-authors");
 571 }
 572
 573
 574 #
 575 # run cvsps into a file unless we are getting
 576 # it passed as a file via $opt_P
 577 #
 578 my $cvspsfile;
 579 unless ($opt_P) {
 580         print "Running cvsps...\n" if $opt_v;
 581         my $pid = open(CVSPS,"-|");
 582         my $cvspsfh;
 583         die "Cannot fork: $!\n" unless defined $pid;
 584         unless ($pid) {
 585                 my @opt;
 586                 @opt = split(/,/,$opt_p) if defined $opt_p;
 587                 unshift @opt, '-z', $opt_z if defined $opt_z;
 588                 unshift @opt, '-q'         unless defined $opt_v;
 589                 unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 590                         push @opt, '--cvs-direct';
 591                 }
 592                 exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 593                 die "Could not start cvsps: $!\n";
 594         }
 595         ($cvspsfh, $cvspsfile) = tempfile('gitXXXXXX', SUFFIX => '.cvsps',
 596                                           DIR => File::Spec->tmpdir());
 597         while (<CVSPS>) {
 598             print $cvspsfh $_;
 599         }
 600         close CVSPS;
 601         close $cvspsfh;
 602 } else {
 603         $cvspsfile = $opt_P;
 604 }
 605
 606 open(CVS, "<$cvspsfile") or die $!;
 607
 608 ## cvsps output:
 609 #---------------------
 610 #PatchSet 314
 611 #Date: 1999/09/18 13:03:59
 612 #Author: wkoch
 613 #Branch: STABLE-BRANCH-1-0
 614 #Ancestor branch: HEAD
 615 #Tag: (none)
 616 #Log:
 617 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 618 #Members:
 619 #       README:1.57->1.57.2.1
 620 #       VERSION:1.96->1.96.2.1
 621 #
 622 #---------------------
 623
 624 my $state = 0;
 625
 626 sub update_index (\@\@) {
 627         my $old = shift;
 628         my $new = shift;
 629         open(my $fh, '|-', qw(git-update-index -z --index-info))
 630                 or die "unable to open git-update-index: $!";
 631         print $fh
 632                 (map { "0 0000000000000000000000000000000000000000\t$_\0" }
 633                         @$old),
 634                 (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
 635                         @$new)
 636                 or die "unable to write to git-update-index: $!";
 637         close $fh
 638                 or die "unable to write to git-update-index: $!";
 639         $? and die "git-update-index reported error: $?";
 640 }
 641
 642 sub write_tree () {
 643         open(my $fh, '-|', qw(git-write-tree))
 644                 or die "unable to open git-write-tree: $!";
 645         chomp(my $tree = <$fh>);
 646         is_sha1($tree)
 647                 or die "Cannot get tree id ($tree): $!";
 648         close($fh)
 649                 or die "Error running git-write-tree: $?\n";
 650         print "Tree ID $tree\n" if $opt_v;
 651         return $tree;
 652 }
 653
 654 my ($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 655 my (@old,@new,@skipped,%ignorebranch);
 656
 657 # commits that cvsps cannot place anywhere...
 658 $ignorebranch{'#CVSPS_NO_BRANCH'} = 1;
 659
 660 sub commit {
 661         if ($branch eq $opt_o && !$index{branch} && !get_headref($branch, $git_dir)) {
 662             # looks like an initial commit
 663             # use the index primed by git-init
 664             $ENV{GIT_INDEX_FILE} = '.git/index';
 665             $index{$branch} = '.git/index';
 666         } else {
 667             # use an index per branch to speed up
 668             # imports of projects with many branches
 669             unless ($index{$branch}) {
 670                 $index{$branch} = tmpnam();
 671                 $ENV{GIT_INDEX_FILE} = $index{$branch};
 672                 if ($ancestor) {
 673                     system("git-read-tree", $ancestor);
 674                 } else {
 675                     system("git-read-tree", $branch);
 676                 }
 677                 die "read-tree failed: $?\n" if $?;
 678             }
 679         }
 680         $ENV{GIT_INDEX_FILE} = $index{$branch};
 681
 682         update_index(@old, @new);
 683         @old = @new = ();
 684         my $tree = write_tree();
 685         my $parent = get_headref($last_branch, $git_dir);
 686         print "Parent ID " . ($parent ? $parent : "(empty)") . "\n" if $opt_v;
 687
 688         my @commit_args;
 689         push @commit_args, ("-p", $parent) if $parent;
 690
 691         # loose detection of merges
 692         # based on the commit msg
 693         foreach my $rx (@mergerx) {
 694                 next unless $logmsg =~ $rx && $1;
 695                 my $mparent = $1 eq 'HEAD' ? $opt_o : $1;
 696                 if (my $sha1 = get_headref($mparent, $git_dir)) {
 697                         push @commit_args, '-p', $mparent;
 698                         print "Merge parent branch: $mparent\n" if $opt_v;
 699                 }
 700         }
 701
 702         my $commit_date = strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date));
 703         $ENV{GIT_AUTHOR_NAME} = $author_name;
 704         $ENV{GIT_AUTHOR_EMAIL} = $author_email;
 705         $ENV{GIT_AUTHOR_DATE} = $commit_date;
 706         $ENV{GIT_COMMITTER_NAME} = $author_name;
 707         $ENV{GIT_COMMITTER_EMAIL} = $author_email;
 708         $ENV{GIT_COMMITTER_DATE} = $commit_date;
 709         my $pid = open2(my $commit_read, my $commit_write,
 710                 'git-commit-tree', $tree, @commit_args);
 711
 712         # compatibility with git2cvs
 713         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 714         $logmsg =~ s/[\s\n]+\z//;
 715
 716         if (@skipped) {
 717             $logmsg .= "\n\n\nSKIPPED:\n\t";
 718             $logmsg .= join("\n\t", @skipped) . "\n";
 719             @skipped = ();
 720         }
 721
 722         print($commit_write "$logmsg\n") && close($commit_write)
 723                 or die "Error writing to git-commit-tree: $!\n";
 724
 725         print "Committed patch $patchset ($branch $commit_date)\n" if $opt_v;
 726         chomp(my $cid = <$commit_read>);
 727         is_sha1($cid) or die "Cannot get commit id ($cid): $!\n";
 728         print "Commit ID $cid\n" if $opt_v;
 729         close($commit_read);
 730
 731         waitpid($pid,0);
 732         die "Error running git-commit-tree: $?\n" if $?;
 733
 734         system("git-update-ref refs/heads/$branch $cid") == 0
 735                 or die "Cannot write branch $branch for update: $!\n";
 736
 737         if ($tag) {
 738                 my ($in, $out) = ('','');
 739                 my ($xtag) = $tag;
 740                 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 741                 $xtag =~ tr/_/\./ if ( $opt_u );
 742                 $xtag =~ s/[\/]/$opt_s/g;
 743
 744                 my $pid = open2($in, $out, 'git-mktag');
 745                 print $out "object $cid\n".
 746                     "type commit\n".
 747                     "tag $xtag\n".
 748                     "tagger $author_name <$author_email>\n"
 749                     or die "Cannot create tag object $xtag: $!\n";
 750                 close($out)
 751                     or die "Cannot create tag object $xtag: $!\n";
 752
 753                 my $tagobj = <$in>;
 754                 chomp $tagobj;
 755
 756                 if ( !close($in) or waitpid($pid, 0) != $pid or
 757                      $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 758                     die "Cannot create tag object $xtag: $!\n";
 759                 }
 760
 761
 762                 open(C,">$git_dir/refs/tags/$xtag")
 763                         or die "Cannot create tag $xtag: $!\n";
 764                 print C "$tagobj\n"
 765                         or die "Cannot write tag $xtag: $!\n";
 766                 close(C)
 767                         or die "Cannot write tag $xtag: $!\n";
 768
 769                 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 770         }
 771 };
 772
 773 my $commitcount = 1;
 774 while (<CVS>) {
 775         chomp;
 776         if ($state == 0 and /^-+$/) {
 777                 $state = 1;
 778         } elsif ($state == 0) {
 779                 $state = 1;
 780                 redo;
 781         } elsif (($state==0 or $state==1) and s/^PatchSet\s+//) {
 782                 $patchset = 0+$_;
 783                 $state=2;
 784         } elsif ($state == 2 and s/^Date:\s+//) {
 785                 $date = pdate($_);
 786                 unless ($date) {
 787                         print STDERR "Could not parse date: $_\n";
 788                         $state=0;
 789                         next;
 790                 }
 791                 $state=3;
 792         } elsif ($state == 3 and s/^Author:\s+//) {
 793                 s/\s+$//;
 794                 if (/^(.*?)\s+<(.*)>/) {
 795                     ($author_name, $author_email) = ($1, $2);
 796                 } elsif ($conv_author_name{$_}) {
 797                         $author_name = $conv_author_name{$_};
 798                         $author_email = $conv_author_email{$_};
 799                 } else {
 800                     $author_name = $author_email = $_;
 801                 }
 802                 $state = 4;
 803         } elsif ($state == 4 and s/^Branch:\s+//) {
 804                 s/\s+$//;
 805                 s/[\/]/$opt_s/g;
 806                 $branch = $_;
 807                 $state = 5;
 808         } elsif ($state == 5 and s/^Ancestor branch:\s+//) {
 809                 s/\s+$//;
 810                 $ancestor = $_;
 811                 $ancestor = $opt_o if $ancestor eq "HEAD";
 812                 $state = 6;
 813         } elsif ($state == 5) {
 814                 $ancestor = undef;
 815                 $state = 6;
 816                 redo;
 817         } elsif ($state == 6 and s/^Tag:\s+//) {
 818                 s/\s+$//;
 819                 if ($_ eq "(none)") {
 820                         $tag = undef;
 821                 } else {
 822                         $tag = $_;
 823                 }
 824                 $state = 7;
 825         } elsif ($state == 7 and /^Log:/) {
 826                 $logmsg = "";
 827                 $state = 8;
 828         } elsif ($state == 8 and /^Members:/) {
 829                 $branch = $opt_o if $branch eq "HEAD";
 830                 if (defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 831                         # skip
 832                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 833                         $state = 11;
 834                         next;
 835                 }
 836                 if (!$opt_a && $starttime - 300 - (defined $opt_z ? $opt_z : 300) <= $date) {
 837                         # skip if the commit is too recent
 838                         # that the cvsps default fuzz is 300s, we give ourselves another
 839                         # 300s just in case -- this also prevents skipping commits
 840                         # due to server clock drift
 841                         print "skip patchset $patchset: $date too recent\n" if $opt_v;
 842                         $state = 11;
 843                         next;
 844                 }
 845                 if (exists $ignorebranch{$branch}) {
 846                         print STDERR "Skipping $branch\n";
 847                         $state = 11;
 848                         next;
 849                 }
 850                 if ($ancestor) {
 851                         if ($ancestor eq $branch) {
 852                                 print STDERR "Branch $branch erroneously stems from itself -- changed ancestor to $opt_o\n";
 853                                 $ancestor = $opt_o;
 854                         }
 855                         if (-f "$git_dir/refs/heads/$branch") {
 856                                 print STDERR "Branch $branch already exists!\n";
 857                                 $state=11;
 858                                 next;
 859                         }
 860                         unless (open(H,"$git_dir/refs/heads/$ancestor")) {
 861                                 print STDERR "Branch $ancestor does not exist!\n";
 862                                 $ignorebranch{$branch} = 1;
 863                                 $state=11;
 864                                 next;
 865                         }
 866                         chomp(my $id = <H>);
 867                         close(H);
 868                         unless (open(H,"> $git_dir/refs/heads/$branch")) {
 869                                 print STDERR "Could not create branch $branch: $!\n";
 870                                 $ignorebranch{$branch} = 1;
 871                                 $state=11;
 872                                 next;
 873                         }
 874                         print H "$id\n"
 875                                 or die "Could not write branch $branch: $!";
 876                         close(H)
 877                                 or die "Could not write branch $branch: $!";
 878                 }
 879                 $last_branch = $branch if $branch ne $last_branch;
 880                 $state = 9;
 881         } elsif ($state == 8) {
 882                 $logmsg .= "$_\n";
 883         } elsif ($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 884 #       VERSION:1.96->1.96.2.1
 885                 my $init = ($2 eq "INITIAL");
 886                 my $fn = $1;
 887                 my $rev = $3;
 888                 $fn =~ s#^/+##;
 889                 if ($opt_S && $fn =~ m/$opt_S/) {
 890                     print "SKIPPING $fn v $rev\n";
 891                     push(@skipped, $fn);
 892                     next;
 893                 }
 894                 print "Fetching $fn   v $rev\n" if $opt_v;
 895                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 896                 if ($size == -1) {
 897                         push(@old,$fn);
 898                         print "Drop $fn\n" if $opt_v;
 899                 } else {
 900                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 901                         my $pid = open(my $F, '-|');
 902                         die $! unless defined $pid;
 903                         if (!$pid) {
 904                             exec("git-hash-object", "-w", $tmpname)
 905                                 or die "Cannot create object: $!\n";
 906                         }
 907                         my $sha = <$F>;
 908                         chomp $sha;
 909                         close $F;
 910                         my $mode = pmode($cvs->{'mode'});
 911                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 912                 }
 913                 unlink($tmpname);
 914         } elsif ($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 915                 my $fn = $1;
 916                 $fn =~ s#^/+##;
 917                 push(@old,$fn);
 918                 print "Delete $fn\n" if $opt_v;
 919         } elsif ($state == 9 and /^\s*$/) {
 920                 $state = 10;
 921         } elsif (($state == 9 or $state == 10) and /^-+$/) {
 922                 $commitcount++;
 923                 if ($opt_L && $commitcount > $opt_L) {
 924                         last;
 925                 }
 926                 commit();
 927                 if (($commitcount & 1023) == 0) {
 928                         system("git repack -a -d");
 929                 }
 930                 $state = 1;
 931         } elsif ($state == 11 and /^-+$/) {
 932                 $state = 1;
 933         } elsif (/^-+$/) { # end of unknown-line processing
 934                 $state = 1;
 935         } elsif ($state != 11) { # ignore stuff when skipping
 936                 print "* UNKNOWN LINE * $_\n";
 937         }
 938 }
 939 commit() if $branch and $state != 11;
 940
 941 unless ($opt_P) {
 942         unlink($cvspsfile);
 943 }
 944
 945 # The heuristic of repacking every 1024 commits can leave a
 946 # lot of unpacked data.  If there is more than 1MB worth of
 947 # not-packed objects, repack once more.
 948 my $line = `git-count-objects`;
 949 if ($line =~ /^(\d+) objects, (\d+) kilobytes$/) {
 950   my ($n_objects, $kb) = ($1, $2);
 951   1024 < $kb
 952     and system("git repack -a -d");
 953 }
 954
 955 foreach my $git_index (values %index) {
 956     if ($git_index ne '.git/index') {
 957         unlink($git_index);
 958     }
 959 }
 960
 961 if (defined $orig_git_index) {
 962         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 963 } else {
 964         delete $ENV{GIT_INDEX_FILE};
 965 }
 966
 967 # Now switch back to the branch we were in before all of this happened
 968 if ($orig_branch) {
 969         print "DONE.\n" if $opt_v;
 970         if ($opt_i) {
 971                 exit 0;
 972         }
 973         my $tip_at_end = `git-rev-parse --verify HEAD`;
 974         if ($tip_at_start ne $tip_at_end) {
 975                 for ($tip_at_start, $tip_at_end) { chomp; }
 976                 print "Fetched into the current branch.\n" if $opt_v;
 977                 system(qw(git-read-tree -u -m),
 978                        $tip_at_start, $tip_at_end);
 979                 die "Fast-forward update failed: $?\n" if $?;
 980         }
 981         else {
 982                 system(qw(git-merge cvsimport HEAD), "refs/heads/$opt_o");
 983                 die "Could not merge $opt_o into the current branch.\n" if $?;
 984         }
 985 } else {
 986         $orig_branch = "master";
 987         print "DONE; creating $orig_branch branch\n" if $opt_v;
 988         system("git-update-ref", "refs/heads/master", "refs/heads/$opt_o")
 989                 unless -f "$git_dir/refs/heads/master";
 990         system('git-update-ref', 'HEAD', "$orig_branch");
 991         unless ($opt_i) {
 992                 system('git checkout');
 993                 die "checkout failed: $?\n" if $?;
 994         }
 995 }