git-gui/git-gui--askpass

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 # This is a trivial implementation of an SSH_ASKPASS handler.
   6 # Git-gui uses this script if none are already configured.
   7
   8 package require Tk
   9
  10 set answer {}
  11 set yesno  0
  12 set rc     255
  13
  14 if {$argc < 1} {
  15         set prompt "Enter your OpenSSH passphrase:"
  16 } else {
  17         set prompt [join $argv " "]
  18         if {[regexp -nocase {\(yes\/no\)\?\s*$} $prompt]} {
  19                 set yesno 1
  20         }
  21 }
  22
  23 message .m -text $prompt -justify center -aspect 4000
  24 pack .m -side top -fill x -padx 20 -pady 20 -expand 1
  25
  26 entry .e -textvariable answer -width 50
  27 pack .e -side top -fill x -padx 10 -pady 10
  28
  29 if {!$yesno} {
  30         .e configure -show "*"
  31 }
  32
  33 frame .b
  34 button .b.ok     -text OK     -command finish
  35 button .b.cancel -text Cancel -command cancel
  36
  37 pack .b.ok -side left -expand 1
  38 pack .b.cancel -side right -expand 1
  39 pack .b -side bottom -fill x -padx 10 -pady 10
  40
  41 bind . <Visibility> {focus -force .e}
  42 bind . <Key-Return> [list .b.ok invoke]
  43 bind . <Key-Escape> [list .b.cancel invoke]
  44 bind . <Destroy>    {set rc $rc}
  45
  46 proc cancel {} {
  47         set ::rc 255
  48 }
  49
  50 proc finish {} {
  51         if {$::yesno} {
  52                 if {$::answer ne "yes" && $::answer ne "no"} {
  53                         tk_messageBox -icon error -title "Error" -type ok \
  54                                 -message "Only 'yes' or 'no' input allowed."
  55                         return
  56                 }
  57         }
  58
  59         puts $::answer
  60         set ::rc 0
  61 }
  62
  63 wm title . "OpenSSH"
  64 tk::PlaceWindow .
  65 vwait rc
  66 exit $rc