git-cvsexportcommit.perl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Getopt::Std;
   5 use File::Temp qw(tempdir);
   6 use Data::Dumper;
   7 use File::Basename qw(basename dirname);
   8
   9 our ($opt_h, $opt_P, $opt_p, $opt_v, $opt_c, $opt_f, $opt_a, $opt_m, $opt_d, $opt_u, $opt_w);
  10
  11 getopts('uhPpvcfam:d:w:');
  12
  13 $opt_h && usage();
  14
  15 die "Need at least one commit identifier!" unless @ARGV;
  16
  17 if ($opt_w) {
  18         unless ($ENV{GIT_DIR}) {
  19                 # Remember where our GIT_DIR is before changing to CVS checkout
  20                 my $gd =`git-rev-parse --git-dir`;
  21                 chomp($gd);
  22                 if ($gd eq '.git') {
  23                         my $wd = `pwd`;
  24                         chomp($wd);
  25                         $gd = $wd."/.git"       ;
  26                 }
  27                 $ENV{GIT_DIR} = $gd;
  28         }
  29
  30         if (! -d $opt_w."/CVS" ) {
  31                 die "$opt_w is not a CVS checkout";
  32         }
  33         chdir $opt_w or die "Cannot change to CVS checkout at $opt_w";
  34 }
  35 unless ($ENV{GIT_DIR} && -r $ENV{GIT_DIR}){
  36     die "GIT_DIR is not defined or is unreadable";
  37 }
  38
  39
  40 my @cvs;
  41 if ($opt_d) {
  42         @cvs = ('cvs', '-d', $opt_d);
  43 } else {
  44         @cvs = ('cvs');
  45 }
  46
  47 # resolve target commit
  48 my $commit;
  49 $commit = pop @ARGV;
  50 $commit = safe_pipe_capture('git-rev-parse', '--verify', "$commit^0");
  51 chomp $commit;
  52 if ($?) {
  53     die "The commit reference $commit did not resolve!";
  54 }
  55
  56 # resolve what parent we want
  57 my $parent;
  58 if (@ARGV) {
  59     $parent = pop @ARGV;
  60     $parent =  safe_pipe_capture('git-rev-parse', '--verify', "$parent^0");
  61     chomp $parent;
  62     if ($?) {
  63         die "The parent reference did not resolve!";
  64     }
  65 }
  66
  67 # find parents from the commit itself
  68 my @commit  = safe_pipe_capture('git-cat-file', 'commit', $commit);
  69 my @parents;
  70 my $committer;
  71 my $author;
  72 my $stage = 'headers'; # headers, msg
  73 my $title;
  74 my $msg = '';
  75
  76 foreach my $line (@commit) {
  77     chomp $line;
  78     if ($stage eq 'headers' && $line eq '') {
  79         $stage = 'msg';
  80         next;
  81     }
  82
  83     if ($stage eq 'headers') {
  84         if ($line =~ m/^parent (\w{40})$/) { # found a parent
  85             push @parents, $1;
  86         } elsif ($line =~ m/^author (.+) \d+ [-+]\d+$/) {
  87             $author = $1;
  88         } elsif ($line =~ m/^committer (.+) \d+ [-+]\d+$/) {
  89             $committer = $1;
  90         }
  91     } else {
  92         $msg .= $line . "\n";
  93         unless ($title) {
  94             $title = $line;
  95         }
  96     }
  97 }
  98
  99 my $noparent = "0000000000000000000000000000000000000000";
 100 if ($parent) {
 101     my $found;
 102     # double check that it's a valid parent
 103     foreach my $p (@parents) {
 104         if ($p eq $parent) {
 105             $found = 1;
 106             last;
 107         }; # found it
 108     }
 109     die "Did not find $parent in the parents for this commit!" if !$found and !$opt_P;
 110 } else { # we don't have a parent from the cmdline...
 111     if (@parents == 1) { # it's safe to get it from the commit
 112         $parent = $parents[0];
 113     } elsif (@parents == 0) { # there is no parent
 114         $parent = $noparent;
 115     } else { # cannot choose automatically from multiple parents
 116         die "This commit has more than one parent -- please name the parent you want to use explicitly";
 117     }
 118 }
 119
 120 $opt_v && print "Applying to CVS commit $commit from parent $parent\n";
 121
 122 # grab the commit message
 123 open(MSG, ">.msg") or die "Cannot open .msg for writing";
 124 if ($opt_m) {
 125     print MSG $opt_m;
 126 }
 127 print MSG $msg;
 128 if ($opt_a) {
 129     print MSG "\n\nAuthor: $author\n";
 130     if ($author ne $committer) {
 131         print MSG "Committer: $committer\n";
 132     }
 133 }
 134 close MSG;
 135
 136 if ($parent eq $noparent) {
 137     `git-diff-tree --binary -p --root $commit >.cvsexportcommit.diff`;# || die "Cannot diff";
 138 } else {
 139     `git-diff-tree --binary -p $parent $commit >.cvsexportcommit.diff`;# || die "Cannot diff";
 140 }
 141
 142 ## apply non-binary changes
 143
 144 # In pedantic mode require all lines of context to match.  In normal
 145 # mode, be compatible with diff/patch: assume 3 lines of context and
 146 # require at least one line match, i.e. ignore at most 2 lines of
 147 # context, like diff/patch do by default.
 148 my $context = $opt_p ? '' : '-C1';
 149
 150 print "Checking if patch will apply\n";
 151
 152 my @stat;
 153 open APPLY, "GIT_DIR= git-apply $context --summary --numstat<.cvsexportcommit.diff|" || die "cannot patch";
 154 @stat=<APPLY>;
 155 close APPLY || die "Cannot patch";
 156 my (@bfiles,@files,@afiles,@dfiles);
 157 chomp @stat;
 158 foreach (@stat) {
 159         push (@bfiles,$1) if m/^-\t-\t(.*)$/;
 160         push (@files, $1) if m/^-\t-\t(.*)$/;
 161         push (@files, $1) if m/^\d+\t\d+\t(.*)$/;
 162         push (@afiles,$1) if m/^ create mode [0-7]+ (.*)$/;
 163         push (@dfiles,$1) if m/^ delete mode [0-7]+ (.*)$/;
 164 }
 165 map { s/^"(.*)"$/$1/g } @bfiles,@files;
 166 map { s/\\([0-7]{3})/sprintf('%c',oct $1)/eg } @bfiles,@files;
 167
 168 # check that the files are clean and up to date according to cvs
 169 my $dirty;
 170 my @dirs;
 171 foreach my $p (@afiles) {
 172     my $path = dirname $p;
 173     while (!-d $path and ! grep { $_ eq $path } @dirs) {
 174         unshift @dirs, $path;
 175         $path = dirname $path;
 176     }
 177 }
 178
 179 # ... check dirs,
 180 foreach my $d (@dirs) {
 181     if (-e $d) {
 182         $dirty = 1;
 183         warn "$d exists and is not a directory!\n";
 184     }
 185 }
 186
 187 # ... query status of all files that we have a directory for and parse output of 'cvs status' to %cvsstat.
 188 my @canstatusfiles;
 189 foreach my $f (@files) {
 190     my $path = dirname $f;
 191     next if (grep { $_ eq $path } @dirs);
 192     push @canstatusfiles, $f;
 193 }
 194
 195 my %cvsstat;
 196 if (@canstatusfiles) {
 197     if ($opt_u) {
 198       my @updated = xargs_safe_pipe_capture([@cvs, 'update'], @canstatusfiles);
 199       print @updated;
 200     }
 201     my @cvsoutput;
 202     @cvsoutput = xargs_safe_pipe_capture([@cvs, 'status'], @canstatusfiles);
 203     my $matchcount = 0;
 204     foreach my $l (@cvsoutput) {
 205         chomp $l;
 206         if ( $l =~ /^File:/ and  $l =~ /Status: (.*)$/ ) {
 207             $cvsstat{$canstatusfiles[$matchcount]} = $1;
 208             $matchcount++;
 209         }
 210     }
 211 }
 212
 213 # ... validate new files,
 214 foreach my $f (@afiles) {
 215     if (defined ($cvsstat{$f}) and $cvsstat{$f} ne "Unknown") {
 216         $dirty = 1;
 217         warn "File $f is already known in your CVS checkout -- perhaps it has been added by another user. Or this may indicate that it exists on a different branch. If this is the case, use -f to force the merge.\n";
 218         warn "Status was: $cvsstat{$f}\n";
 219     }
 220 }
 221 # ... validate known files.
 222 foreach my $f (@files) {
 223     next if grep { $_ eq $f } @afiles;
 224     # TODO:we need to handle removed in cvs
 225     unless (defined ($cvsstat{$f}) and $cvsstat{$f} eq "Up-to-date") {
 226         $dirty = 1;
 227         warn "File $f not up to date but has status '$cvsstat{$f}' in your CVS checkout!\n";
 228     }
 229 }
 230 if ($dirty) {
 231     if ($opt_f) {       warn "The tree is not clean -- forced merge\n";
 232         $dirty = 0;
 233     } else {
 234         die "Exiting: your CVS tree is not clean for this merge.";
 235     }
 236 }
 237
 238 print "Applying\n";
 239 `GIT_DIR= git-apply $context --summary --numstat --apply <.cvsexportcommit.diff` || die "cannot patch";
 240
 241 print "Patch applied successfully. Adding new files and directories to CVS\n";
 242 my $dirtypatch = 0;
 243
 244 #
 245 # We have to add the directories in order otherwise we will have
 246 # problems when we try and add the sub-directory of a directory we
 247 # have not added yet.
 248 #
 249 # Luckily this is easy to deal with by sorting the directories and
 250 # dealing with the shortest ones first.
 251 #
 252 @dirs = sort { length $a <=> length $b} @dirs;
 253
 254 foreach my $d (@dirs) {
 255     if (system(@cvs,'add',$d)) {
 256         $dirtypatch = 1;
 257         warn "Failed to cvs add directory $d -- you may need to do it manually";
 258     }
 259 }
 260
 261 foreach my $f (@afiles) {
 262     if (grep { $_ eq $f } @bfiles) {
 263       system(@cvs, 'add','-kb',$f);
 264     } else {
 265       system(@cvs, 'add', $f);
 266     }
 267     if ($?) {
 268         $dirtypatch = 1;
 269         warn "Failed to cvs add $f -- you may need to do it manually";
 270     }
 271 }
 272
 273 foreach my $f (@dfiles) {
 274     system(@cvs, 'rm', '-f', $f);
 275     if ($?) {
 276         $dirtypatch = 1;
 277         warn "Failed to cvs rm -f $f -- you may need to do it manually";
 278     }
 279 }
 280
 281 print "Commit to CVS\n";
 282 print "Patch title (first comment line): $title\n";
 283 my @commitfiles = map { unless (m/\s/) { '\''.$_.'\''; } else { $_; }; } (@files);
 284 my $cmd = join(' ', @cvs)." commit -F .msg @commitfiles";
 285
 286 if ($dirtypatch) {
 287     print "NOTE: One or more hunks failed to apply cleanly.\n";
 288     print "You'll need to apply the patch in .cvsexportcommit.diff manually\n";
 289     print "using a patch program. After applying the patch and resolving the\n";
 290     print "problems you may commit using:";
 291     print "\n    cd \"$opt_w\"" if $opt_w;
 292     print "\n    $cmd\n\n";
 293     exit(1);
 294 }
 295
 296 if ($opt_c) {
 297     print "Autocommit\n  $cmd\n";
 298     print xargs_safe_pipe_capture([@cvs, 'commit', '-F', '.msg'], @files);
 299     if ($?) {
 300         die "Exiting: The commit did not succeed";
 301     }
 302     print "Committed successfully to CVS\n";
 303     # clean up
 304     unlink(".msg");
 305 } else {
 306     print "Ready for you to commit, just run:\n\n   $cmd\n";
 307 }
 308
 309 # clean up
 310 unlink(".cvsexportcommit.diff");
 311
 312 # CVS version 1.11.x and 1.12.x sleeps the wrong way to ensure the timestamp
 313 # used by CVS and the one set by subsequence file modifications are different.
 314 # If they are not different CVS will not detect changes.
 315 sleep(1);
 316
 317 sub usage {
 318         print STDERR <<END;
 319 Usage: GIT_DIR=/path/to/.git ${\basename $0} [-h] [-p] [-v] [-c] [-f] [-u] [-w cvsworkdir] [-m msgprefix] [ parent ] commit
 320 END
 321         exit(1);
 322 }
 323
 324 # An alternative to `command` that allows input to be passed as an array
 325 # to work around shell problems with weird characters in arguments
 326 # if the exec returns non-zero we die
 327 sub safe_pipe_capture {
 328     my @output;
 329     if (my $pid = open my $child, '-|') {
 330         @output = (<$child>);
 331         close $child or die join(' ',@_).": $! $?";
 332     } else {
 333         exec(@_) or die "$! $?"; # exec() can fail the executable can't be found
 334     }
 335     return wantarray ? @output : join('',@output);
 336 }
 337
 338 sub xargs_safe_pipe_capture {
 339         my $MAX_ARG_LENGTH = 65536;
 340         my $cmd = shift;
 341         my @output;
 342         my $output;
 343         while(@_) {
 344                 my @args;
 345                 my $length = 0;
 346                 while(@_ && $length < $MAX_ARG_LENGTH) {
 347                         push @args, shift;
 348                         $length += length($args[$#args]);
 349                 }
 350                 if (wantarray) {
 351                         push @output, safe_pipe_capture(@$cmd, @args);
 352                 }
 353                 else {
 354                         $output .= safe_pipe_capture(@$cmd, @args);
 355                 }
 356         }
 357         return wantarray ? @output : $output;
 358 }