git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --annotate                     * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  60
  61   Sending:
  62     --envelope-sender       <str>  * Email envelope sender.
  63     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  64                                      is optional. Default 'localhost'.
  65     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  66     --smtp-server-port      <int>  * Outgoing SMTP server port.
  67     --smtp-user             <str>  * Username for SMTP-AUTH.
  68     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  69     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  70     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  71     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  72     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  73
  74   Automating:
  75     --identity              <str>  * Use the sendemail.<id> options.
  76     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  77     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  78     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  79     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  80     --[no-]suppress-from           * Send to self. Default off.
  81     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  82     --[no-]thread                  * Use In-Reply-To: field. Default on.
  83
  84   Administering:
  85     --confirm               <str>  * Confirm recipients before sending;
  86                                      auto, cc, compose, always, or never.
  87     --quiet                        * Output one line of info per email.
  88     --dry-run                      * Don't actually send the emails.
  89     --[no-]validate                * Perform patch sanity checks. Default on.
  90     --[no-]format-patch            * understand any non optional arguments as
  91                                      `git format-patch` ones.
  92     --force                        * Send even if safety checks would prevent it.
  93
  94 EOT
  95         exit(1);
  96 }
  97
  98 # most mail servers generate the Date: header, but not all...
  99 sub format_2822_time {
 100         my ($time) = @_;
 101         my @localtm = localtime($time);
 102         my @gmttm = gmtime($time);
 103         my $localmin = $localtm[1] + $localtm[2] * 60;
 104         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 105         if ($localtm[0] != $gmttm[0]) {
 106                 die "local zone differs from GMT by a non-minute interval\n";
 107         }
 108         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 109                 $localmin += 1440;
 110         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 111                 $localmin -= 1440;
 112         } elsif ($gmttm[6] != $localtm[6]) {
 113                 die "local time offset greater than or equal to 24 hours\n";
 114         }
 115         my $offset = $localmin - $gmtmin;
 116         my $offhour = $offset / 60;
 117         my $offmin = abs($offset % 60);
 118         if (abs($offhour) >= 24) {
 119                 die ("local time offset greater than or equal to 24 hours\n");
 120         }
 121
 122         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 123                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 124                        $localtm[3],
 125                        qw(Jan Feb Mar Apr May Jun
 126                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 127                        $localtm[5]+1900,
 128                        $localtm[2],
 129                        $localtm[1],
 130                        $localtm[0],
 131                        ($offset >= 0) ? '+' : '-',
 132                        abs($offhour),
 133                        $offmin,
 134                        );
 135 }
 136
 137 my $have_email_valid = eval { require Email::Valid; 1 };
 138 my $have_mail_address = eval { require Mail::Address; 1 };
 139 my $smtp;
 140 my $auth;
 141
 142 sub unique_email_list(@);
 143 sub cleanup_compose_files();
 144
 145 # Variables we fill in automatically, or via prompting:
 146 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 147         $initial_reply_to,$initial_subject,@files,
 148         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 149
 150 my $envelope_sender;
 151
 152 # Example reply to:
 153 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 154
 155 my $repo = eval { Git->repository() };
 156 my @repo = $repo ? ($repo) : ();
 157 my $term = eval {
 158         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 159                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 160                 : new Term::ReadLine 'git-send-email';
 161 };
 162 if ($@) {
 163         $term = new FakeTerm "$@: going non-interactive";
 164 }
 165
 166 # Behavior modification variables
 167 my ($quiet, $dry_run) = (0, 0);
 168 my $format_patch;
 169 my $compose_filename;
 170 my $force = 0;
 171
 172 # Handle interactive edition of files.
 173 my $multiedit;
 174 my $editor;
 175
 176 sub do_edit {
 177         if (!defined($editor)) {
 178                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 179         }
 180         if (defined($multiedit) && !$multiedit) {
 181                 map {
 182                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 183                         if (($? & 127) || ($? >> 8)) {
 184                                 die("the editor exited uncleanly, aborting everything");
 185                         }
 186                 } @_;
 187         } else {
 188                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 189                 if (($? & 127) || ($? >> 8)) {
 190                         die("the editor exited uncleanly, aborting everything");
 191                 }
 192         }
 193 }
 194
 195 # Variables with corresponding config settings
 196 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 197 my ($to_cmd, $cc_cmd);
 198 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 199 my ($smtp_authuser, $smtp_encryption);
 200 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 201 my ($validate, $confirm);
 202 my (@suppress_cc);
 203 my ($auto_8bit_encoding);
 204
 205 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 206
 207 my $not_set_by_user = "true but not set by the user";
 208
 209 my %config_bool_settings = (
 210     "thread" => [\$thread, 1],
 211     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 212     "suppressfrom" => [\$suppress_from, undef],
 213     "signedoffbycc" => [\$signed_off_by_cc, undef],
 214     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 215     "validate" => [\$validate, 1],
 216 );
 217
 218 my %config_settings = (
 219     "smtpserver" => \$smtp_server,
 220     "smtpserverport" => \$smtp_server_port,
 221     "smtpserveroption" => \@smtp_server_options,
 222     "smtpuser" => \$smtp_authuser,
 223     "smtppass" => \$smtp_authpass,
 224     "smtpdomain" => \$smtp_domain,
 225     "to" => \@initial_to,
 226     "tocmd" => \$to_cmd,
 227     "cc" => \@initial_cc,
 228     "cccmd" => \$cc_cmd,
 229     "aliasfiletype" => \$aliasfiletype,
 230     "bcc" => \@bcclist,
 231     "aliasesfile" => \@alias_files,
 232     "suppresscc" => \@suppress_cc,
 233     "envelopesender" => \$envelope_sender,
 234     "multiedit" => \$multiedit,
 235     "confirm"   => \$confirm,
 236     "from" => \$sender,
 237     "assume8bitencoding" => \$auto_8bit_encoding,
 238 );
 239
 240 # Help users prepare for 1.7.0
 241 sub chain_reply_to {
 242         if (defined $chain_reply_to &&
 243             $chain_reply_to eq $not_set_by_user) {
 244                 print STDERR
 245                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 246                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 247                     "you want to keep --chain-reply-to as your default.\n";
 248                 $chain_reply_to = 0;
 249         }
 250         return $chain_reply_to;
 251 }
 252
 253 # Handle Uncouth Termination
 254 sub signal_handler {
 255
 256         # Make text normal
 257         print color("reset"), "\n";
 258
 259         # SMTP password masked
 260         system "stty echo";
 261
 262         # tmp files from --compose
 263         if (defined $compose_filename) {
 264                 if (-e $compose_filename) {
 265                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 266                 }
 267                 if (-e ($compose_filename . ".final")) {
 268                         print "'$compose_filename.final' contains the composed email.\n"
 269                 }
 270         }
 271
 272         exit;
 273 };
 274
 275 $SIG{TERM} = \&signal_handler;
 276 $SIG{INT}  = \&signal_handler;
 277
 278 # Begin by accumulating all the variables (defined above), that we will end up
 279 # needing, first, from the command line:
 280
 281 my $rc = GetOptions("sender|from=s" => \$sender,
 282                     "in-reply-to=s" => \$initial_reply_to,
 283                     "subject=s" => \$initial_subject,
 284                     "to=s" => \@initial_to,
 285                     "to-cmd=s" => \$to_cmd,
 286                     "no-to" => \$no_to,
 287                     "cc=s" => \@initial_cc,
 288                     "no-cc" => \$no_cc,
 289                     "bcc=s" => \@bcclist,
 290                     "no-bcc" => \$no_bcc,
 291                     "chain-reply-to!" => \$chain_reply_to,
 292                     "smtp-server=s" => \$smtp_server,
 293                     "smtp-server-option=s" => \@smtp_server_options,
 294                     "smtp-server-port=s" => \$smtp_server_port,
 295                     "smtp-user=s" => \$smtp_authuser,
 296                     "smtp-pass:s" => \$smtp_authpass,
 297                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 298                     "smtp-encryption=s" => \$smtp_encryption,
 299                     "smtp-debug:i" => \$debug_net_smtp,
 300                     "smtp-domain:s" => \$smtp_domain,
 301                     "identity=s" => \$identity,
 302                     "annotate" => \$annotate,
 303                     "compose" => \$compose,
 304                     "quiet" => \$quiet,
 305                     "cc-cmd=s" => \$cc_cmd,
 306                     "suppress-from!" => \$suppress_from,
 307                     "suppress-cc=s" => \@suppress_cc,
 308                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 309                     "confirm=s" => \$confirm,
 310                     "dry-run" => \$dry_run,
 311                     "envelope-sender=s" => \$envelope_sender,
 312                     "thread!" => \$thread,
 313                     "validate!" => \$validate,
 314                     "format-patch!" => \$format_patch,
 315                     "8bit-encoding=s" => \$auto_8bit_encoding,
 316                     "force" => \$force,
 317          );
 318
 319 unless ($rc) {
 320     usage();
 321 }
 322
 323 die "Cannot run git format-patch from outside a repository\n"
 324         if $format_patch and not $repo;
 325
 326 # Now, let's fill any that aren't set in with defaults:
 327
 328 sub read_config {
 329         my ($prefix) = @_;
 330
 331         foreach my $setting (keys %config_bool_settings) {
 332                 my $target = $config_bool_settings{$setting}->[0];
 333                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 334         }
 335
 336         foreach my $setting (keys %config_settings) {
 337                 my $target = $config_settings{$setting};
 338                 next if $setting eq "to" and defined $no_to;
 339                 next if $setting eq "cc" and defined $no_cc;
 340                 next if $setting eq "bcc" and defined $no_bcc;
 341                 if (ref($target) eq "ARRAY") {
 342                         unless (@$target) {
 343                                 my @values = Git::config(@repo, "$prefix.$setting");
 344                                 @$target = @values if (@values && defined $values[0]);
 345                         }
 346                 }
 347                 else {
 348                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 349                 }
 350         }
 351
 352         if (!defined $smtp_encryption) {
 353                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 354                 if (defined $enc) {
 355                         $smtp_encryption = $enc;
 356                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 357                         $smtp_encryption = 'ssl';
 358                 }
 359         }
 360 }
 361
 362 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 363 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 364 read_config("sendemail.$identity") if (defined $identity);
 365 read_config("sendemail");
 366
 367 # fall back on builtin bool defaults
 368 foreach my $setting (values %config_bool_settings) {
 369         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 370 }
 371
 372 # 'default' encryption is none -- this only prevents a warning
 373 $smtp_encryption = '' unless (defined $smtp_encryption);
 374
 375 # Set CC suppressions
 376 my(%suppress_cc);
 377 if (@suppress_cc) {
 378         foreach my $entry (@suppress_cc) {
 379                 die "Unknown --suppress-cc field: '$entry'\n"
 380                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 381                 $suppress_cc{$entry} = 1;
 382         }
 383 }
 384
 385 if ($suppress_cc{'all'}) {
 386         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 387                 $suppress_cc{$entry} = 1;
 388         }
 389         delete $suppress_cc{'all'};
 390 }
 391
 392 # If explicit old-style ones are specified, they trump --suppress-cc.
 393 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 394 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 395
 396 if ($suppress_cc{'body'}) {
 397         foreach my $entry (qw (sob bodycc)) {
 398                 $suppress_cc{$entry} = 1;
 399         }
 400         delete $suppress_cc{'body'};
 401 }
 402
 403 # Set confirm's default value
 404 my $confirm_unconfigured = !defined $confirm;
 405 if ($confirm_unconfigured) {
 406         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 407 };
 408 die "Unknown --confirm setting: '$confirm'\n"
 409         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 410
 411 # Debugging, print out the suppressions.
 412 if (0) {
 413         print "suppressions:\n";
 414         foreach my $entry (keys %suppress_cc) {
 415                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 416         }
 417 }
 418
 419 my ($repoauthor, $repocommitter);
 420 ($repoauthor) = Git::ident_person(@repo, 'author');
 421 ($repocommitter) = Git::ident_person(@repo, 'committer');
 422
 423 # Verify the user input
 424
 425 foreach my $entry (@initial_to) {
 426         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 427 }
 428
 429 foreach my $entry (@initial_cc) {
 430         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 431 }
 432
 433 foreach my $entry (@bcclist) {
 434         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 435 }
 436
 437 sub parse_address_line {
 438         if ($have_mail_address) {
 439                 return map { $_->format } Mail::Address->parse($_[0]);
 440         } else {
 441                 return split_addrs($_[0]);
 442         }
 443 }
 444
 445 sub split_addrs {
 446         return quotewords('\s*,\s*', 1, @_);
 447 }
 448
 449 my %aliases;
 450 my %parse_alias = (
 451         # multiline formats can be supported in the future
 452         mutt => sub { my $fh = shift; while (<$fh>) {
 453                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 454                         my ($alias, $addr) = ($1, $2);
 455                         $addr =~ s/#.*$//; # mutt allows # comments
 456                          # commas delimit multiple addresses
 457                         $aliases{$alias} = [ split_addrs($addr) ];
 458                 }}},
 459         mailrc => sub { my $fh = shift; while (<$fh>) {
 460                 if (/^alias\s+(\S+)\s+(.*)$/) {
 461                         # spaces delimit multiple addresses
 462                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 463                 }}},
 464         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 465                 for (my $x = ''; defined($x); $x = $_) {
 466                         chomp $x;
 467                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 468                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 469                         $aliases{$1} = [ split_addrs($2) ];
 470                 }},
 471         elm => sub  { my $fh = shift;
 472                       while (<$fh>) {
 473                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 474                               my ($alias, $addr) = ($1, $2);
 475                                $aliases{$alias} = [ split_addrs($addr) ];
 476                           }
 477                       } },
 478
 479         gnus => sub { my $fh = shift; while (<$fh>) {
 480                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 481                         $aliases{$1} = [ $2 ];
 482                 }}}
 483 );
 484
 485 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 486         foreach my $file (@alias_files) {
 487                 open my $fh, '<', $file or die "opening $file: $!\n";
 488                 $parse_alias{$aliasfiletype}->($fh);
 489                 close $fh;
 490         }
 491 }
 492
 493 ($sender) = expand_aliases($sender) if defined $sender;
 494
 495 # returns 1 if the conflict must be solved using it as a format-patch argument
 496 sub check_file_rev_conflict($) {
 497         return unless $repo;
 498         my $f = shift;
 499         try {
 500                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 501                 if (defined($format_patch)) {
 502                         return $format_patch;
 503                 }
 504                 die(<<EOF);
 505 File '$f' exists but it could also be the range of commits
 506 to produce patches for.  Please disambiguate by...
 507
 508     * Saying "./$f" if you mean a file; or
 509     * Giving --format-patch option if you mean a range.
 510 EOF
 511         } catch Git::Error::Command with {
 512                 return 0;
 513         }
 514 }
 515
 516 # Now that all the defaults are set, process the rest of the command line
 517 # arguments and collect up the files that need to be processed.
 518 my @rev_list_opts;
 519 while (defined(my $f = shift @ARGV)) {
 520         if ($f eq "--") {
 521                 push @rev_list_opts, "--", @ARGV;
 522                 @ARGV = ();
 523         } elsif (-d $f and !check_file_rev_conflict($f)) {
 524                 opendir(DH,$f)
 525                         or die "Failed to opendir $f: $!";
 526
 527                 push @files, grep { -f $_ } map { catfile($f, $_) }
 528                                 sort readdir(DH);
 529                 closedir(DH);
 530         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 531                 push @files, $f;
 532         } else {
 533                 push @rev_list_opts, $f;
 534         }
 535 }
 536
 537 if (@rev_list_opts) {
 538         die "Cannot run git format-patch from outside a repository\n"
 539                 unless $repo;
 540         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 541 }
 542
 543 if ($validate) {
 544         foreach my $f (@files) {
 545                 unless (-p $f) {
 546                         my $error = validate_patch($f);
 547                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 548                 }
 549         }
 550 }
 551
 552 if (@files) {
 553         unless ($quiet) {
 554                 print $_,"\n" for (@files);
 555         }
 556 } else {
 557         print STDERR "\nNo patch files specified!\n\n";
 558         usage();
 559 }
 560
 561 sub get_patch_subject($) {
 562         my $fn = shift;
 563         open (my $fh, '<', $fn);
 564         while (my $line = <$fh>) {
 565                 next unless ($line =~ /^Subject: (.*)$/);
 566                 close $fh;
 567                 return "GIT: $1\n";
 568         }
 569         close $fh;
 570         die "No subject line in $fn ?";
 571 }
 572
 573 if ($compose) {
 574         # Note that this does not need to be secure, but we will make a small
 575         # effort to have it be unique
 576         $compose_filename = ($repo ?
 577                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 578                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 579         open(C,">",$compose_filename)
 580                 or die "Failed to open for writing $compose_filename: $!";
 581
 582
 583         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 584         my $tpl_subject = $initial_subject || '';
 585         my $tpl_reply_to = $initial_reply_to || '';
 586
 587         print C <<EOT;
 588 From $tpl_sender # This line is ignored.
 589 GIT: Lines beginning in "GIT:" will be removed.
 590 GIT: Consider including an overall diffstat or table of contents
 591 GIT: for the patch you are writing.
 592 GIT:
 593 GIT: Clear the body content if you don't wish to send a summary.
 594 From: $tpl_sender
 595 Subject: $tpl_subject
 596 In-Reply-To: $tpl_reply_to
 597
 598 EOT
 599         for my $f (@files) {
 600                 print C get_patch_subject($f);
 601         }
 602         close(C);
 603
 604         if ($annotate) {
 605                 do_edit($compose_filename, @files);
 606         } else {
 607                 do_edit($compose_filename);
 608         }
 609
 610         open(C2,">",$compose_filename . ".final")
 611                 or die "Failed to open $compose_filename.final : " . $!;
 612
 613         open(C,"<",$compose_filename)
 614                 or die "Failed to open $compose_filename : " . $!;
 615
 616         my $need_8bit_cte = file_has_nonascii($compose_filename);
 617         my $in_body = 0;
 618         my $summary_empty = 1;
 619         while(<C>) {
 620                 next if m/^GIT:/;
 621                 if ($in_body) {
 622                         $summary_empty = 0 unless (/^\n$/);
 623                 } elsif (/^\n$/) {
 624                         $in_body = 1;
 625                         if ($need_8bit_cte) {
 626                                 print C2 "MIME-Version: 1.0\n",
 627                                          "Content-Type: text/plain; ",
 628                                            "charset=UTF-8\n",
 629                                          "Content-Transfer-Encoding: 8bit\n";
 630                         }
 631                 } elsif (/^MIME-Version:/i) {
 632                         $need_8bit_cte = 0;
 633                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 634                         $initial_subject = $1;
 635                         my $subject = $initial_subject;
 636                         $_ = "Subject: " .
 637                                 ($subject =~ /[^[:ascii:]]/ ?
 638                                  quote_rfc2047($subject) :
 639                                  $subject) .
 640                                 "\n";
 641                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 642                         $initial_reply_to = $1;
 643                         next;
 644                 } elsif (/^From:\s*(.+)\s*$/i) {
 645                         $sender = $1;
 646                         next;
 647                 } elsif (/^(?:To|Cc|Bcc):/i) {
 648                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 649                         next;
 650                 }
 651                 print C2 $_;
 652         }
 653         close(C);
 654         close(C2);
 655
 656         if ($summary_empty) {
 657                 print "Summary email is empty, skipping it\n";
 658                 $compose = -1;
 659         }
 660 } elsif ($annotate) {
 661         do_edit(@files);
 662 }
 663
 664 sub ask {
 665         my ($prompt, %arg) = @_;
 666         my $valid_re = $arg{valid_re};
 667         my $default = $arg{default};
 668         my $resp;
 669         my $i = 0;
 670         return defined $default ? $default : undef
 671                 unless defined $term->IN and defined fileno($term->IN) and
 672                        defined $term->OUT and defined fileno($term->OUT);
 673         while ($i++ < 10) {
 674                 $resp = $term->readline($prompt);
 675                 if (!defined $resp) { # EOF
 676                         print "\n";
 677                         return defined $default ? $default : undef;
 678                 }
 679                 if ($resp eq '' and defined $default) {
 680                         return $default;
 681                 }
 682                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 683                         return $resp;
 684                 }
 685         }
 686         return undef;
 687 }
 688
 689 my %broken_encoding;
 690
 691 sub file_declares_8bit_cte($) {
 692         my $fn = shift;
 693         open (my $fh, '<', $fn);
 694         while (my $line = <$fh>) {
 695                 last if ($line =~ /^$/);
 696                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 697         }
 698         close $fh;
 699         return 0;
 700 }
 701
 702 foreach my $f (@files) {
 703         next unless (body_or_subject_has_nonascii($f)
 704                      && !file_declares_8bit_cte($f));
 705         $broken_encoding{$f} = 1;
 706 }
 707
 708 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 709         print "The following files are 8bit, but do not declare " .
 710                 "a Content-Transfer-Encoding.\n";
 711         foreach my $f (sort keys %broken_encoding) {
 712                 print "    $f\n";
 713         }
 714         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 715                                   default => "UTF-8");
 716 }
 717
 718 if (!$force) {
 719         for my $f (@files) {
 720                 if (get_patch_subject($f) =~ /\*\*\* SUBJECT HERE \*\*\*/) {
 721                         die "Refusing to send because the patch\n\t$f\n"
 722                                 . "has the template subject '*** SUBJECT HERE ***'. "
 723                                 . "Pass --force if you really want to send.\n";
 724                 }
 725         }
 726 }
 727
 728 my $prompting = 0;
 729 if (!defined $sender) {
 730         $sender = $repoauthor || $repocommitter || '';
 731         $sender = ask("Who should the emails appear to be from? [$sender] ",
 732                       default => $sender);
 733         print "Emails will be sent from: ", $sender, "\n";
 734         $prompting++;
 735 }
 736
 737 if (!@initial_to && !defined $to_cmd) {
 738         my $to = ask("Who should the emails be sent to? ");
 739         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 740         $prompting++;
 741 }
 742
 743 sub expand_aliases {
 744         return map { expand_one_alias($_) } @_;
 745 }
 746
 747 my %EXPANDED_ALIASES;
 748 sub expand_one_alias {
 749         my $alias = shift;
 750         if ($EXPANDED_ALIASES{$alias}) {
 751                 die "fatal: alias '$alias' expands to itself\n";
 752         }
 753         local $EXPANDED_ALIASES{$alias} = 1;
 754         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 755 }
 756
 757 @initial_to = expand_aliases(@initial_to);
 758 @initial_to = (map { sanitize_address($_) } @initial_to);
 759 @initial_cc = expand_aliases(@initial_cc);
 760 @bcclist = expand_aliases(@bcclist);
 761
 762 if ($thread && !defined $initial_reply_to && $prompting) {
 763         $initial_reply_to = ask(
 764                 "Message-ID to be used as In-Reply-To for the first email? ");
 765 }
 766 if (defined $initial_reply_to) {
 767         $initial_reply_to =~ s/^\s*<?//;
 768         $initial_reply_to =~ s/>?\s*$//;
 769         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 770 }
 771
 772 if (!defined $smtp_server) {
 773         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 774                 if (-x $_) {
 775                         $smtp_server = $_;
 776                         last;
 777                 }
 778         }
 779         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 780 }
 781
 782 if ($compose && $compose > 0) {
 783         @files = ($compose_filename . ".final", @files);
 784 }
 785
 786 # Variables we set as part of the loop over files
 787 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 788         $needs_confirm, $message_num, $ask_default);
 789
 790 sub extract_valid_address {
 791         my $address = shift;
 792         my $local_part_regexp = '[^<>"\s@]+';
 793         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 794
 795         # check for a local address:
 796         return $address if ($address =~ /^($local_part_regexp)$/);
 797
 798         $address =~ s/^\s*<(.*)>\s*$/$1/;
 799         if ($have_email_valid) {
 800                 return scalar Email::Valid->address($address);
 801         } else {
 802                 # less robust/correct than the monster regexp in Email::Valid,
 803                 # but still does a 99% job, and one less dependency
 804                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 805                 return $1;
 806         }
 807 }
 808
 809 # Usually don't need to change anything below here.
 810
 811 # we make a "fake" message id by taking the current number
 812 # of seconds since the beginning of Unix time and tacking on
 813 # a random number to the end, in case we are called quicker than
 814 # 1 second since the last time we were called.
 815
 816 # We'll setup a template for the message id, using the "from" address:
 817
 818 my ($message_id_stamp, $message_id_serial);
 819 sub make_message_id {
 820         my $uniq;
 821         if (!defined $message_id_stamp) {
 822                 $message_id_stamp = sprintf("%s-%s", time, $$);
 823                 $message_id_serial = 0;
 824         }
 825         $message_id_serial++;
 826         $uniq = "$message_id_stamp-$message_id_serial";
 827
 828         my $du_part;
 829         for ($sender, $repocommitter, $repoauthor) {
 830                 $du_part = extract_valid_address(sanitize_address($_));
 831                 last if (defined $du_part and $du_part ne '');
 832         }
 833         if (not defined $du_part or $du_part eq '') {
 834                 use Sys::Hostname qw();
 835                 $du_part = 'user@' . Sys::Hostname::hostname();
 836         }
 837         my $message_id_template = "<%s-git-send-email-%s>";
 838         $message_id = sprintf($message_id_template, $uniq, $du_part);
 839         #print "new message id = $message_id\n"; # Was useful for debugging
 840 }
 841
 842
 843
 844 $time = time - scalar $#files;
 845
 846 sub unquote_rfc2047 {
 847         local ($_) = @_;
 848         my $encoding;
 849         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 850                 $encoding = $1;
 851                 s/_/ /g;
 852                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 853         }
 854         return wantarray ? ($_, $encoding) : $_;
 855 }
 856
 857 sub quote_rfc2047 {
 858         local $_ = shift;
 859         my $encoding = shift || 'UTF-8';
 860         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 861         s/(.*)/=\?$encoding\?q\?$1\?=/;
 862         return $_;
 863 }
 864
 865 sub is_rfc2047_quoted {
 866         my $s = shift;
 867         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 868         my $encoded_text = '[!->@-~]+';
 869         length($s) <= 75 &&
 870         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 871 }
 872
 873 # use the simplest quoting being able to handle the recipient
 874 sub sanitize_address {
 875         my ($recipient) = @_;
 876         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 877
 878         if (not $recipient_name) {
 879                 return "$recipient";
 880         }
 881
 882         # if recipient_name is already quoted, do nothing
 883         if (is_rfc2047_quoted($recipient_name)) {
 884                 return $recipient;
 885         }
 886
 887         # rfc2047 is needed if a non-ascii char is included
 888         if ($recipient_name =~ /[^[:ascii:]]/) {
 889                 $recipient_name =~ s/^"(.*)"$/$1/;
 890                 $recipient_name = quote_rfc2047($recipient_name);
 891         }
 892
 893         # double quotes are needed if specials or CTLs are included
 894         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 895                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 896                 $recipient_name = "\"$recipient_name\"";
 897         }
 898
 899         return "$recipient_name $recipient_addr";
 900
 901 }
 902
 903 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 904 #
 905 # Tightly configured MTAa require that a caller sends a real DNS
 906 # domain name that corresponds the IP address in the HELO/EHLO
 907 # handshake. This is used to verify the connection and prevent
 908 # spammers from trying to hide their identity. If the DNS and IP don't
 909 # match, the receiveing MTA may deny the connection.
 910 #
 911 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 912 #
 913 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
 914 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
 915 #
 916 # This maildomain*() code is based on ideas in Perl library Test::Reporter
 917 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
 918
 919 sub valid_fqdn {
 920         my $domain = shift;
 921         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
 922 }
 923
 924 sub maildomain_net {
 925         my $maildomain;
 926
 927         if (eval { require Net::Domain; 1 }) {
 928                 my $domain = Net::Domain::domainname();
 929                 $maildomain = $domain if valid_fqdn($domain);
 930         }
 931
 932         return $maildomain;
 933 }
 934
 935 sub maildomain_mta {
 936         my $maildomain;
 937
 938         if (eval { require Net::SMTP; 1 }) {
 939                 for my $host (qw(mailhost localhost)) {
 940                         my $smtp = Net::SMTP->new($host);
 941                         if (defined $smtp) {
 942                                 my $domain = $smtp->domain;
 943                                 $smtp->quit;
 944
 945                                 $maildomain = $domain if valid_fqdn($domain);
 946
 947                                 last if $maildomain;
 948                         }
 949                 }
 950         }
 951
 952         return $maildomain;
 953 }
 954
 955 sub maildomain {
 956         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
 957 }
 958
 959 # Returns 1 if the message was sent, and 0 otherwise.
 960 # In actuality, the whole program dies when there
 961 # is an error sending a message.
 962
 963 sub send_message {
 964         my @recipients = unique_email_list(@to);
 965         @cc = (grep { my $cc = extract_valid_address($_);
 966                       not grep { $cc eq $_ } @recipients
 967                     }
 968                map { sanitize_address($_) }
 969                @cc);
 970         my $to = join (",\n\t", @recipients);
 971         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 972         @recipients = (map { extract_valid_address($_) } @recipients);
 973         my $date = format_2822_time($time++);
 974         my $gitversion = '@@GIT_VERSION@@';
 975         if ($gitversion =~ m/..GIT_VERSION../) {
 976             $gitversion = Git::version();
 977         }
 978
 979         my $cc = join(",\n\t", unique_email_list(@cc));
 980         my $ccline = "";
 981         if ($cc ne '') {
 982                 $ccline = "\nCc: $cc";
 983         }
 984         my $sanitized_sender = sanitize_address($sender);
 985         make_message_id() unless defined($message_id);
 986
 987         my $header = "From: $sanitized_sender
 988 To: $to${ccline}
 989 Subject: $subject
 990 Date: $date
 991 Message-Id: $message_id
 992 X-Mailer: git-send-email $gitversion
 993 ";
 994         if ($reply_to) {
 995
 996                 $header .= "In-Reply-To: $reply_to\n";
 997                 $header .= "References: $references\n";
 998         }
 999         if (@xh) {
1000                 $header .= join("\n", @xh) . "\n";
1001         }
1002
1003         my @sendmail_parameters = ('-i', @recipients);
1004         my $raw_from = $sanitized_sender;
1005         if (defined $envelope_sender && $envelope_sender ne "auto") {
1006                 $raw_from = $envelope_sender;
1007         }
1008         $raw_from = extract_valid_address($raw_from);
1009         unshift (@sendmail_parameters,
1010                         '-f', $raw_from) if(defined $envelope_sender);
1011
1012         if ($needs_confirm && !$dry_run) {
1013                 print "\n$header\n";
1014                 if ($needs_confirm eq "inform") {
1015                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1016                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1017                         print "    The Cc list above has been expanded by additional\n";
1018                         print "    addresses found in the patch commit message. By default\n";
1019                         print "    send-email prompts before sending whenever this occurs.\n";
1020                         print "    This behavior is controlled by the sendemail.confirm\n";
1021                         print "    configuration setting.\n";
1022                         print "\n";
1023                         print "    For additional information, run 'git send-email --help'.\n";
1024                         print "    To retain the current behavior, but squelch this message,\n";
1025                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1026                 }
1027                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1028                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1029                          default => $ask_default);
1030                 die "Send this email reply required" unless defined $_;
1031                 if (/^n/i) {
1032                         return 0;
1033                 } elsif (/^q/i) {
1034                         cleanup_compose_files();
1035                         exit(0);
1036                 } elsif (/^a/i) {
1037                         $confirm = 'never';
1038                 }
1039         }
1040
1041         unshift (@sendmail_parameters, @smtp_server_options);
1042
1043         if ($dry_run) {
1044                 # We don't want to send the email.
1045         } elsif ($smtp_server =~ m#^/#) {
1046                 my $pid = open my $sm, '|-';
1047                 defined $pid or die $!;
1048                 if (!$pid) {
1049                         exec($smtp_server, @sendmail_parameters) or die $!;
1050                 }
1051                 print $sm "$header\n$message";
1052                 close $sm or die $?;
1053         } else {
1054
1055                 if (!defined $smtp_server) {
1056                         die "The required SMTP server is not properly defined."
1057                 }
1058
1059                 if ($smtp_encryption eq 'ssl') {
1060                         $smtp_server_port ||= 465; # ssmtp
1061                         require Net::SMTP::SSL;
1062                         $smtp_domain ||= maildomain();
1063                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1064                                                       Hello => $smtp_domain,
1065                                                       Port => $smtp_server_port);
1066                 }
1067                 else {
1068                         require Net::SMTP;
1069                         $smtp_domain ||= maildomain();
1070                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1071                                                  ? "$smtp_server:$smtp_server_port"
1072                                                  : $smtp_server,
1073                                                  Hello => $smtp_domain,
1074                                                  Debug => $debug_net_smtp);
1075                         if ($smtp_encryption eq 'tls' && $smtp) {
1076                                 require Net::SMTP::SSL;
1077                                 $smtp->command('STARTTLS');
1078                                 $smtp->response();
1079                                 if ($smtp->code == 220) {
1080                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1081                                                 or die "STARTTLS failed! ".$smtp->message;
1082                                         $smtp_encryption = '';
1083                                         # Send EHLO again to receive fresh
1084                                         # supported commands
1085                                         $smtp->hello();
1086                                 } else {
1087                                         die "Server does not support STARTTLS! ".$smtp->message;
1088                                 }
1089                         }
1090                 }
1091
1092                 if (!$smtp) {
1093                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1094                             "VALUES: server=$smtp_server ",
1095                             "encryption=$smtp_encryption ",
1096                             "hello=$smtp_domain",
1097                             defined $smtp_server_port ? "port=$smtp_server_port" : "";
1098                 }
1099
1100                 if (defined $smtp_authuser) {
1101
1102                         if (!defined $smtp_authpass) {
1103
1104                                 system "stty -echo";
1105
1106                                 do {
1107                                         print "Password: ";
1108                                         $_ = <STDIN>;
1109                                         print "\n";
1110                                 } while (!defined $_);
1111
1112                                 chomp($smtp_authpass = $_);
1113
1114                                 system "stty echo";
1115                         }
1116
1117                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1118                 }
1119
1120                 $smtp->mail( $raw_from ) or die $smtp->message;
1121                 $smtp->to( @recipients ) or die $smtp->message;
1122                 $smtp->data or die $smtp->message;
1123                 $smtp->datasend("$header\n$message") or die $smtp->message;
1124                 $smtp->dataend() or die $smtp->message;
1125                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1126         }
1127         if ($quiet) {
1128                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1129         } else {
1130                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1131                 if ($smtp_server !~ m#^/#) {
1132                         print "Server: $smtp_server\n";
1133                         print "MAIL FROM:<$raw_from>\n";
1134                         foreach my $entry (@recipients) {
1135                             print "RCPT TO:<$entry>\n";
1136                         }
1137                 } else {
1138                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1139                 }
1140                 print $header, "\n";
1141                 if ($smtp) {
1142                         print "Result: ", $smtp->code, ' ',
1143                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1144                 } else {
1145                         print "Result: OK\n";
1146                 }
1147         }
1148
1149         return 1;
1150 }
1151
1152 $reply_to = $initial_reply_to;
1153 $references = $initial_reply_to || '';
1154 $subject = $initial_subject;
1155 $message_num = 0;
1156
1157 foreach my $t (@files) {
1158         open(F,"<",$t) or die "can't open file $t";
1159
1160         my $author = undef;
1161         my $author_encoding;
1162         my $has_content_type;
1163         my $body_encoding;
1164         @to = ();
1165         @cc = ();
1166         @xh = ();
1167         my $input_format = undef;
1168         my @header = ();
1169         $message = "";
1170         $message_num++;
1171         # First unfold multiline header fields
1172         while(<F>) {
1173                 last if /^\s*$/;
1174                 if (/^\s+\S/ and @header) {
1175                         chomp($header[$#header]);
1176                         s/^\s+/ /;
1177                         $header[$#header] .= $_;
1178             } else {
1179                         push(@header, $_);
1180                 }
1181         }
1182         # Now parse the header
1183         foreach(@header) {
1184                 if (/^From /) {
1185                         $input_format = 'mbox';
1186                         next;
1187                 }
1188                 chomp;
1189                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1190                         $input_format = 'mbox';
1191                 }
1192
1193                 if (defined $input_format && $input_format eq 'mbox') {
1194                         if (/^Subject:\s+(.*)$/) {
1195                                 $subject = $1;
1196                         }
1197                         elsif (/^From:\s+(.*)$/) {
1198                                 ($author, $author_encoding) = unquote_rfc2047($1);
1199                                 next if $suppress_cc{'author'};
1200                                 next if $suppress_cc{'self'} and $author eq $sender;
1201                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1202                                         $1, $_) unless $quiet;
1203                                 push @cc, $1;
1204                         }
1205                         elsif (/^To:\s+(.*)$/) {
1206                                 foreach my $addr (parse_address_line($1)) {
1207                                         printf("(mbox) Adding to: %s from line '%s'\n",
1208                                                 $addr, $_) unless $quiet;
1209                                         push @to, sanitize_address($addr);
1210                                 }
1211                         }
1212                         elsif (/^Cc:\s+(.*)$/) {
1213                                 foreach my $addr (parse_address_line($1)) {
1214                                         if (unquote_rfc2047($addr) eq $sender) {
1215                                                 next if ($suppress_cc{'self'});
1216                                         } else {
1217                                                 next if ($suppress_cc{'cc'});
1218                                         }
1219                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1220                                                 $addr, $_) unless $quiet;
1221                                         push @cc, $addr;
1222                                 }
1223                         }
1224                         elsif (/^Content-type:/i) {
1225                                 $has_content_type = 1;
1226                                 if (/charset="?([^ "]+)/) {
1227                                         $body_encoding = $1;
1228                                 }
1229                                 push @xh, $_;
1230                         }
1231                         elsif (/^Message-Id: (.*)/i) {
1232                                 $message_id = $1;
1233                         }
1234                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1235                                 push @xh, $_;
1236                         }
1237
1238                 } else {
1239                         # In the traditional
1240                         # "send lots of email" format,
1241                         # line 1 = cc
1242                         # line 2 = subject
1243                         # So let's support that, too.
1244                         $input_format = 'lots';
1245                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1246                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1247                                         $_, $_) unless $quiet;
1248                                 push @cc, $_;
1249                         } elsif (!defined $subject) {
1250                                 $subject = $_;
1251                         }
1252                 }
1253         }
1254         # Now parse the message body
1255         while(<F>) {
1256                 $message .=  $_;
1257                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1258                         chomp;
1259                         my ($what, $c) = ($1, $2);
1260                         chomp $c;
1261                         if ($c eq $sender) {
1262                                 next if ($suppress_cc{'self'});
1263                         } else {
1264                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1265                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1266                         }
1267                         push @cc, $c;
1268                         printf("(body) Adding cc: %s from line '%s'\n",
1269                                 $c, $_) unless $quiet;
1270                 }
1271         }
1272         close F;
1273
1274         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1275                 if defined $to_cmd;
1276         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1277                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1278
1279         if ($broken_encoding{$t} && !$has_content_type) {
1280                 $has_content_type = 1;
1281                 push @xh, "MIME-Version: 1.0",
1282                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1283                         "Content-Transfer-Encoding: 8bit";
1284                 $body_encoding = $auto_8bit_encoding;
1285         }
1286
1287         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1288                 $subject = quote_rfc2047($subject, $auto_8bit_encoding);
1289         }
1290
1291         if (defined $author and $author ne $sender) {
1292                 $message = "From: $author\n\n$message";
1293                 if (defined $author_encoding) {
1294                         if ($has_content_type) {
1295                                 if ($body_encoding eq $author_encoding) {
1296                                         # ok, we already have the right encoding
1297                                 }
1298                                 else {
1299                                         # uh oh, we should re-encode
1300                                 }
1301                         }
1302                         else {
1303                                 $has_content_type = 1;
1304                                 push @xh,
1305                                   'MIME-Version: 1.0',
1306                                   "Content-Type: text/plain; charset=$author_encoding",
1307                                   'Content-Transfer-Encoding: 8bit';
1308                         }
1309                 }
1310         }
1311
1312         $needs_confirm = (
1313                 $confirm eq "always" or
1314                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1315                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1316         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1317
1318         @to = (@initial_to, @to);
1319         @cc = (@initial_cc, @cc);
1320
1321         my $message_was_sent = send_message();
1322
1323         # set up for the next message
1324         if ($thread && $message_was_sent &&
1325                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1326                 $reply_to = $message_id;
1327                 if (length $references > 0) {
1328                         $references .= "\n $message_id";
1329                 } else {
1330                         $references = "$message_id";
1331                 }
1332         }
1333         $message_id = undef;
1334 }
1335
1336 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1337 # and return a results array
1338 sub recipients_cmd {
1339         my ($prefix, $what, $cmd, $file) = @_;
1340
1341         my $sanitized_sender = sanitize_address($sender);
1342         my @addresses = ();
1343         open(F, "$cmd \Q$file\E |")
1344             or die "($prefix) Could not execute '$cmd'";
1345         while(<F>) {
1346                 my $address = $_;
1347                 $address =~ s/^\s*//g;
1348                 $address =~ s/\s*$//g;
1349                 $address = sanitize_address($address);
1350                 next if ($address eq $sanitized_sender and $suppress_from);
1351                 push @addresses, $address;
1352                 printf("($prefix) Adding %s: %s from: '%s'\n",
1353                        $what, $address, $cmd) unless $quiet;
1354                 }
1355         close F
1356             or die "($prefix) failed to close pipe to '$cmd'";
1357         return @addresses;
1358 }
1359
1360 cleanup_compose_files();
1361
1362 sub cleanup_compose_files() {
1363         unlink($compose_filename, $compose_filename . ".final") if $compose;
1364 }
1365
1366 $smtp->quit if $smtp;
1367
1368 sub unique_email_list(@) {
1369         my %seen;
1370         my @emails;
1371
1372         foreach my $entry (@_) {
1373                 if (my $clean = extract_valid_address($entry)) {
1374                         $seen{$clean} ||= 0;
1375                         next if $seen{$clean}++;
1376                         push @emails, $entry;
1377                 } else {
1378                         print STDERR "W: unable to extract a valid address",
1379                                         " from: $entry\n";
1380                 }
1381         }
1382         return @emails;
1383 }
1384
1385 sub validate_patch {
1386         my $fn = shift;
1387         open(my $fh, '<', $fn)
1388                 or die "unable to open $fn: $!\n";
1389         while (my $line = <$fh>) {
1390                 if (length($line) > 998) {
1391                         return "$.: patch contains a line longer than 998 characters";
1392                 }
1393         }
1394         return undef;
1395 }
1396
1397 sub file_has_nonascii {
1398         my $fn = shift;
1399         open(my $fh, '<', $fn)
1400                 or die "unable to open $fn: $!\n";
1401         while (my $line = <$fh>) {
1402                 return 1 if $line =~ /[^[:ascii:]]/;
1403         }
1404         return 0;
1405 }
1406
1407 sub body_or_subject_has_nonascii {
1408         my $fn = shift;
1409         open(my $fh, '<', $fn)
1410                 or die "unable to open $fn: $!\n";
1411         while (my $line = <$fh>) {
1412                 last if $line =~ /^$/;
1413                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1414         }
1415         while (my $line = <$fh>) {
1416                 return 1 if $line =~ /[^[:ascii:]]/;
1417         }
1418         return 0;
1419 }