git-gui/git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title "git-gui: fatal error" \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86         if {[tk windowingsystem] eq "win32"} { console show }
  87 }
  88
  89 ######################################################################
  90 ##
  91 ## Internationalization (i18n) through msgcat and gettext. See
  92 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  93
  94 package require msgcat
  95
  96 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
  97 if {[tk windowingsystem] eq "win32"
  98         && [package vcompare [package provide msgcat] 1.4.4] < 0
  99 } then {
 100         proc _mc_update_locale {} {
 101                 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 102                 if {![catch {
 103                         package require registry
 104                         set uilocale [registry get $key "PreferredUILanguages"]
 105                         msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 106                 } uilocale]} {
 107                         if {[string length $uilocale] > 0} {
 108                                 msgcat::mclocale $uilocale
 109                         }
 110                 }
 111         }
 112         _mc_update_locale
 113 }
 114
 115 proc _mc_trim {fmt} {
 116         set cmk [string first @@ $fmt]
 117         if {$cmk > 0} {
 118                 return [string range $fmt 0 [expr {$cmk - 1}]]
 119         }
 120         return $fmt
 121 }
 122
 123 proc mc {en_fmt args} {
 124         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 125         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 126                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 127         }
 128         return $msg
 129 }
 130
 131 proc strcat {args} {
 132         return [join $args {}]
 133 }
 134
 135 ::msgcat::mcload $oguimsg
 136 unset oguimsg
 137
 138 ######################################################################
 139 ##
 140 ## On Mac, bring the current Wish process window to front
 141
 142 if {[tk windowingsystem] eq "aqua"} {
 143         catch {
 144                 exec osascript -e [format {
 145                         tell application "System Events"
 146                                 set frontmost of processes whose unix id is %d to true
 147                         end tell
 148                 } [pid]]
 149         }
 150 }
 151
 152 ######################################################################
 153 ##
 154 ## read only globals
 155
 156 set _appname {Git Gui}
 157 set _gitdir {}
 158 set _gitworktree {}
 159 set _isbare {}
 160 set _gitexec {}
 161 set _githtmldir {}
 162 set _reponame {}
 163 set _iscygwin {}
 164 set _search_path {}
 165 set _shellpath {@@SHELL_PATH@@}
 166
 167 set _trace [lsearch -exact $argv --trace]
 168 if {$_trace >= 0} {
 169         set argv [lreplace $argv $_trace $_trace]
 170         set _trace 1
 171         if {[tk windowingsystem] eq "win32"} { console show }
 172 } else {
 173         set _trace 0
 174 }
 175
 176 # variable for the last merged branch (useful for a default when deleting
 177 # branches).
 178 set _last_merged_branch {}
 179
 180 proc shellpath {} {
 181         global _shellpath env
 182         if {[string match @@* $_shellpath]} {
 183                 if {[info exists env(SHELL)]} {
 184                         return $env(SHELL)
 185                 } else {
 186                         return /bin/sh
 187                 }
 188         }
 189         return $_shellpath
 190 }
 191
 192 proc appname {} {
 193         global _appname
 194         return $_appname
 195 }
 196
 197 proc gitdir {args} {
 198         global _gitdir
 199         if {$args eq {}} {
 200                 return $_gitdir
 201         }
 202         return [eval [list file join $_gitdir] $args]
 203 }
 204
 205 proc gitexec {args} {
 206         global _gitexec
 207         if {$_gitexec eq {}} {
 208                 if {[catch {set _gitexec [git --exec-path]} err]} {
 209                         error "Git not installed?\n\n$err"
 210                 }
 211                 if {[is_Cygwin]} {
 212                         set _gitexec [exec cygpath \
 213                                 --windows \
 214                                 --absolute \
 215                                 $_gitexec]
 216                 } else {
 217                         set _gitexec [file normalize $_gitexec]
 218                 }
 219         }
 220         if {$args eq {}} {
 221                 return $_gitexec
 222         }
 223         return [eval [list file join $_gitexec] $args]
 224 }
 225
 226 proc githtmldir {args} {
 227         global _githtmldir
 228         if {$_githtmldir eq {}} {
 229                 if {[catch {set _githtmldir [git --html-path]}]} {
 230                         # Git not installed or option not yet supported
 231                         return {}
 232                 }
 233                 if {[is_Cygwin]} {
 234                         set _githtmldir [exec cygpath \
 235                                 --windows \
 236                                 --absolute \
 237                                 $_githtmldir]
 238                 } else {
 239                         set _githtmldir [file normalize $_githtmldir]
 240                 }
 241         }
 242         if {$args eq {}} {
 243                 return $_githtmldir
 244         }
 245         return [eval [list file join $_githtmldir] $args]
 246 }
 247
 248 proc reponame {} {
 249         return $::_reponame
 250 }
 251
 252 proc is_MacOSX {} {
 253         if {[tk windowingsystem] eq {aqua}} {
 254                 return 1
 255         }
 256         return 0
 257 }
 258
 259 proc is_Windows {} {
 260         if {$::tcl_platform(platform) eq {windows}} {
 261                 return 1
 262         }
 263         return 0
 264 }
 265
 266 proc is_Cygwin {} {
 267         global _iscygwin
 268         if {$_iscygwin eq {}} {
 269                 if {$::tcl_platform(platform) eq {windows}} {
 270                         if {[catch {set p [exec cygpath --windir]} err]} {
 271                                 set _iscygwin 0
 272                         } else {
 273                                 set _iscygwin 1
 274                         }
 275                 } else {
 276                         set _iscygwin 0
 277                 }
 278         }
 279         return $_iscygwin
 280 }
 281
 282 proc is_enabled {option} {
 283         global enabled_options
 284         if {[catch {set on $enabled_options($option)}]} {return 0}
 285         return $on
 286 }
 287
 288 proc enable_option {option} {
 289         global enabled_options
 290         set enabled_options($option) 1
 291 }
 292
 293 proc disable_option {option} {
 294         global enabled_options
 295         set enabled_options($option) 0
 296 }
 297
 298 ######################################################################
 299 ##
 300 ## config
 301
 302 proc is_many_config {name} {
 303         switch -glob -- $name {
 304         gui.recentrepo -
 305         remote.*.fetch -
 306         remote.*.push
 307                 {return 1}
 308         *
 309                 {return 0}
 310         }
 311 }
 312
 313 proc is_config_true {name} {
 314         global repo_config
 315         if {[catch {set v $repo_config($name)}]} {
 316                 return 0
 317         }
 318         set v [string tolower $v]
 319         if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
 320                 return 1
 321         } else {
 322                 return 0
 323         }
 324 }
 325
 326 proc is_config_false {name} {
 327         global repo_config
 328         if {[catch {set v $repo_config($name)}]} {
 329                 return 0
 330         }
 331         set v [string tolower $v]
 332         if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
 333                 return 1
 334         } else {
 335                 return 0
 336         }
 337 }
 338
 339 proc get_config {name} {
 340         global repo_config
 341         if {[catch {set v $repo_config($name)}]} {
 342                 return {}
 343         } else {
 344                 return $v
 345         }
 346 }
 347
 348 proc is_bare {} {
 349         global _isbare
 350         global _gitdir
 351         global _gitworktree
 352
 353         if {$_isbare eq {}} {
 354                 if {[catch {
 355                         set _bare [git rev-parse --is-bare-repository]
 356                         switch  -- $_bare {
 357                         true { set _isbare 1 }
 358                         false { set _isbare 0}
 359                         default { throw }
 360                         }
 361                 }]} {
 362                         if {[is_config_true core.bare]
 363                                 || ($_gitworktree eq {}
 364                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 365                                 set _isbare 1
 366                         } else {
 367                                 set _isbare 0
 368                         }
 369                 }
 370         }
 371         return $_isbare
 372 }
 373
 374 ######################################################################
 375 ##
 376 ## handy utils
 377
 378 proc _trace_exec {cmd} {
 379         if {!$::_trace} return
 380         set d {}
 381         foreach v $cmd {
 382                 if {$d ne {}} {
 383                         append d { }
 384                 }
 385                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 386                         set v [sq $v]
 387                 }
 388                 append d $v
 389         }
 390         puts stderr $d
 391 }
 392
 393 #'"  fix poor old emacs font-lock mode
 394
 395 proc _git_cmd {name} {
 396         global _git_cmd_path
 397
 398         if {[catch {set v $_git_cmd_path($name)}]} {
 399                 switch -- $name {
 400                   version   -
 401                 --version   -
 402                 --exec-path { return [list $::_git $name] }
 403                 }
 404
 405                 set p [gitexec git-$name$::_search_exe]
 406                 if {[file exists $p]} {
 407                         set v [list $p]
 408                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 409                         # Try to determine what sort of magic will make
 410                         # git-$name go and do its thing, because native
 411                         # Tcl on Windows doesn't know it.
 412                         #
 413                         set p [gitexec git-$name]
 414                         set f [open $p r]
 415                         set s [gets $f]
 416                         close $f
 417
 418                         switch -glob -- [lindex $s 0] {
 419                         #!*sh     { set i sh     }
 420                         #!*perl   { set i perl   }
 421                         #!*python { set i python }
 422                         default   { error "git-$name is not supported: $s" }
 423                         }
 424
 425                         upvar #0 _$i interp
 426                         if {![info exists interp]} {
 427                                 set interp [_which $i]
 428                         }
 429                         if {$interp eq {}} {
 430                                 error "git-$name requires $i (not in PATH)"
 431                         }
 432                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 433                 } else {
 434                         # Assume it is builtin to git somehow and we
 435                         # aren't actually able to see a file for it.
 436                         #
 437                         set v [list $::_git $name]
 438                 }
 439                 set _git_cmd_path($name) $v
 440         }
 441         return $v
 442 }
 443
 444 proc _which {what args} {
 445         global env _search_exe _search_path
 446
 447         if {$_search_path eq {}} {
 448                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 449                         set _search_path [split [exec cygpath \
 450                                 --windows \
 451                                 --path \
 452                                 --absolute \
 453                                 $env(PATH)] {;}]
 454                         set _search_exe .exe
 455                 } elseif {[is_Windows]} {
 456                         set gitguidir [file dirname [info script]]
 457                         regsub -all ";" $gitguidir "\\;" gitguidir
 458                         set env(PATH) "$gitguidir;$env(PATH)"
 459                         set _search_path [split $env(PATH) {;}]
 460                         set _search_exe .exe
 461                 } else {
 462                         set _search_path [split $env(PATH) :]
 463                         set _search_exe {}
 464                 }
 465         }
 466
 467         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 468                 set suffix {}
 469         } else {
 470                 set suffix $_search_exe
 471         }
 472
 473         foreach p $_search_path {
 474                 set p [file join $p $what$suffix]
 475                 if {[file exists $p]} {
 476                         return [file normalize $p]
 477                 }
 478         }
 479         return {}
 480 }
 481
 482 # Test a file for a hashbang to identify executable scripts on Windows.
 483 proc is_shellscript {filename} {
 484         if {![file exists $filename]} {return 0}
 485         set f [open $filename r]
 486         fconfigure $f -encoding binary
 487         set magic [read $f 2]
 488         close $f
 489         return [expr {$magic eq "#!"}]
 490 }
 491
 492 # Run a command connected via pipes on stdout.
 493 # This is for use with textconv filters and uses sh -c "..." to allow it to
 494 # contain a command with arguments. On windows we must check for shell
 495 # scripts specifically otherwise just call the filter command.
 496 proc open_cmd_pipe {cmd path} {
 497         global env
 498         if {![file executable [shellpath]]} {
 499                 set exe [auto_execok [lindex $cmd 0]]
 500                 if {[is_shellscript [lindex $exe 0]]} {
 501                         set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
 502                 } else {
 503                         set run [concat $exe [lrange $cmd 1 end] $path]
 504                 }
 505         } else {
 506                 set run [list [shellpath] -c "$cmd \"\$0\"" $path]
 507         }
 508         return [open |$run r]
 509 }
 510
 511 proc _lappend_nice {cmd_var} {
 512         global _nice
 513         upvar $cmd_var cmd
 514
 515         if {![info exists _nice]} {
 516                 set _nice [_which nice]
 517                 if {[catch {exec $_nice git version}]} {
 518                         set _nice {}
 519                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 520                         set _nice {}
 521                 }
 522         }
 523         if {$_nice ne {}} {
 524                 lappend cmd $_nice
 525         }
 526 }
 527
 528 proc git {args} {
 529         set opt [list]
 530
 531         while {1} {
 532                 switch -- [lindex $args 0] {
 533                 --nice {
 534                         _lappend_nice opt
 535                 }
 536
 537                 default {
 538                         break
 539                 }
 540
 541                 }
 542
 543                 set args [lrange $args 1 end]
 544         }
 545
 546         set cmdp [_git_cmd [lindex $args 0]]
 547         set args [lrange $args 1 end]
 548
 549         _trace_exec [concat $opt $cmdp $args]
 550         set result [eval exec $opt $cmdp $args]
 551         if {[encoding system] != "utf-8"} {
 552                 set result [encoding convertfrom utf-8 [encoding convertto $result]]
 553         }
 554         if {$::_trace} {
 555                 puts stderr "< $result"
 556         }
 557         return $result
 558 }
 559
 560 proc _open_stdout_stderr {cmd} {
 561         _trace_exec $cmd
 562         if {[catch {
 563                         set fd [open [concat [list | ] $cmd] r]
 564                 } err]} {
 565                 if {   [lindex $cmd end] eq {2>@1}
 566                     && $err eq {can not find channel named "1"}
 567                         } {
 568                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 569                         # redirect operator.  Fallback to |& cat for those.
 570                         # The command was not actually started, so its safe
 571                         # to try to start it a second time.
 572                         #
 573                         set fd [open [concat \
 574                                 [list | ] \
 575                                 [lrange $cmd 0 end-1] \
 576                                 [list |& cat] \
 577                                 ] r]
 578                 } else {
 579                         error $err
 580                 }
 581         }
 582         fconfigure $fd -eofchar {}
 583         return $fd
 584 }
 585
 586 proc git_read {args} {
 587         set opt [list]
 588
 589         while {1} {
 590                 switch -- [lindex $args 0] {
 591                 --nice {
 592                         _lappend_nice opt
 593                 }
 594
 595                 --stderr {
 596                         lappend args 2>@1
 597                 }
 598
 599                 default {
 600                         break
 601                 }
 602
 603                 }
 604
 605                 set args [lrange $args 1 end]
 606         }
 607
 608         set cmdp [_git_cmd [lindex $args 0]]
 609         set args [lrange $args 1 end]
 610
 611         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 612 }
 613
 614 proc git_write {args} {
 615         set opt [list]
 616
 617         while {1} {
 618                 switch -- [lindex $args 0] {
 619                 --nice {
 620                         _lappend_nice opt
 621                 }
 622
 623                 default {
 624                         break
 625                 }
 626
 627                 }
 628
 629                 set args [lrange $args 1 end]
 630         }
 631
 632         set cmdp [_git_cmd [lindex $args 0]]
 633         set args [lrange $args 1 end]
 634
 635         _trace_exec [concat $opt $cmdp $args]
 636         return [open [concat [list | ] $opt $cmdp $args] w]
 637 }
 638
 639 proc githook_read {hook_name args} {
 640         set pchook [gitdir hooks $hook_name]
 641         lappend args 2>@1
 642
 643         # On Windows [file executable] might lie so we need to ask
 644         # the shell if the hook is executable.  Yes that's annoying.
 645         #
 646         if {[is_Windows]} {
 647                 upvar #0 _sh interp
 648                 if {![info exists interp]} {
 649                         set interp [_which sh]
 650                 }
 651                 if {$interp eq {}} {
 652                         error "hook execution requires sh (not in PATH)"
 653                 }
 654
 655                 set scr {if test -x "$1";then exec "$@";fi}
 656                 set sh_c [list $interp -c $scr $interp $pchook]
 657                 return [_open_stdout_stderr [concat $sh_c $args]]
 658         }
 659
 660         if {[file executable $pchook]} {
 661                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 662         }
 663
 664         return {}
 665 }
 666
 667 proc kill_file_process {fd} {
 668         set process [pid $fd]
 669
 670         catch {
 671                 if {[is_Windows]} {
 672                         # Use a Cygwin-specific flag to allow killing
 673                         # native Windows processes
 674                         exec kill -f $process
 675                 } else {
 676                         exec kill $process
 677                 }
 678         }
 679 }
 680
 681 proc gitattr {path attr default} {
 682         if {[catch {set r [git check-attr $attr -- $path]}]} {
 683                 set r unspecified
 684         } else {
 685                 set r [join [lrange [split $r :] 2 end] :]
 686                 regsub {^ } $r {} r
 687         }
 688         if {$r eq {unspecified}} {
 689                 return $default
 690         }
 691         return $r
 692 }
 693
 694 proc sq {value} {
 695         regsub -all ' $value "'\\''" value
 696         return "'$value'"
 697 }
 698
 699 proc load_current_branch {} {
 700         global current_branch is_detached
 701
 702         set fd [open [gitdir HEAD] r]
 703         if {[gets $fd ref] < 1} {
 704                 set ref {}
 705         }
 706         close $fd
 707
 708         set pfx {ref: refs/heads/}
 709         set len [string length $pfx]
 710         if {[string equal -length $len $pfx $ref]} {
 711                 # We're on a branch.  It might not exist.  But
 712                 # HEAD looks good enough to be a branch.
 713                 #
 714                 set current_branch [string range $ref $len end]
 715                 set is_detached 0
 716         } else {
 717                 # Assume this is a detached head.
 718                 #
 719                 set current_branch HEAD
 720                 set is_detached 1
 721         }
 722 }
 723
 724 auto_load tk_optionMenu
 725 rename tk_optionMenu real__tkOptionMenu
 726 proc tk_optionMenu {w varName args} {
 727         set m [eval real__tkOptionMenu $w $varName $args]
 728         $m configure -font font_ui
 729         $w configure -font font_ui
 730         return $m
 731 }
 732
 733 proc rmsel_tag {text} {
 734         $text tag conf sel \
 735                 -background [$text cget -background] \
 736                 -foreground [$text cget -foreground] \
 737                 -borderwidth 0
 738         $text tag conf in_sel -background lightgray
 739         bind $text <Motion> break
 740         return $text
 741 }
 742
 743 wm withdraw .
 744 set root_exists 0
 745 bind . <Visibility> {
 746         bind . <Visibility> {}
 747         set root_exists 1
 748 }
 749
 750 if {[is_Windows]} {
 751         wm iconbitmap . -default $oguilib/git-gui.ico
 752         set ::tk::AlwaysShowSelection 1
 753         bind . <Control-F2> {console show}
 754
 755         # Spoof an X11 display for SSH
 756         if {![info exists env(DISPLAY)]} {
 757                 set env(DISPLAY) :9999
 758         }
 759 } else {
 760         catch {
 761                 image create photo gitlogo -width 16 -height 16
 762
 763                 gitlogo put #33CC33 -to  7  0  9  2
 764                 gitlogo put #33CC33 -to  4  2 12  4
 765                 gitlogo put #33CC33 -to  7  4  9  6
 766                 gitlogo put #CC3333 -to  4  6 12  8
 767                 gitlogo put gray26  -to  4  9  6 10
 768                 gitlogo put gray26  -to  3 10  6 12
 769                 gitlogo put gray26  -to  8  9 13 11
 770                 gitlogo put gray26  -to  8 11 10 12
 771                 gitlogo put gray26  -to 11 11 13 14
 772                 gitlogo put gray26  -to  3 12  5 14
 773                 gitlogo put gray26  -to  5 13
 774                 gitlogo put gray26  -to 10 13
 775                 gitlogo put gray26  -to  4 14 12 15
 776                 gitlogo put gray26  -to  5 15 11 16
 777                 gitlogo redither
 778
 779                 image create photo gitlogo32 -width 32 -height 32
 780                 gitlogo32 copy gitlogo -zoom 2 2
 781
 782                 wm iconphoto . -default gitlogo gitlogo32
 783         }
 784 }
 785
 786 ######################################################################
 787 ##
 788 ## config defaults
 789
 790 set cursor_ptr arrow
 791 font create font_ui
 792 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 793         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 794         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 795 } else {
 796         font create font_diff -family Courier -size 10
 797         catch {
 798                 label .dummy
 799                 eval font configure font_ui [font actual [.dummy cget -font]]
 800                 destroy .dummy
 801         }
 802 }
 803
 804 font create font_uiitalic
 805 font create font_uibold
 806 font create font_diffbold
 807 font create font_diffitalic
 808
 809 foreach class {Button Checkbutton Entry Label
 810                 Labelframe Listbox Message
 811                 Radiobutton Spinbox Text} {
 812         option add *$class.font font_ui
 813 }
 814 if {![is_MacOSX]} {
 815         option add *Menu.font font_ui
 816         option add *Entry.borderWidth 1 startupFile
 817         option add *Entry.relief sunken startupFile
 818         option add *RadioButton.anchor w startupFile
 819 }
 820 unset class
 821
 822 if {[is_Windows] || [is_MacOSX]} {
 823         option add *Menu.tearOff 0
 824 }
 825
 826 if {[is_MacOSX]} {
 827         set M1B M1
 828         set M1T Cmd
 829 } else {
 830         set M1B Control
 831         set M1T Ctrl
 832 }
 833
 834 proc bind_button3 {w cmd} {
 835         bind $w <Any-Button-3> $cmd
 836         if {[is_MacOSX]} {
 837                 # Mac OS X sends Button-2 on right click through three-button mouse,
 838                 # or through trackpad right-clicking (two-finger touch + click).
 839                 bind $w <Any-Button-2> $cmd
 840                 bind $w <Control-Button-1> $cmd
 841         }
 842 }
 843
 844 proc apply_config {} {
 845         global repo_config font_descs
 846
 847         foreach option $font_descs {
 848                 set name [lindex $option 0]
 849                 set font [lindex $option 1]
 850                 if {[catch {
 851                         set need_weight 1
 852                         foreach {cn cv} $repo_config(gui.$name) {
 853                                 if {$cn eq {-weight}} {
 854                                         set need_weight 0
 855                                 }
 856                                 font configure $font $cn $cv
 857                         }
 858                         if {$need_weight} {
 859                                 font configure $font -weight normal
 860                         }
 861                         } err]} {
 862                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 863                 }
 864                 foreach {cn cv} [font configure $font] {
 865                         font configure ${font}bold $cn $cv
 866                         font configure ${font}italic $cn $cv
 867                 }
 868                 font configure ${font}bold -weight bold
 869                 font configure ${font}italic -slant italic
 870         }
 871
 872         global use_ttk NS
 873         set use_ttk 0
 874         set NS {}
 875         if {$repo_config(gui.usettk)} {
 876                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 877                 if {$use_ttk} {
 878                         set NS ttk
 879                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 880                         pave_toplevel .
 881                 }
 882         }
 883 }
 884
 885 set default_config(branch.autosetupmerge) true
 886 set default_config(merge.tool) {}
 887 set default_config(mergetool.keepbackup) true
 888 set default_config(merge.diffstat) true
 889 set default_config(merge.summary) false
 890 set default_config(merge.verbosity) 2
 891 set default_config(user.name) {}
 892 set default_config(user.email) {}
 893
 894 set default_config(gui.encoding) [encoding system]
 895 set default_config(gui.matchtrackingbranch) false
 896 set default_config(gui.textconv) true
 897 set default_config(gui.pruneduringfetch) false
 898 set default_config(gui.trustmtime) false
 899 set default_config(gui.fastcopyblame) false
 900 set default_config(gui.maxrecentrepo) 10
 901 set default_config(gui.copyblamethreshold) 40
 902 set default_config(gui.blamehistoryctx) 7
 903 set default_config(gui.diffcontext) 5
 904 set default_config(gui.diffopts) {}
 905 set default_config(gui.commitmsgwidth) 75
 906 set default_config(gui.newbranchtemplate) {}
 907 set default_config(gui.spellingdictionary) {}
 908 set default_config(gui.fontui) [font configure font_ui]
 909 set default_config(gui.fontdiff) [font configure font_diff]
 910 # TODO: this option should be added to the git-config documentation
 911 set default_config(gui.maxfilesdisplayed) 5000
 912 set default_config(gui.usettk) 1
 913 set default_config(gui.warndetachedcommit) 1
 914 set font_descs {
 915         {fontui   font_ui   {mc "Main Font"}}
 916         {fontdiff font_diff {mc "Diff/Console Font"}}
 917 }
 918 set default_config(gui.stageuntracked) ask
 919 set default_config(gui.displayuntracked) true
 920
 921 ######################################################################
 922 ##
 923 ## find git
 924
 925 set _git  [_which git]
 926 if {$_git eq {}} {
 927         catch {wm withdraw .}
 928         tk_messageBox \
 929                 -icon error \
 930                 -type ok \
 931                 -title [mc "git-gui: fatal error"] \
 932                 -message [mc "Cannot find git in PATH."]
 933         exit 1
 934 }
 935
 936 ######################################################################
 937 ##
 938 ## version check
 939
 940 if {[catch {set _git_version [git --version]} err]} {
 941         catch {wm withdraw .}
 942         tk_messageBox \
 943                 -icon error \
 944                 -type ok \
 945                 -title [mc "git-gui: fatal error"] \
 946                 -message "Cannot determine Git version:
 947
 948 $err
 949
 950 [appname] requires Git 1.5.0 or later."
 951         exit 1
 952 }
 953 if {![regsub {^git version } $_git_version {} _git_version]} {
 954         catch {wm withdraw .}
 955         tk_messageBox \
 956                 -icon error \
 957                 -type ok \
 958                 -title [mc "git-gui: fatal error"] \
 959                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 960         exit 1
 961 }
 962
 963 proc get_trimmed_version {s} {
 964     set r {}
 965     foreach x [split $s -._] {
 966         if {[string is integer -strict $x]} {
 967             lappend r $x
 968         } else {
 969             break
 970         }
 971     }
 972     return [join $r .]
 973 }
 974 set _real_git_version $_git_version
 975 set _git_version [get_trimmed_version $_git_version]
 976
 977 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 978         catch {wm withdraw .}
 979         if {[tk_messageBox \
 980                 -icon warning \
 981                 -type yesno \
 982                 -default no \
 983                 -title "[appname]: warning" \
 984                  -message [mc "Git version cannot be determined.
 985
 986 %s claims it is version '%s'.
 987
 988 %s requires at least Git 1.5.0 or later.
 989
 990 Assume '%s' is version 1.5.0?
 991 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 992                 set _git_version 1.5.0
 993         } else {
 994                 exit 1
 995         }
 996 }
 997 unset _real_git_version
 998
 999 proc git-version {args} {
1000         global _git_version
1001
1002         switch [llength $args] {
1003         0 {
1004                 return $_git_version
1005         }
1006
1007         2 {
1008                 set op [lindex $args 0]
1009                 set vr [lindex $args 1]
1010                 set cm [package vcompare $_git_version $vr]
1011                 return [expr $cm $op 0]
1012         }
1013
1014         4 {
1015                 set type [lindex $args 0]
1016                 set name [lindex $args 1]
1017                 set parm [lindex $args 2]
1018                 set body [lindex $args 3]
1019
1020                 if {($type ne {proc} && $type ne {method})} {
1021                         error "Invalid arguments to git-version"
1022                 }
1023                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1024                         error "Last arm of $type $name must be default"
1025                 }
1026
1027                 foreach {op vr cb} [lrange $body 0 end-2] {
1028                         if {[git-version $op $vr]} {
1029                                 return [uplevel [list $type $name $parm $cb]]
1030                         }
1031                 }
1032
1033                 return [uplevel [list $type $name $parm [lindex $body end]]]
1034         }
1035
1036         default {
1037                 error "git-version >= x"
1038         }
1039
1040         }
1041 }
1042
1043 if {[git-version < 1.5]} {
1044         catch {wm withdraw .}
1045         tk_messageBox \
1046                 -icon error \
1047                 -type ok \
1048                 -title [mc "git-gui: fatal error"] \
1049                 -message "[appname] requires Git 1.5.0 or later.
1050
1051 You are using [git-version]:
1052
1053 [git --version]"
1054         exit 1
1055 }
1056
1057 ######################################################################
1058 ##
1059 ## configure our library
1060
1061 set idx [file join $oguilib tclIndex]
1062 if {[catch {set fd [open $idx r]} err]} {
1063         catch {wm withdraw .}
1064         tk_messageBox \
1065                 -icon error \
1066                 -type ok \
1067                 -title [mc "git-gui: fatal error"] \
1068                 -message $err
1069         exit 1
1070 }
1071 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1072         set idx [list]
1073         while {[gets $fd n] >= 0} {
1074                 if {$n ne {} && ![string match #* $n]} {
1075                         lappend idx $n
1076                 }
1077         }
1078 } else {
1079         set idx {}
1080 }
1081 close $fd
1082
1083 if {$idx ne {}} {
1084         set loaded [list]
1085         foreach p $idx {
1086                 if {[lsearch -exact $loaded $p] >= 0} continue
1087                 source [file join $oguilib $p]
1088                 lappend loaded $p
1089         }
1090         unset loaded p
1091 } else {
1092         set auto_path [concat [list $oguilib] $auto_path]
1093 }
1094 unset -nocomplain idx fd
1095
1096 ######################################################################
1097 ##
1098 ## config file parsing
1099
1100 git-version proc _parse_config {arr_name args} {
1101         >= 1.5.3 {
1102                 upvar $arr_name arr
1103                 array unset arr
1104                 set buf {}
1105                 catch {
1106                         set fd_rc [eval \
1107                                 [list git_read config] \
1108                                 $args \
1109                                 [list --null --list]]
1110                         fconfigure $fd_rc -translation binary -encoding utf-8
1111                         set buf [read $fd_rc]
1112                         close $fd_rc
1113                 }
1114                 foreach line [split $buf "\0"] {
1115                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1116                                 if {[is_many_config $name]} {
1117                                         lappend arr($name) $value
1118                                 } else {
1119                                         set arr($name) $value
1120                                 }
1121                         } elseif {[regexp {^([^\n]+)$} $line line name]} {
1122                                 # no value given, but interpreting them as
1123                                 # boolean will be handled as true
1124                                 set arr($name) {}
1125                         }
1126                 }
1127         }
1128         default {
1129                 upvar $arr_name arr
1130                 array unset arr
1131                 catch {
1132                         set fd_rc [eval [list git_read config --list] $args]
1133                         while {[gets $fd_rc line] >= 0} {
1134                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1135                                         if {[is_many_config $name]} {
1136                                                 lappend arr($name) $value
1137                                         } else {
1138                                                 set arr($name) $value
1139                                         }
1140                                 } elseif {[regexp {^([^=]+)$} $line line name]} {
1141                                         # no value given, but interpreting them as
1142                                         # boolean will be handled as true
1143                                         set arr($name) {}
1144                                 }
1145                         }
1146                         close $fd_rc
1147                 }
1148         }
1149 }
1150
1151 proc load_config {include_global} {
1152         global repo_config global_config system_config default_config
1153
1154         if {$include_global} {
1155                 _parse_config system_config --system
1156                 _parse_config global_config --global
1157         }
1158         _parse_config repo_config
1159
1160         foreach name [array names default_config] {
1161                 if {[catch {set v $system_config($name)}]} {
1162                         set system_config($name) $default_config($name)
1163                 }
1164         }
1165         foreach name [array names system_config] {
1166                 if {[catch {set v $global_config($name)}]} {
1167                         set global_config($name) $system_config($name)
1168                 }
1169                 if {[catch {set v $repo_config($name)}]} {
1170                         set repo_config($name) $system_config($name)
1171                 }
1172         }
1173 }
1174
1175 ######################################################################
1176 ##
1177 ## feature option selection
1178
1179 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1180         unset _junk
1181 } else {
1182         set subcommand gui
1183 }
1184 if {$subcommand eq {gui.sh}} {
1185         set subcommand gui
1186 }
1187 if {$subcommand eq {gui} && [llength $argv] > 0} {
1188         set subcommand [lindex $argv 0]
1189         set argv [lrange $argv 1 end]
1190 }
1191
1192 enable_option multicommit
1193 enable_option branch
1194 enable_option transport
1195 disable_option bare
1196
1197 switch -- $subcommand {
1198 browser -
1199 blame {
1200         enable_option bare
1201
1202         disable_option multicommit
1203         disable_option branch
1204         disable_option transport
1205 }
1206 citool {
1207         enable_option singlecommit
1208         enable_option retcode
1209
1210         disable_option multicommit
1211         disable_option branch
1212         disable_option transport
1213
1214         while {[llength $argv] > 0} {
1215                 set a [lindex $argv 0]
1216                 switch -- $a {
1217                 --amend {
1218                         enable_option initialamend
1219                 }
1220                 --nocommit {
1221                         enable_option nocommit
1222                         enable_option nocommitmsg
1223                 }
1224                 --commitmsg {
1225                         disable_option nocommitmsg
1226                 }
1227                 default {
1228                         break
1229                 }
1230                 }
1231
1232                 set argv [lrange $argv 1 end]
1233         }
1234 }
1235 }
1236
1237 ######################################################################
1238 ##
1239 ## execution environment
1240
1241 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1242
1243 # Suggest our implementation of askpass, if none is set
1244 if {![info exists env(SSH_ASKPASS)]} {
1245         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1246 }
1247
1248 ######################################################################
1249 ##
1250 ## repository setup
1251
1252 set picked 0
1253 if {[catch {
1254                 set _gitdir $env(GIT_DIR)
1255                 set _prefix {}
1256                 }]
1257         && [catch {
1258                 # beware that from the .git dir this sets _gitdir to .
1259                 # and _prefix to the empty string
1260                 set _gitdir [git rev-parse --git-dir]
1261                 set _prefix [git rev-parse --show-prefix]
1262         } err]} {
1263         load_config 1
1264         apply_config
1265         choose_repository::pick
1266         set picked 1
1267 }
1268
1269 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1270 # run from the .git dir itself) lest the routines to find the worktree
1271 # get confused
1272 if {$_gitdir eq "."} {
1273         set _gitdir [pwd]
1274 }
1275
1276 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1277         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1278 }
1279 if {![file isdirectory $_gitdir]} {
1280         catch {wm withdraw .}
1281         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1282         exit 1
1283 }
1284 # _gitdir exists, so try loading the config
1285 load_config 0
1286 apply_config
1287
1288 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1289 if {[package vsatisfies $_git_version 1.7.0-]} {
1290         if { [is_Cygwin] } {
1291                 catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1292         } else {
1293                 set _gitworktree [git rev-parse --show-toplevel]
1294         }
1295 } else {
1296         # try to set work tree from environment, core.worktree or use
1297         # cdup to obtain a relative path to the top of the worktree. If
1298         # run from the top, the ./ prefix ensures normalize expands pwd.
1299         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1300                 set _gitworktree [get_config core.worktree]
1301                 if {$_gitworktree eq ""} {
1302                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1303                 }
1304         }
1305 }
1306
1307 if {$_prefix ne {}} {
1308         if {$_gitworktree eq {}} {
1309                 regsub -all {[^/]+/} $_prefix ../ cdup
1310         } else {
1311                 set cdup $_gitworktree
1312         }
1313         if {[catch {cd $cdup} err]} {
1314                 catch {wm withdraw .}
1315                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1316                 exit 1
1317         }
1318         set _gitworktree [pwd]
1319         unset cdup
1320 } elseif {![is_enabled bare]} {
1321         if {[is_bare]} {
1322                 catch {wm withdraw .}
1323                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1324                 exit 1
1325         }
1326         if {$_gitworktree eq {}} {
1327                 set _gitworktree [file dirname $_gitdir]
1328         }
1329         if {[catch {cd $_gitworktree} err]} {
1330                 catch {wm withdraw .}
1331                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1332                 exit 1
1333         }
1334         set _gitworktree [pwd]
1335 }
1336 set _reponame [file split [file normalize $_gitdir]]
1337 if {[lindex $_reponame end] eq {.git}} {
1338         set _reponame [lindex $_reponame end-1]
1339 } else {
1340         set _reponame [lindex $_reponame end]
1341 }
1342
1343 set env(GIT_DIR) $_gitdir
1344 set env(GIT_WORK_TREE) $_gitworktree
1345
1346 ######################################################################
1347 ##
1348 ## global init
1349
1350 set current_diff_path {}
1351 set current_diff_side {}
1352 set diff_actions [list]
1353
1354 set HEAD {}
1355 set PARENT {}
1356 set MERGE_HEAD [list]
1357 set commit_type {}
1358 set empty_tree {}
1359 set current_branch {}
1360 set is_detached 0
1361 set current_diff_path {}
1362 set is_3way_diff 0
1363 set is_submodule_diff 0
1364 set is_conflict_diff 0
1365 set selected_commit_type new
1366 set diff_empty_count 0
1367
1368 set nullid "0000000000000000000000000000000000000000"
1369 set nullid2 "0000000000000000000000000000000000000001"
1370
1371 ######################################################################
1372 ##
1373 ## task management
1374
1375 set rescan_active 0
1376 set diff_active 0
1377 set last_clicked {}
1378
1379 set disable_on_lock [list]
1380 set index_lock_type none
1381
1382 proc lock_index {type} {
1383         global index_lock_type disable_on_lock
1384
1385         if {$index_lock_type eq {none}} {
1386                 set index_lock_type $type
1387                 foreach w $disable_on_lock {
1388                         uplevel #0 $w disabled
1389                 }
1390                 return 1
1391         } elseif {$index_lock_type eq "begin-$type"} {
1392                 set index_lock_type $type
1393                 return 1
1394         }
1395         return 0
1396 }
1397
1398 proc unlock_index {} {
1399         global index_lock_type disable_on_lock
1400
1401         set index_lock_type none
1402         foreach w $disable_on_lock {
1403                 uplevel #0 $w normal
1404         }
1405 }
1406
1407 ######################################################################
1408 ##
1409 ## status
1410
1411 proc repository_state {ctvar hdvar mhvar} {
1412         global current_branch
1413         upvar $ctvar ct $hdvar hd $mhvar mh
1414
1415         set mh [list]
1416
1417         load_current_branch
1418         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1419                 set hd {}
1420                 set ct initial
1421                 return
1422         }
1423
1424         set merge_head [gitdir MERGE_HEAD]
1425         if {[file exists $merge_head]} {
1426                 set ct merge
1427                 set fd_mh [open $merge_head r]
1428                 while {[gets $fd_mh line] >= 0} {
1429                         lappend mh $line
1430                 }
1431                 close $fd_mh
1432                 return
1433         }
1434
1435         set ct normal
1436 }
1437
1438 proc PARENT {} {
1439         global PARENT empty_tree
1440
1441         set p [lindex $PARENT 0]
1442         if {$p ne {}} {
1443                 return $p
1444         }
1445         if {$empty_tree eq {}} {
1446                 set empty_tree [git mktree << {}]
1447         }
1448         return $empty_tree
1449 }
1450
1451 proc force_amend {} {
1452         global selected_commit_type
1453         global HEAD PARENT MERGE_HEAD commit_type
1454
1455         repository_state newType newHEAD newMERGE_HEAD
1456         set HEAD $newHEAD
1457         set PARENT $newHEAD
1458         set MERGE_HEAD $newMERGE_HEAD
1459         set commit_type $newType
1460
1461         set selected_commit_type amend
1462         do_select_commit_type
1463 }
1464
1465 proc rescan {after {honor_trustmtime 1}} {
1466         global HEAD PARENT MERGE_HEAD commit_type
1467         global ui_index ui_workdir ui_comm
1468         global rescan_active file_states
1469         global repo_config
1470
1471         if {$rescan_active > 0 || ![lock_index read]} return
1472
1473         repository_state newType newHEAD newMERGE_HEAD
1474         if {[string match amend* $commit_type]
1475                 && $newType eq {normal}
1476                 && $newHEAD eq $HEAD} {
1477         } else {
1478                 set HEAD $newHEAD
1479                 set PARENT $newHEAD
1480                 set MERGE_HEAD $newMERGE_HEAD
1481                 set commit_type $newType
1482         }
1483
1484         array unset file_states
1485
1486         if {!$::GITGUI_BCK_exists &&
1487                 (![$ui_comm edit modified]
1488                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1489                 if {[string match amend* $commit_type]} {
1490                 } elseif {[load_message GITGUI_MSG utf-8]} {
1491                 } elseif {[run_prepare_commit_msg_hook]} {
1492                 } elseif {[load_message MERGE_MSG]} {
1493                 } elseif {[load_message SQUASH_MSG]} {
1494                 }
1495                 $ui_comm edit reset
1496                 $ui_comm edit modified false
1497         }
1498
1499         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1500                 rescan_stage2 {} $after
1501         } else {
1502                 set rescan_active 1
1503                 ui_status [mc "Refreshing file status..."]
1504                 set fd_rf [git_read update-index \
1505                         -q \
1506                         --unmerged \
1507                         --ignore-missing \
1508                         --refresh \
1509                         ]
1510                 fconfigure $fd_rf -blocking 0 -translation binary
1511                 fileevent $fd_rf readable \
1512                         [list rescan_stage2 $fd_rf $after]
1513         }
1514 }
1515
1516 if {[is_Cygwin]} {
1517         set is_git_info_exclude {}
1518         proc have_info_exclude {} {
1519                 global is_git_info_exclude
1520
1521                 if {$is_git_info_exclude eq {}} {
1522                         if {[catch {exec test -f [gitdir info exclude]}]} {
1523                                 set is_git_info_exclude 0
1524                         } else {
1525                                 set is_git_info_exclude 1
1526                         }
1527                 }
1528                 return $is_git_info_exclude
1529         }
1530 } else {
1531         proc have_info_exclude {} {
1532                 return [file readable [gitdir info exclude]]
1533         }
1534 }
1535
1536 proc rescan_stage2 {fd after} {
1537         global rescan_active buf_rdi buf_rdf buf_rlo
1538
1539         if {$fd ne {}} {
1540                 read $fd
1541                 if {![eof $fd]} return
1542                 close $fd
1543         }
1544
1545         if {[package vsatisfies $::_git_version 1.6.3-]} {
1546                 set ls_others [list --exclude-standard]
1547         } else {
1548                 set ls_others [list --exclude-per-directory=.gitignore]
1549                 if {[have_info_exclude]} {
1550                         lappend ls_others "--exclude-from=[gitdir info exclude]"
1551                 }
1552                 set user_exclude [get_config core.excludesfile]
1553                 if {$user_exclude ne {} && [file readable $user_exclude]} {
1554                         lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1555                 }
1556         }
1557
1558         set buf_rdi {}
1559         set buf_rdf {}
1560         set buf_rlo {}
1561
1562         set rescan_active 2
1563         ui_status [mc "Scanning for modified files ..."]
1564         set fd_di [git_read diff-index --cached -z [PARENT]]
1565         set fd_df [git_read diff-files -z]
1566
1567         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1568         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1569
1570         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1571         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1572
1573         if {[is_config_true gui.displayuntracked]} {
1574                 set fd_lo [eval git_read ls-files --others -z $ls_others]
1575                 fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1576                 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1577                 incr rescan_active
1578         }
1579 }
1580
1581 proc load_message {file {encoding {}}} {
1582         global ui_comm
1583
1584         set f [gitdir $file]
1585         if {[file isfile $f]} {
1586                 if {[catch {set fd [open $f r]}]} {
1587                         return 0
1588                 }
1589                 fconfigure $fd -eofchar {}
1590                 if {$encoding ne {}} {
1591                         fconfigure $fd -encoding $encoding
1592                 }
1593                 set content [string trim [read $fd]]
1594                 close $fd
1595                 regsub -all -line {[ \r\t]+$} $content {} content
1596                 $ui_comm delete 0.0 end
1597                 $ui_comm insert end $content
1598                 return 1
1599         }
1600         return 0
1601 }
1602
1603 proc run_prepare_commit_msg_hook {} {
1604         global pch_error
1605
1606         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1607         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1608         # empty file but existent file.
1609
1610         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1611
1612         if {[file isfile [gitdir MERGE_MSG]]} {
1613                 set pcm_source "merge"
1614                 set fd_mm [open [gitdir MERGE_MSG] r]
1615                 puts -nonewline $fd_pcm [read $fd_mm]
1616                 close $fd_mm
1617         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1618                 set pcm_source "squash"
1619                 set fd_sm [open [gitdir SQUASH_MSG] r]
1620                 puts -nonewline $fd_pcm [read $fd_sm]
1621                 close $fd_sm
1622         } else {
1623                 set pcm_source ""
1624         }
1625
1626         close $fd_pcm
1627
1628         set fd_ph [githook_read prepare-commit-msg \
1629                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1630         if {$fd_ph eq {}} {
1631                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1632                 return 0;
1633         }
1634
1635         ui_status [mc "Calling prepare-commit-msg hook..."]
1636         set pch_error {}
1637
1638         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1639         fileevent $fd_ph readable \
1640                 [list prepare_commit_msg_hook_wait $fd_ph]
1641
1642         return 1;
1643 }
1644
1645 proc prepare_commit_msg_hook_wait {fd_ph} {
1646         global pch_error
1647
1648         append pch_error [read $fd_ph]
1649         fconfigure $fd_ph -blocking 1
1650         if {[eof $fd_ph]} {
1651                 if {[catch {close $fd_ph}]} {
1652                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1653                         hook_failed_popup prepare-commit-msg $pch_error
1654                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1655                         exit 1
1656                 } else {
1657                         load_message PREPARE_COMMIT_MSG
1658                 }
1659                 set pch_error {}
1660                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1661                 return
1662         }
1663         fconfigure $fd_ph -blocking 0
1664         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1665 }
1666
1667 proc read_diff_index {fd after} {
1668         global buf_rdi
1669
1670         append buf_rdi [read $fd]
1671         set c 0
1672         set n [string length $buf_rdi]
1673         while {$c < $n} {
1674                 set z1 [string first "\0" $buf_rdi $c]
1675                 if {$z1 == -1} break
1676                 incr z1
1677                 set z2 [string first "\0" $buf_rdi $z1]
1678                 if {$z2 == -1} break
1679
1680                 incr c
1681                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1682                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1683                 merge_state \
1684                         [encoding convertfrom utf-8 $p] \
1685                         [lindex $i 4]? \
1686                         [list [lindex $i 0] [lindex $i 2]] \
1687                         [list]
1688                 set c $z2
1689                 incr c
1690         }
1691         if {$c < $n} {
1692                 set buf_rdi [string range $buf_rdi $c end]
1693         } else {
1694                 set buf_rdi {}
1695         }
1696
1697         rescan_done $fd buf_rdi $after
1698 }
1699
1700 proc read_diff_files {fd after} {
1701         global buf_rdf
1702
1703         append buf_rdf [read $fd]
1704         set c 0
1705         set n [string length $buf_rdf]
1706         while {$c < $n} {
1707                 set z1 [string first "\0" $buf_rdf $c]
1708                 if {$z1 == -1} break
1709                 incr z1
1710                 set z2 [string first "\0" $buf_rdf $z1]
1711                 if {$z2 == -1} break
1712
1713                 incr c
1714                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1715                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1716                 merge_state \
1717                         [encoding convertfrom utf-8 $p] \
1718                         ?[lindex $i 4] \
1719                         [list] \
1720                         [list [lindex $i 0] [lindex $i 2]]
1721                 set c $z2
1722                 incr c
1723         }
1724         if {$c < $n} {
1725                 set buf_rdf [string range $buf_rdf $c end]
1726         } else {
1727                 set buf_rdf {}
1728         }
1729
1730         rescan_done $fd buf_rdf $after
1731 }
1732
1733 proc read_ls_others {fd after} {
1734         global buf_rlo
1735
1736         append buf_rlo [read $fd]
1737         set pck [split $buf_rlo "\0"]
1738         set buf_rlo [lindex $pck end]
1739         foreach p [lrange $pck 0 end-1] {
1740                 set p [encoding convertfrom utf-8 $p]
1741                 if {[string index $p end] eq {/}} {
1742                         set p [string range $p 0 end-1]
1743                 }
1744                 merge_state $p ?O
1745         }
1746         rescan_done $fd buf_rlo $after
1747 }
1748
1749 proc rescan_done {fd buf after} {
1750         global rescan_active current_diff_path
1751         global file_states repo_config
1752         upvar $buf to_clear
1753
1754         if {![eof $fd]} return
1755         set to_clear {}
1756         close $fd
1757         if {[incr rescan_active -1] > 0} return
1758
1759         prune_selection
1760         unlock_index
1761         display_all_files
1762         if {$current_diff_path ne {}} { reshow_diff $after }
1763         if {$current_diff_path eq {}} { select_first_diff $after }
1764 }
1765
1766 proc prune_selection {} {
1767         global file_states selected_paths
1768
1769         foreach path [array names selected_paths] {
1770                 if {[catch {set still_here $file_states($path)}]} {
1771                         unset selected_paths($path)
1772                 }
1773         }
1774 }
1775
1776 ######################################################################
1777 ##
1778 ## ui helpers
1779
1780 proc mapicon {w state path} {
1781         global all_icons
1782
1783         if {[catch {set r $all_icons($state$w)}]} {
1784                 puts "error: no icon for $w state={$state} $path"
1785                 return file_plain
1786         }
1787         return $r
1788 }
1789
1790 proc mapdesc {state path} {
1791         global all_descs
1792
1793         if {[catch {set r $all_descs($state)}]} {
1794                 puts "error: no desc for state={$state} $path"
1795                 return $state
1796         }
1797         return $r
1798 }
1799
1800 proc ui_status {msg} {
1801         global main_status
1802         if {[info exists main_status]} {
1803                 $main_status show $msg
1804         }
1805 }
1806
1807 proc ui_ready {{test {}}} {
1808         global main_status
1809         if {[info exists main_status]} {
1810                 $main_status show [mc "Ready."] $test
1811         }
1812 }
1813
1814 proc escape_path {path} {
1815         regsub -all {\\} $path "\\\\" path
1816         regsub -all "\n" $path "\\n" path
1817         return $path
1818 }
1819
1820 proc short_path {path} {
1821         return [escape_path [lindex [file split $path] end]]
1822 }
1823
1824 set next_icon_id 0
1825 set null_sha1 [string repeat 0 40]
1826
1827 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1828         global file_states next_icon_id null_sha1
1829
1830         set s0 [string index $new_state 0]
1831         set s1 [string index $new_state 1]
1832
1833         if {[catch {set info $file_states($path)}]} {
1834                 set state __
1835                 set icon n[incr next_icon_id]
1836         } else {
1837                 set state [lindex $info 0]
1838                 set icon [lindex $info 1]
1839                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1840                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1841         }
1842
1843         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1844         elseif {$s0 eq {_}} {set s0 _}
1845
1846         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1847         elseif {$s1 eq {_}} {set s1 _}
1848
1849         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1850                 set head_info [list 0 $null_sha1]
1851         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1852                 && $head_info eq {}} {
1853                 set head_info $index_info
1854         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1855                 set index_info $head_info
1856                 set head_info {}
1857         }
1858
1859         set file_states($path) [list $s0$s1 $icon \
1860                 $head_info $index_info \
1861                 ]
1862         return $state
1863 }
1864
1865 proc display_file_helper {w path icon_name old_m new_m} {
1866         global file_lists
1867
1868         if {$new_m eq {_}} {
1869                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1870                 if {$lno >= 0} {
1871                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1872                         incr lno
1873                         $w conf -state normal
1874                         $w delete $lno.0 [expr {$lno + 1}].0
1875                         $w conf -state disabled
1876                 }
1877         } elseif {$old_m eq {_} && $new_m ne {_}} {
1878                 lappend file_lists($w) $path
1879                 set file_lists($w) [lsort -unique $file_lists($w)]
1880                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1881                 incr lno
1882                 $w conf -state normal
1883                 $w image create $lno.0 \
1884                         -align center -padx 5 -pady 1 \
1885                         -name $icon_name \
1886                         -image [mapicon $w $new_m $path]
1887                 $w insert $lno.1 "[escape_path $path]\n"
1888                 $w conf -state disabled
1889         } elseif {$old_m ne $new_m} {
1890                 $w conf -state normal
1891                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1892                 $w conf -state disabled
1893         }
1894 }
1895
1896 proc display_file {path state} {
1897         global file_states selected_paths
1898         global ui_index ui_workdir
1899
1900         set old_m [merge_state $path $state]
1901         set s $file_states($path)
1902         set new_m [lindex $s 0]
1903         set icon_name [lindex $s 1]
1904
1905         set o [string index $old_m 0]
1906         set n [string index $new_m 0]
1907         if {$o eq {U}} {
1908                 set o _
1909         }
1910         if {$n eq {U}} {
1911                 set n _
1912         }
1913         display_file_helper     $ui_index $path $icon_name $o $n
1914
1915         if {[string index $old_m 0] eq {U}} {
1916                 set o U
1917         } else {
1918                 set o [string index $old_m 1]
1919         }
1920         if {[string index $new_m 0] eq {U}} {
1921                 set n U
1922         } else {
1923                 set n [string index $new_m 1]
1924         }
1925         display_file_helper     $ui_workdir $path $icon_name $o $n
1926
1927         if {$new_m eq {__}} {
1928                 unset file_states($path)
1929                 catch {unset selected_paths($path)}
1930         }
1931 }
1932
1933 proc display_all_files_helper {w path icon_name m} {
1934         global file_lists
1935
1936         lappend file_lists($w) $path
1937         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1938         $w image create end \
1939                 -align center -padx 5 -pady 1 \
1940                 -name $icon_name \
1941                 -image [mapicon $w $m $path]
1942         $w insert end "[escape_path $path]\n"
1943 }
1944
1945 set files_warning 0
1946 proc display_all_files {} {
1947         global ui_index ui_workdir
1948         global file_states file_lists
1949         global last_clicked
1950         global files_warning
1951
1952         $ui_index conf -state normal
1953         $ui_workdir conf -state normal
1954
1955         $ui_index delete 0.0 end
1956         $ui_workdir delete 0.0 end
1957         set last_clicked {}
1958
1959         set file_lists($ui_index) [list]
1960         set file_lists($ui_workdir) [list]
1961
1962         set to_display [lsort [array names file_states]]
1963         set display_limit [get_config gui.maxfilesdisplayed]
1964         if {[llength $to_display] > $display_limit} {
1965                 if {!$files_warning} {
1966                         # do not repeatedly warn:
1967                         set files_warning 1
1968                         info_popup [mc "Displaying only %s of %s files." \
1969                                 $display_limit [llength $to_display]]
1970                 }
1971                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1972         }
1973         foreach path $to_display {
1974                 set s $file_states($path)
1975                 set m [lindex $s 0]
1976                 set icon_name [lindex $s 1]
1977
1978                 set s [string index $m 0]
1979                 if {$s ne {U} && $s ne {_}} {
1980                         display_all_files_helper $ui_index $path \
1981                                 $icon_name $s
1982                 }
1983
1984                 if {[string index $m 0] eq {U}} {
1985                         set s U
1986                 } else {
1987                         set s [string index $m 1]
1988                 }
1989                 if {$s ne {_}} {
1990                         display_all_files_helper $ui_workdir $path \
1991                                 $icon_name $s
1992                 }
1993         }
1994
1995         $ui_index conf -state disabled
1996         $ui_workdir conf -state disabled
1997 }
1998
1999 ######################################################################
2000 ##
2001 ## icons
2002
2003 set filemask {
2004 #define mask_width 14
2005 #define mask_height 15
2006 static unsigned char mask_bits[] = {
2007    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2008    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2009    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2010 }
2011
2012 image create bitmap file_plain -background white -foreground black -data {
2013 #define plain_width 14
2014 #define plain_height 15
2015 static unsigned char plain_bits[] = {
2016    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2017    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2018    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2019 } -maskdata $filemask
2020
2021 image create bitmap file_mod -background white -foreground blue -data {
2022 #define mod_width 14
2023 #define mod_height 15
2024 static unsigned char mod_bits[] = {
2025    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2026    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2027    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2028 } -maskdata $filemask
2029
2030 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2031 #define file_fulltick_width 14
2032 #define file_fulltick_height 15
2033 static unsigned char file_fulltick_bits[] = {
2034    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2035    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2036    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2037 } -maskdata $filemask
2038
2039 image create bitmap file_question -background white -foreground black -data {
2040 #define file_question_width 14
2041 #define file_question_height 15
2042 static unsigned char file_question_bits[] = {
2043    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2044    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2045    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2046 } -maskdata $filemask
2047
2048 image create bitmap file_removed -background white -foreground red -data {
2049 #define file_removed_width 14
2050 #define file_removed_height 15
2051 static unsigned char file_removed_bits[] = {
2052    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2053    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2054    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2055 } -maskdata $filemask
2056
2057 image create bitmap file_merge -background white -foreground blue -data {
2058 #define file_merge_width 14
2059 #define file_merge_height 15
2060 static unsigned char file_merge_bits[] = {
2061    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2062    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2063    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2064 } -maskdata $filemask
2065
2066 image create bitmap file_statechange -background white -foreground green -data {
2067 #define file_statechange_width 14
2068 #define file_statechange_height 15
2069 static unsigned char file_statechange_bits[] = {
2070    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2071    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2072    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2073 } -maskdata $filemask
2074
2075 set ui_index .vpane.files.index.list
2076 set ui_workdir .vpane.files.workdir.list
2077
2078 set all_icons(_$ui_index)   file_plain
2079 set all_icons(A$ui_index)   file_plain
2080 set all_icons(M$ui_index)   file_fulltick
2081 set all_icons(D$ui_index)   file_removed
2082 set all_icons(U$ui_index)   file_merge
2083 set all_icons(T$ui_index)   file_statechange
2084
2085 set all_icons(_$ui_workdir) file_plain
2086 set all_icons(M$ui_workdir) file_mod
2087 set all_icons(D$ui_workdir) file_question
2088 set all_icons(U$ui_workdir) file_merge
2089 set all_icons(O$ui_workdir) file_plain
2090 set all_icons(T$ui_workdir) file_statechange
2091
2092 set max_status_desc 0
2093 foreach i {
2094                 {__ {mc "Unmodified"}}
2095
2096                 {_M {mc "Modified, not staged"}}
2097                 {M_ {mc "Staged for commit"}}
2098                 {MM {mc "Portions staged for commit"}}
2099                 {MD {mc "Staged for commit, missing"}}
2100
2101                 {_T {mc "File type changed, not staged"}}
2102                 {MT {mc "File type changed, old type staged for commit"}}
2103                 {AT {mc "File type changed, old type staged for commit"}}
2104                 {T_ {mc "File type changed, staged"}}
2105                 {TM {mc "File type change staged, modification not staged"}}
2106                 {TD {mc "File type change staged, file missing"}}
2107
2108                 {_O {mc "Untracked, not staged"}}
2109                 {A_ {mc "Staged for commit"}}
2110                 {AM {mc "Portions staged for commit"}}
2111                 {AD {mc "Staged for commit, missing"}}
2112
2113                 {_D {mc "Missing"}}
2114                 {D_ {mc "Staged for removal"}}
2115                 {DO {mc "Staged for removal, still present"}}
2116
2117                 {_U {mc "Requires merge resolution"}}
2118                 {U_ {mc "Requires merge resolution"}}
2119                 {UU {mc "Requires merge resolution"}}
2120                 {UM {mc "Requires merge resolution"}}
2121                 {UD {mc "Requires merge resolution"}}
2122                 {UT {mc "Requires merge resolution"}}
2123         } {
2124         set text [eval [lindex $i 1]]
2125         if {$max_status_desc < [string length $text]} {
2126                 set max_status_desc [string length $text]
2127         }
2128         set all_descs([lindex $i 0]) $text
2129 }
2130 unset i
2131
2132 ######################################################################
2133 ##
2134 ## util
2135
2136 proc scrollbar2many {list mode args} {
2137         foreach w $list {eval $w $mode $args}
2138 }
2139
2140 proc many2scrollbar {list mode sb top bottom} {
2141         $sb set $top $bottom
2142         foreach w $list {$w $mode moveto $top}
2143 }
2144
2145 proc incr_font_size {font {amt 1}} {
2146         set sz [font configure $font -size]
2147         incr sz $amt
2148         font configure $font -size $sz
2149         font configure ${font}bold -size $sz
2150         font configure ${font}italic -size $sz
2151 }
2152
2153 ######################################################################
2154 ##
2155 ## ui commands
2156
2157 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2158
2159 proc do_gitk {revs {is_submodule false}} {
2160         global current_diff_path file_states current_diff_side ui_index
2161         global _gitdir _gitworktree
2162
2163         # -- Always start gitk through whatever we were loaded with.  This
2164         #    lets us bypass using shell process on Windows systems.
2165         #
2166         set exe [_which gitk -script]
2167         set cmd [list [info nameofexecutable] $exe]
2168         if {$exe eq {}} {
2169                 error_popup [mc "Couldn't find gitk in PATH"]
2170         } else {
2171                 global env
2172
2173                 set pwd [pwd]
2174
2175                 if {!$is_submodule} {
2176                         if {![is_bare]} {
2177                                 cd $_gitworktree
2178                         }
2179                 } else {
2180                         cd $current_diff_path
2181                         if {$revs eq {--}} {
2182                                 set s $file_states($current_diff_path)
2183                                 set old_sha1 {}
2184                                 set new_sha1 {}
2185                                 switch -glob -- [lindex $s 0] {
2186                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2187                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2188                                 MM {
2189                                         if {$current_diff_side eq $ui_index} {
2190                                                 set old_sha1 [lindex [lindex $s 2] 1]
2191                                                 set new_sha1 [lindex [lindex $s 3] 1]
2192                                         } else {
2193                                                 set old_sha1 [lindex [lindex $s 3] 1]
2194                                         }
2195                                 }
2196                                 }
2197                                 set revs $old_sha1...$new_sha1
2198                         }
2199                         # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2200                         # we've been using for the main repository, so unset them.
2201                         # TODO we could make life easier (start up faster?) for gitk
2202                         # by setting these to the appropriate values to allow gitk
2203                         # to skip the heuristics to find their proper value
2204                         unset env(GIT_DIR)
2205                         unset env(GIT_WORK_TREE)
2206                 }
2207                 eval exec $cmd $revs "--" "--" &
2208
2209                 set env(GIT_DIR) $_gitdir
2210                 set env(GIT_WORK_TREE) $_gitworktree
2211                 cd $pwd
2212
2213                 ui_status $::starting_gitk_msg
2214                 after 10000 {
2215                         ui_ready $starting_gitk_msg
2216                 }
2217         }
2218 }
2219
2220 proc do_git_gui {} {
2221         global current_diff_path
2222
2223         # -- Always start git gui through whatever we were loaded with.  This
2224         #    lets us bypass using shell process on Windows systems.
2225         #
2226         set exe [list [_which git]]
2227         if {$exe eq {}} {
2228                 error_popup [mc "Couldn't find git gui in PATH"]
2229         } else {
2230                 global env
2231                 global _gitdir _gitworktree
2232
2233                 # see note in do_gitk about unsetting these vars when
2234                 # running tools in a submodule
2235                 unset env(GIT_DIR)
2236                 unset env(GIT_WORK_TREE)
2237
2238                 set pwd [pwd]
2239                 cd $current_diff_path
2240
2241                 eval exec $exe gui &
2242
2243                 set env(GIT_DIR) $_gitdir
2244                 set env(GIT_WORK_TREE) $_gitworktree
2245                 cd $pwd
2246
2247                 ui_status $::starting_gitk_msg
2248                 after 10000 {
2249                         ui_ready $starting_gitk_msg
2250                 }
2251         }
2252 }
2253
2254 proc do_explore {} {
2255         global _gitworktree
2256         set explorer {}
2257         if {[is_Cygwin] || [is_Windows]} {
2258                 set explorer "explorer.exe"
2259         } elseif {[is_MacOSX]} {
2260                 set explorer "open"
2261         } else {
2262                 # freedesktop.org-conforming system is our best shot
2263                 set explorer "xdg-open"
2264         }
2265         eval exec $explorer [list [file nativename $_gitworktree]] &
2266 }
2267
2268 set is_quitting 0
2269 set ret_code    1
2270
2271 proc terminate_me {win} {
2272         global ret_code
2273         if {$win ne {.}} return
2274         exit $ret_code
2275 }
2276
2277 proc do_quit {{rc {1}}} {
2278         global ui_comm is_quitting repo_config commit_type
2279         global GITGUI_BCK_exists GITGUI_BCK_i
2280         global ui_comm_spell
2281         global ret_code use_ttk
2282
2283         if {$is_quitting} return
2284         set is_quitting 1
2285
2286         if {[winfo exists $ui_comm]} {
2287                 # -- Stash our current commit buffer.
2288                 #
2289                 set save [gitdir GITGUI_MSG]
2290                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2291                         file rename -force [gitdir GITGUI_BCK] $save
2292                         set GITGUI_BCK_exists 0
2293                 } else {
2294                         set msg [string trim [$ui_comm get 0.0 end]]
2295                         regsub -all -line {[ \r\t]+$} $msg {} msg
2296                         if {(![string match amend* $commit_type]
2297                                 || [$ui_comm edit modified])
2298                                 && $msg ne {}} {
2299                                 catch {
2300                                         set fd [open $save w]
2301                                         fconfigure $fd -encoding utf-8
2302                                         puts -nonewline $fd $msg
2303                                         close $fd
2304                                 }
2305                         } else {
2306                                 catch {file delete $save}
2307                         }
2308                 }
2309
2310                 # -- Cancel our spellchecker if its running.
2311                 #
2312                 if {[info exists ui_comm_spell]} {
2313                         $ui_comm_spell stop
2314                 }
2315
2316                 # -- Remove our editor backup, its not needed.
2317                 #
2318                 after cancel $GITGUI_BCK_i
2319                 if {$GITGUI_BCK_exists} {
2320                         catch {file delete [gitdir GITGUI_BCK]}
2321                 }
2322
2323                 # -- Stash our current window geometry into this repository.
2324                 #
2325                 set cfg_wmstate [wm state .]
2326                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2327                         set rc_wmstate {}
2328                 }
2329                 if {$cfg_wmstate ne $rc_wmstate} {
2330                         catch {git config gui.wmstate $cfg_wmstate}
2331                 }
2332                 if {$cfg_wmstate eq {zoomed}} {
2333                         # on Windows wm geometry will lie about window
2334                         # position (but not size) when window is zoomed
2335                         # restore the window before querying wm geometry
2336                         wm state . normal
2337                 }
2338                 set cfg_geometry [list]
2339                 lappend cfg_geometry [wm geometry .]
2340                 if {$use_ttk} {
2341                         lappend cfg_geometry [.vpane sashpos 0]
2342                         lappend cfg_geometry [.vpane.files sashpos 0]
2343                 } else {
2344                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2345                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2346                 }
2347                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2348                         set rc_geometry {}
2349                 }
2350                 if {$cfg_geometry ne $rc_geometry} {
2351                         catch {git config gui.geometry $cfg_geometry}
2352                 }
2353         }
2354
2355         set ret_code $rc
2356
2357         # Briefly enable send again, working around Tk bug
2358         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2359         tk appname [appname]
2360
2361         destroy .
2362 }
2363
2364 proc do_rescan {} {
2365         rescan ui_ready
2366 }
2367
2368 proc ui_do_rescan {} {
2369         rescan {force_first_diff ui_ready}
2370 }
2371
2372 proc do_commit {} {
2373         commit_tree
2374 }
2375
2376 proc next_diff {{after {}}} {
2377         global next_diff_p next_diff_w next_diff_i
2378         show_diff $next_diff_p $next_diff_w {} {} $after
2379 }
2380
2381 proc find_anchor_pos {lst name} {
2382         set lid [lsearch -sorted -exact $lst $name]
2383
2384         if {$lid == -1} {
2385                 set lid 0
2386                 foreach lname $lst {
2387                         if {$lname >= $name} break
2388                         incr lid
2389                 }
2390         }
2391
2392         return $lid
2393 }
2394
2395 proc find_file_from {flist idx delta path mmask} {
2396         global file_states
2397
2398         set len [llength $flist]
2399         while {$idx >= 0 && $idx < $len} {
2400                 set name [lindex $flist $idx]
2401
2402                 if {$name ne $path && [info exists file_states($name)]} {
2403                         set state [lindex $file_states($name) 0]
2404
2405                         if {$mmask eq {} || [regexp $mmask $state]} {
2406                                 return $idx
2407                         }
2408                 }
2409
2410                 incr idx $delta
2411         }
2412
2413         return {}
2414 }
2415
2416 proc find_next_diff {w path {lno {}} {mmask {}}} {
2417         global next_diff_p next_diff_w next_diff_i
2418         global file_lists ui_index ui_workdir
2419
2420         set flist $file_lists($w)
2421         if {$lno eq {}} {
2422                 set lno [find_anchor_pos $flist $path]
2423         } else {
2424                 incr lno -1
2425         }
2426
2427         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2428                 if {$w eq $ui_index} {
2429                         set mmask "^$mmask"
2430                 } else {
2431                         set mmask "$mmask\$"
2432                 }
2433         }
2434
2435         set idx [find_file_from $flist $lno 1 $path $mmask]
2436         if {$idx eq {}} {
2437                 incr lno -1
2438                 set idx [find_file_from $flist $lno -1 $path $mmask]
2439         }
2440
2441         if {$idx ne {}} {
2442                 set next_diff_w $w
2443                 set next_diff_p [lindex $flist $idx]
2444                 set next_diff_i [expr {$idx+1}]
2445                 return 1
2446         } else {
2447                 return 0
2448         }
2449 }
2450
2451 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2452         global current_diff_path
2453
2454         if {$path ne $current_diff_path} {
2455                 return {}
2456         } elseif {[find_next_diff $w $path $lno $mmask]} {
2457                 return {next_diff;}
2458         } else {
2459                 return {reshow_diff;}
2460         }
2461 }
2462
2463 proc select_first_diff {after} {
2464         global ui_workdir
2465
2466         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2467             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2468                 next_diff $after
2469         } else {
2470                 uplevel #0 $after
2471         }
2472 }
2473
2474 proc force_first_diff {after} {
2475         global ui_workdir current_diff_path file_states
2476
2477         if {[info exists file_states($current_diff_path)]} {
2478                 set state [lindex $file_states($current_diff_path) 0]
2479         } else {
2480                 set state {OO}
2481         }
2482
2483         set reselect 0
2484         if {[string first {U} $state] >= 0} {
2485                 # Already a conflict, do nothing
2486         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2487                 set reselect 1
2488         } elseif {[string index $state 1] ne {O}} {
2489                 # Already a diff & no conflicts, do nothing
2490         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2491                 set reselect 1
2492         }
2493
2494         if {$reselect} {
2495                 next_diff $after
2496         } else {
2497                 uplevel #0 $after
2498         }
2499 }
2500
2501 proc toggle_or_diff {w x y} {
2502         global file_states file_lists current_diff_path ui_index ui_workdir
2503         global last_clicked selected_paths
2504
2505         set pos [split [$w index @$x,$y] .]
2506         set lno [lindex $pos 0]
2507         set col [lindex $pos 1]
2508         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2509         if {$path eq {}} {
2510                 set last_clicked {}
2511                 return
2512         }
2513
2514         set last_clicked [list $w $lno]
2515         array unset selected_paths
2516         $ui_index tag remove in_sel 0.0 end
2517         $ui_workdir tag remove in_sel 0.0 end
2518
2519         # Determine the state of the file
2520         if {[info exists file_states($path)]} {
2521                 set state [lindex $file_states($path) 0]
2522         } else {
2523                 set state {__}
2524         }
2525
2526         # Restage the file, or simply show the diff
2527         if {$col == 0 && $y > 1} {
2528                 # Conflicts need special handling
2529                 if {[string first {U} $state] >= 0} {
2530                         # $w must always be $ui_workdir, but...
2531                         if {$w ne $ui_workdir} { set lno {} }
2532                         merge_stage_workdir $path $lno
2533                         return
2534                 }
2535
2536                 if {[string index $state 1] eq {O}} {
2537                         set mmask {}
2538                 } else {
2539                         set mmask {[^O]}
2540                 }
2541
2542                 set after [next_diff_after_action $w $path $lno $mmask]
2543
2544                 if {$w eq $ui_index} {
2545                         update_indexinfo \
2546                                 "Unstaging [short_path $path] from commit" \
2547                                 [list $path] \
2548                                 [concat $after [list ui_ready]]
2549                 } elseif {$w eq $ui_workdir} {
2550                         update_index \
2551                                 "Adding [short_path $path]" \
2552                                 [list $path] \
2553                                 [concat $after [list ui_ready]]
2554                 }
2555         } else {
2556                 set selected_paths($path) 1
2557                 show_diff $path $w $lno
2558         }
2559 }
2560
2561 proc add_one_to_selection {w x y} {
2562         global file_lists last_clicked selected_paths
2563
2564         set lno [lindex [split [$w index @$x,$y] .] 0]
2565         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2566         if {$path eq {}} {
2567                 set last_clicked {}
2568                 return
2569         }
2570
2571         if {$last_clicked ne {}
2572                 && [lindex $last_clicked 0] ne $w} {
2573                 array unset selected_paths
2574                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2575         }
2576
2577         set last_clicked [list $w $lno]
2578         if {[catch {set in_sel $selected_paths($path)}]} {
2579                 set in_sel 0
2580         }
2581         if {$in_sel} {
2582                 unset selected_paths($path)
2583                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2584         } else {
2585                 set selected_paths($path) 1
2586                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2587         }
2588 }
2589
2590 proc add_range_to_selection {w x y} {
2591         global file_lists last_clicked selected_paths
2592
2593         if {[lindex $last_clicked 0] ne $w} {
2594                 toggle_or_diff $w $x $y
2595                 return
2596         }
2597
2598         set lno [lindex [split [$w index @$x,$y] .] 0]
2599         set lc [lindex $last_clicked 1]
2600         if {$lc < $lno} {
2601                 set begin $lc
2602                 set end $lno
2603         } else {
2604                 set begin $lno
2605                 set end $lc
2606         }
2607
2608         foreach path [lrange $file_lists($w) \
2609                 [expr {$begin - 1}] \
2610                 [expr {$end - 1}]] {
2611                 set selected_paths($path) 1
2612         }
2613         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2614 }
2615
2616 proc show_more_context {} {
2617         global repo_config
2618         if {$repo_config(gui.diffcontext) < 99} {
2619                 incr repo_config(gui.diffcontext)
2620                 reshow_diff
2621         }
2622 }
2623
2624 proc show_less_context {} {
2625         global repo_config
2626         if {$repo_config(gui.diffcontext) > 1} {
2627                 incr repo_config(gui.diffcontext) -1
2628                 reshow_diff
2629         }
2630 }
2631
2632 ######################################################################
2633 ##
2634 ## ui construction
2635
2636 set ui_comm {}
2637
2638 # -- Menu Bar
2639 #
2640 menu .mbar -tearoff 0
2641 if {[is_MacOSX]} {
2642         # -- Apple Menu (Mac OS X only)
2643         #
2644         .mbar add cascade -label Apple -menu .mbar.apple
2645         menu .mbar.apple
2646 }
2647 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2648 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2649 if {[is_enabled branch]} {
2650         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2651 }
2652 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2653         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2654 }
2655 if {[is_enabled transport]} {
2656         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2657         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2658 }
2659 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2660         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2661 }
2662
2663 # -- Repository Menu
2664 #
2665 menu .mbar.repository
2666
2667 if {![is_bare]} {
2668         .mbar.repository add command \
2669                 -label [mc "Explore Working Copy"] \
2670                 -command {do_explore}
2671 }
2672
2673 if {[is_Windows]} {
2674         .mbar.repository add command \
2675                 -label [mc "Git Bash"] \
2676                 -command {eval exec [auto_execok start] \
2677                                           [list "Git Bash" bash --login -l &]}
2678 }
2679
2680 if {[is_Windows] || ![is_bare]} {
2681         .mbar.repository add separator
2682 }
2683
2684 .mbar.repository add command \
2685         -label [mc "Browse Current Branch's Files"] \
2686         -command {browser::new $current_branch}
2687 set ui_browse_current [.mbar.repository index last]
2688 .mbar.repository add command \
2689         -label [mc "Browse Branch Files..."] \
2690         -command browser_open::dialog
2691 .mbar.repository add separator
2692
2693 .mbar.repository add command \
2694         -label [mc "Visualize Current Branch's History"] \
2695         -command {do_gitk $current_branch}
2696 set ui_visualize_current [.mbar.repository index last]
2697 .mbar.repository add command \
2698         -label [mc "Visualize All Branch History"] \
2699         -command {do_gitk --all}
2700 .mbar.repository add separator
2701
2702 proc current_branch_write {args} {
2703         global current_branch
2704         .mbar.repository entryconf $::ui_browse_current \
2705                 -label [mc "Browse %s's Files" $current_branch]
2706         .mbar.repository entryconf $::ui_visualize_current \
2707                 -label [mc "Visualize %s's History" $current_branch]
2708 }
2709 trace add variable current_branch write current_branch_write
2710
2711 if {[is_enabled multicommit]} {
2712         .mbar.repository add command -label [mc "Database Statistics"] \
2713                 -command do_stats
2714
2715         .mbar.repository add command -label [mc "Compress Database"] \
2716                 -command do_gc
2717
2718         .mbar.repository add command -label [mc "Verify Database"] \
2719                 -command do_fsck_objects
2720
2721         .mbar.repository add separator
2722
2723         if {[is_Cygwin]} {
2724                 .mbar.repository add command \
2725                         -label [mc "Create Desktop Icon"] \
2726                         -command do_cygwin_shortcut
2727         } elseif {[is_Windows]} {
2728                 .mbar.repository add command \
2729                         -label [mc "Create Desktop Icon"] \
2730                         -command do_windows_shortcut
2731         } elseif {[is_MacOSX]} {
2732                 .mbar.repository add command \
2733                         -label [mc "Create Desktop Icon"] \
2734                         -command do_macosx_app
2735         }
2736 }
2737
2738 if {[is_MacOSX]} {
2739         proc ::tk::mac::Quit {args} { do_quit }
2740 } else {
2741         .mbar.repository add command -label [mc Quit] \
2742                 -command do_quit \
2743                 -accelerator $M1T-Q
2744 }
2745
2746 # -- Edit Menu
2747 #
2748 menu .mbar.edit
2749 .mbar.edit add command -label [mc Undo] \
2750         -command {catch {[focus] edit undo}} \
2751         -accelerator $M1T-Z
2752 .mbar.edit add command -label [mc Redo] \
2753         -command {catch {[focus] edit redo}} \
2754         -accelerator $M1T-Y
2755 .mbar.edit add separator
2756 .mbar.edit add command -label [mc Cut] \
2757         -command {catch {tk_textCut [focus]}} \
2758         -accelerator $M1T-X
2759 .mbar.edit add command -label [mc Copy] \
2760         -command {catch {tk_textCopy [focus]}} \
2761         -accelerator $M1T-C
2762 .mbar.edit add command -label [mc Paste] \
2763         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2764         -accelerator $M1T-V
2765 .mbar.edit add command -label [mc Delete] \
2766         -command {catch {[focus] delete sel.first sel.last}} \
2767         -accelerator Del
2768 .mbar.edit add separator
2769 .mbar.edit add command -label [mc "Select All"] \
2770         -command {catch {[focus] tag add sel 0.0 end}} \
2771         -accelerator $M1T-A
2772
2773 # -- Branch Menu
2774 #
2775 if {[is_enabled branch]} {
2776         menu .mbar.branch
2777
2778         .mbar.branch add command -label [mc "Create..."] \
2779                 -command branch_create::dialog \
2780                 -accelerator $M1T-N
2781         lappend disable_on_lock [list .mbar.branch entryconf \
2782                 [.mbar.branch index last] -state]
2783
2784         .mbar.branch add command -label [mc "Checkout..."] \
2785                 -command branch_checkout::dialog \
2786                 -accelerator $M1T-O
2787         lappend disable_on_lock [list .mbar.branch entryconf \
2788                 [.mbar.branch index last] -state]
2789
2790         .mbar.branch add command -label [mc "Rename..."] \
2791                 -command branch_rename::dialog
2792         lappend disable_on_lock [list .mbar.branch entryconf \
2793                 [.mbar.branch index last] -state]
2794
2795         .mbar.branch add command -label [mc "Delete..."] \
2796                 -command branch_delete::dialog
2797         lappend disable_on_lock [list .mbar.branch entryconf \
2798                 [.mbar.branch index last] -state]
2799
2800         .mbar.branch add command -label [mc "Reset..."] \
2801                 -command merge::reset_hard
2802         lappend disable_on_lock [list .mbar.branch entryconf \
2803                 [.mbar.branch index last] -state]
2804 }
2805
2806 # -- Commit Menu
2807 #
2808 proc commit_btn_caption {} {
2809         if {[is_enabled nocommit]} {
2810                 return [mc "Done"]
2811         } else {
2812                 return [mc Commit@@verb]
2813         }
2814 }
2815
2816 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2817         menu .mbar.commit
2818
2819         if {![is_enabled nocommit]} {
2820                 .mbar.commit add radiobutton \
2821                         -label [mc "New Commit"] \
2822                         -command do_select_commit_type \
2823                         -variable selected_commit_type \
2824                         -value new
2825                 lappend disable_on_lock \
2826                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2827
2828                 .mbar.commit add radiobutton \
2829                         -label [mc "Amend Last Commit"] \
2830                         -command do_select_commit_type \
2831                         -variable selected_commit_type \
2832                         -value amend
2833                 lappend disable_on_lock \
2834                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2835
2836                 .mbar.commit add separator
2837         }
2838
2839         .mbar.commit add command -label [mc Rescan] \
2840                 -command ui_do_rescan \
2841                 -accelerator F5
2842         lappend disable_on_lock \
2843                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2844
2845         .mbar.commit add command -label [mc "Stage To Commit"] \
2846                 -command do_add_selection \
2847                 -accelerator $M1T-T
2848         lappend disable_on_lock \
2849                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2850
2851         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2852                 -command do_add_all \
2853                 -accelerator $M1T-I
2854         lappend disable_on_lock \
2855                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2856
2857         .mbar.commit add command -label [mc "Unstage From Commit"] \
2858                 -command do_unstage_selection \
2859                 -accelerator $M1T-U
2860         lappend disable_on_lock \
2861                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2862
2863         .mbar.commit add command -label [mc "Revert Changes"] \
2864                 -command do_revert_selection \
2865                 -accelerator $M1T-J
2866         lappend disable_on_lock \
2867                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2868
2869         .mbar.commit add separator
2870
2871         .mbar.commit add command -label [mc "Show Less Context"] \
2872                 -command show_less_context \
2873                 -accelerator $M1T-\-
2874
2875         .mbar.commit add command -label [mc "Show More Context"] \
2876                 -command show_more_context \
2877                 -accelerator $M1T-=
2878
2879         .mbar.commit add separator
2880
2881         if {![is_enabled nocommitmsg]} {
2882                 .mbar.commit add command -label [mc "Sign Off"] \
2883                         -command do_signoff \
2884                         -accelerator $M1T-S
2885         }
2886
2887         .mbar.commit add command -label [commit_btn_caption] \
2888                 -command do_commit \
2889                 -accelerator $M1T-Return
2890         lappend disable_on_lock \
2891                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2892 }
2893
2894 # -- Merge Menu
2895 #
2896 if {[is_enabled branch]} {
2897         menu .mbar.merge
2898         .mbar.merge add command -label [mc "Local Merge..."] \
2899                 -command merge::dialog \
2900                 -accelerator $M1T-M
2901         lappend disable_on_lock \
2902                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2903         .mbar.merge add command -label [mc "Abort Merge..."] \
2904                 -command merge::reset_hard
2905         lappend disable_on_lock \
2906                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2907 }
2908
2909 # -- Transport Menu
2910 #
2911 if {[is_enabled transport]} {
2912         menu .mbar.remote
2913
2914         .mbar.remote add command \
2915                 -label [mc "Add..."] \
2916                 -command remote_add::dialog \
2917                 -accelerator $M1T-A
2918         .mbar.remote add command \
2919                 -label [mc "Push..."] \
2920                 -command do_push_anywhere \
2921                 -accelerator $M1T-P
2922         .mbar.remote add command \
2923                 -label [mc "Delete Branch..."] \
2924                 -command remote_branch_delete::dialog
2925 }
2926
2927 if {[is_MacOSX]} {
2928         proc ::tk::mac::ShowPreferences {} {do_options}
2929 } else {
2930         # -- Edit Menu
2931         #
2932         .mbar.edit add separator
2933         .mbar.edit add command -label [mc "Options..."] \
2934                 -command do_options
2935 }
2936
2937 # -- Tools Menu
2938 #
2939 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2940         set tools_menubar .mbar.tools
2941         menu $tools_menubar
2942         $tools_menubar add separator
2943         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2944         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2945         set tools_tailcnt 3
2946         if {[array names repo_config guitool.*.cmd] ne {}} {
2947                 tools_populate_all
2948         }
2949 }
2950
2951 # -- Help Menu
2952 #
2953 .mbar add cascade -label [mc Help] -menu .mbar.help
2954 menu .mbar.help
2955
2956 if {[is_MacOSX]} {
2957         .mbar.apple add command -label [mc "About %s" [appname]] \
2958                 -command do_about
2959         .mbar.apple add separator
2960 } else {
2961         .mbar.help add command -label [mc "About %s" [appname]] \
2962                 -command do_about
2963 }
2964 . configure -menu .mbar
2965
2966 set doc_path [githtmldir]
2967 if {$doc_path ne {}} {
2968         set doc_path [file join $doc_path index.html]
2969
2970         if {[is_Cygwin]} {
2971                 set doc_path [exec cygpath --mixed $doc_path]
2972         }
2973 }
2974
2975 if {[file isfile $doc_path]} {
2976         set doc_url "file:$doc_path"
2977 } else {
2978         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2979 }
2980
2981 proc start_browser {url} {
2982         git "web--browse" $url
2983 }
2984
2985 .mbar.help add command -label [mc "Online Documentation"] \
2986         -command [list start_browser $doc_url]
2987
2988 .mbar.help add command -label [mc "Show SSH Key"] \
2989         -command do_ssh_key
2990
2991 unset doc_path doc_url
2992
2993 # -- Standard bindings
2994 #
2995 wm protocol . WM_DELETE_WINDOW do_quit
2996 bind all <$M1B-Key-q> do_quit
2997 bind all <$M1B-Key-Q> do_quit
2998 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2999 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3000
3001 set subcommand_args {}
3002 proc usage {} {
3003         set s "usage: $::argv0 $::subcommand $::subcommand_args"
3004         if {[tk windowingsystem] eq "win32"} {
3005                 wm withdraw .
3006                 tk_messageBox -icon info -message $s \
3007                         -title [mc "Usage"]
3008         } else {
3009                 puts stderr $s
3010         }
3011         exit 1
3012 }
3013
3014 proc normalize_relpath {path} {
3015         set elements {}
3016         foreach item [file split $path] {
3017                 if {$item eq {.}} continue
3018                 if {$item eq {..} && [llength $elements] > 0
3019                     && [lindex $elements end] ne {..}} {
3020                         set elements [lrange $elements 0 end-1]
3021                         continue
3022                 }
3023                 lappend elements $item
3024         }
3025         return [eval file join $elements]
3026 }
3027
3028 # -- Not a normal commit type invocation?  Do that instead!
3029 #
3030 switch -- $subcommand {
3031 browser -
3032 blame {
3033         if {$subcommand eq "blame"} {
3034                 set subcommand_args {[--line=<num>] rev? path}
3035         } else {
3036                 set subcommand_args {rev? path}
3037         }
3038         if {$argv eq {}} usage
3039         set head {}
3040         set path {}
3041         set jump_spec {}
3042         set is_path 0
3043         foreach a $argv {
3044                 set p [file join $_prefix $a]
3045
3046                 if {$is_path || [file exists $p]} {
3047                         if {$path ne {}} usage
3048                         set path [normalize_relpath $p]
3049                         break
3050                 } elseif {$a eq {--}} {
3051                         if {$path ne {}} {
3052                                 if {$head ne {}} usage
3053                                 set head $path
3054                                 set path {}
3055                         }
3056                         set is_path 1
3057                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3058                         if {$jump_spec ne {} || $head ne {}} usage
3059                         set jump_spec [list $lnum]
3060                 } elseif {$head eq {}} {
3061                         if {$head ne {}} usage
3062                         set head $a
3063                         set is_path 1
3064                 } else {
3065                         usage
3066                 }
3067         }
3068         unset is_path
3069
3070         if {$head ne {} && $path eq {}} {
3071                 if {[string index $head 0] eq {/}} {
3072                         set path [normalize_relpath $head]
3073                         set head {}
3074                 } else {
3075                         set path [normalize_relpath $_prefix$head]
3076                         set head {}
3077                 }
3078         }
3079
3080         if {$head eq {}} {
3081                 load_current_branch
3082         } else {
3083                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3084                         if {[catch {
3085                                         set head [git rev-parse --verify $head]
3086                                 } err]} {
3087                                 if {[tk windowingsystem] eq "win32"} {
3088                                         tk_messageBox -icon error -title [mc Error] -message $err
3089                                 } else {
3090                                         puts stderr $err
3091                                 }
3092                                 exit 1
3093                         }
3094                 }
3095                 set current_branch $head
3096         }
3097
3098         wm deiconify .
3099         switch -- $subcommand {
3100         browser {
3101                 if {$jump_spec ne {}} usage
3102                 if {$head eq {}} {
3103                         if {$path ne {} && [file isdirectory $path]} {
3104                                 set head $current_branch
3105                         } else {
3106                                 set head $path
3107                                 set path {}
3108                         }
3109                 }
3110                 browser::new $head $path
3111         }
3112         blame   {
3113                 if {$head eq {} && ![file exists $path]} {
3114                         catch {wm withdraw .}
3115                         tk_messageBox \
3116                                 -icon error \
3117                                 -type ok \
3118                                 -title [mc "git-gui: fatal error"] \
3119                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3120                         exit 1
3121                 }
3122                 blame::new $head $path $jump_spec
3123         }
3124         }
3125         return
3126 }
3127 citool -
3128 gui {
3129         if {[llength $argv] != 0} {
3130                 usage
3131         }
3132         # fall through to setup UI for commits
3133 }
3134 default {
3135         set err "usage: $argv0 \[{blame|browser|citool}\]"
3136         if {[tk windowingsystem] eq "win32"} {
3137                 wm withdraw .
3138                 tk_messageBox -icon error -message $err \
3139                         -title [mc "Usage"]
3140         } else {
3141                 puts stderr $err
3142         }
3143         exit 1
3144 }
3145 }
3146
3147 # -- Branch Control
3148 #
3149 ${NS}::frame .branch
3150 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3151 ${NS}::label .branch.l1 \
3152         -text [mc "Current Branch:"] \
3153         -anchor w \
3154         -justify left
3155 ${NS}::label .branch.cb \
3156         -textvariable current_branch \
3157         -anchor w \
3158         -justify left
3159 pack .branch.l1 -side left
3160 pack .branch.cb -side left -fill x
3161 pack .branch -side top -fill x
3162
3163 # -- Main Window Layout
3164 #
3165 ${NS}::panedwindow .vpane -orient horizontal
3166 ${NS}::panedwindow .vpane.files -orient vertical
3167 if {$use_ttk} {
3168         .vpane add .vpane.files
3169 } else {
3170         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3171 }
3172 pack .vpane -anchor n -side top -fill both -expand 1
3173
3174 # -- Index File List
3175 #
3176 ${NS}::frame .vpane.files.index -height 100 -width 200
3177 tlabel .vpane.files.index.title \
3178         -text [mc "Staged Changes (Will Commit)"] \
3179         -background lightgreen -foreground black
3180 text $ui_index -background white -foreground black \
3181         -borderwidth 0 \
3182         -width 20 -height 10 \
3183         -wrap none \
3184         -cursor $cursor_ptr \
3185         -xscrollcommand {.vpane.files.index.sx set} \
3186         -yscrollcommand {.vpane.files.index.sy set} \
3187         -state disabled
3188 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3189 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3190 pack .vpane.files.index.title -side top -fill x
3191 pack .vpane.files.index.sx -side bottom -fill x
3192 pack .vpane.files.index.sy -side right -fill y
3193 pack $ui_index -side left -fill both -expand 1
3194
3195 # -- Working Directory File List
3196 #
3197 ${NS}::frame .vpane.files.workdir -height 100 -width 200
3198 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3199         -background lightsalmon -foreground black
3200 text $ui_workdir -background white -foreground black \
3201         -borderwidth 0 \
3202         -width 20 -height 10 \
3203         -wrap none \
3204         -cursor $cursor_ptr \
3205         -xscrollcommand {.vpane.files.workdir.sx set} \
3206         -yscrollcommand {.vpane.files.workdir.sy set} \
3207         -state disabled
3208 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3209 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3210 pack .vpane.files.workdir.title -side top -fill x
3211 pack .vpane.files.workdir.sx -side bottom -fill x
3212 pack .vpane.files.workdir.sy -side right -fill y
3213 pack $ui_workdir -side left -fill both -expand 1
3214
3215 .vpane.files add .vpane.files.workdir
3216 .vpane.files add .vpane.files.index
3217 if {!$use_ttk} {
3218         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3219         .vpane.files paneconfigure .vpane.files.index -sticky news
3220 }
3221
3222 foreach i [list $ui_index $ui_workdir] {
3223         rmsel_tag $i
3224         $i tag conf in_diff -background [$i tag cget in_sel -background]
3225 }
3226 unset i
3227
3228 # -- Diff and Commit Area
3229 #
3230 if {$have_tk85} {
3231         ${NS}::panedwindow .vpane.lower -orient vertical
3232         ${NS}::frame .vpane.lower.commarea
3233         ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3234         .vpane.lower add .vpane.lower.diff
3235         .vpane.lower add .vpane.lower.commarea
3236         .vpane add .vpane.lower
3237         if {$use_ttk} {
3238                 .vpane.lower pane .vpane.lower.diff -weight 1
3239                 .vpane.lower pane .vpane.lower.commarea -weight 0
3240         } else {
3241                 .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3242                 .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3243         }
3244 } else {
3245         frame .vpane.lower -height 300 -width 400
3246         frame .vpane.lower.commarea
3247         frame .vpane.lower.diff -relief sunken -borderwidth 1
3248         pack .vpane.lower.diff -fill both -expand 1
3249         pack .vpane.lower.commarea -side bottom -fill x
3250         .vpane add .vpane.lower
3251         .vpane paneconfigure .vpane.lower -sticky nsew
3252 }
3253
3254 # -- Commit Area Buttons
3255 #
3256 ${NS}::frame .vpane.lower.commarea.buttons
3257 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3258         -anchor w \
3259         -justify left
3260 pack .vpane.lower.commarea.buttons.l -side top -fill x
3261 pack .vpane.lower.commarea.buttons -side left -fill y
3262
3263 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3264         -command ui_do_rescan
3265 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3266 lappend disable_on_lock \
3267         {.vpane.lower.commarea.buttons.rescan conf -state}
3268
3269 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3270         -command do_add_all
3271 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3272 lappend disable_on_lock \
3273         {.vpane.lower.commarea.buttons.incall conf -state}
3274
3275 if {![is_enabled nocommitmsg]} {
3276         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3277                 -command do_signoff
3278         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3279 }
3280
3281 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3282         -command do_commit
3283 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3284 lappend disable_on_lock \
3285         {.vpane.lower.commarea.buttons.commit conf -state}
3286
3287 if {![is_enabled nocommit]} {
3288         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3289                 -command do_push_anywhere
3290         pack .vpane.lower.commarea.buttons.push -side top -fill x
3291 }
3292
3293 # -- Commit Message Buffer
3294 #
3295 ${NS}::frame .vpane.lower.commarea.buffer
3296 ${NS}::frame .vpane.lower.commarea.buffer.header
3297 set ui_comm .vpane.lower.commarea.buffer.t
3298 set ui_coml .vpane.lower.commarea.buffer.header.l
3299
3300 if {![is_enabled nocommit]} {
3301         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3302                 -text [mc "New Commit"] \
3303                 -command do_select_commit_type \
3304                 -variable selected_commit_type \
3305                 -value new
3306         lappend disable_on_lock \
3307                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3308         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3309                 -text [mc "Amend Last Commit"] \
3310                 -command do_select_commit_type \
3311                 -variable selected_commit_type \
3312                 -value amend
3313         lappend disable_on_lock \
3314                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3315 }
3316
3317 ${NS}::label $ui_coml \
3318         -anchor w \
3319         -justify left
3320 proc trace_commit_type {varname args} {
3321         global ui_coml commit_type
3322         switch -glob -- $commit_type {
3323         initial       {set txt [mc "Initial Commit Message:"]}
3324         amend         {set txt [mc "Amended Commit Message:"]}
3325         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3326         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3327         merge         {set txt [mc "Merge Commit Message:"]}
3328         *             {set txt [mc "Commit Message:"]}
3329         }
3330         $ui_coml conf -text $txt
3331 }
3332 trace add variable commit_type write trace_commit_type
3333 pack $ui_coml -side left -fill x
3334
3335 if {![is_enabled nocommit]} {
3336         pack .vpane.lower.commarea.buffer.header.amend -side right
3337         pack .vpane.lower.commarea.buffer.header.new -side right
3338 }
3339
3340 text $ui_comm -background white -foreground black \
3341         -borderwidth 1 \
3342         -undo true \
3343         -maxundo 20 \
3344         -autoseparators true \
3345         -relief sunken \
3346         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3347         -font font_diff \
3348         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3349 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3350         -command [list $ui_comm yview]
3351 pack .vpane.lower.commarea.buffer.header -side top -fill x
3352 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3353 pack $ui_comm -side left -fill y
3354 pack .vpane.lower.commarea.buffer -side left -fill y
3355
3356 # -- Commit Message Buffer Context Menu
3357 #
3358 set ctxm .vpane.lower.commarea.buffer.ctxm
3359 menu $ctxm -tearoff 0
3360 $ctxm add command \
3361         -label [mc Cut] \
3362         -command {tk_textCut $ui_comm}
3363 $ctxm add command \
3364         -label [mc Copy] \
3365         -command {tk_textCopy $ui_comm}
3366 $ctxm add command \
3367         -label [mc Paste] \
3368         -command {tk_textPaste $ui_comm}
3369 $ctxm add command \
3370         -label [mc Delete] \
3371         -command {catch {$ui_comm delete sel.first sel.last}}
3372 $ctxm add separator
3373 $ctxm add command \
3374         -label [mc "Select All"] \
3375         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3376 $ctxm add command \
3377         -label [mc "Copy All"] \
3378         -command {
3379                 $ui_comm tag add sel 0.0 end
3380                 tk_textCopy $ui_comm
3381                 $ui_comm tag remove sel 0.0 end
3382         }
3383 $ctxm add separator
3384 $ctxm add command \
3385         -label [mc "Sign Off"] \
3386         -command do_signoff
3387 set ui_comm_ctxm $ctxm
3388
3389 # -- Diff Header
3390 #
3391 proc trace_current_diff_path {varname args} {
3392         global current_diff_path diff_actions file_states
3393         if {$current_diff_path eq {}} {
3394                 set s {}
3395                 set f {}
3396                 set p {}
3397                 set o disabled
3398         } else {
3399                 set p $current_diff_path
3400                 set s [mapdesc [lindex $file_states($p) 0] $p]
3401                 set f [mc "File:"]
3402                 set p [escape_path $p]
3403                 set o normal
3404         }
3405
3406         .vpane.lower.diff.header.status configure -text $s
3407         .vpane.lower.diff.header.file configure -text $f
3408         .vpane.lower.diff.header.path configure -text $p
3409         foreach w $diff_actions {
3410                 uplevel #0 $w $o
3411         }
3412 }
3413 trace add variable current_diff_path write trace_current_diff_path
3414
3415 gold_frame .vpane.lower.diff.header
3416 tlabel .vpane.lower.diff.header.status \
3417         -background gold \
3418         -foreground black \
3419         -width $max_status_desc \
3420         -anchor w \
3421         -justify left
3422 tlabel .vpane.lower.diff.header.file \
3423         -background gold \
3424         -foreground black \
3425         -anchor w \
3426         -justify left
3427 tlabel .vpane.lower.diff.header.path \
3428         -background gold \
3429         -foreground black \
3430         -anchor w \
3431         -justify left
3432 pack .vpane.lower.diff.header.status -side left
3433 pack .vpane.lower.diff.header.file -side left
3434 pack .vpane.lower.diff.header.path -fill x
3435 set ctxm .vpane.lower.diff.header.ctxm
3436 menu $ctxm -tearoff 0
3437 $ctxm add command \
3438         -label [mc Copy] \
3439         -command {
3440                 clipboard clear
3441                 clipboard append \
3442                         -format STRING \
3443                         -type STRING \
3444                         -- $current_diff_path
3445         }
3446 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3447 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3448
3449 # -- Diff Body
3450 #
3451 ${NS}::frame .vpane.lower.diff.body
3452 set ui_diff .vpane.lower.diff.body.t
3453 text $ui_diff -background white -foreground black \
3454         -borderwidth 0 \
3455         -width 80 -height 5 -wrap none \
3456         -font font_diff \
3457         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3458         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3459         -state disabled
3460 catch {$ui_diff configure -tabstyle wordprocessor}
3461 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3462         -command [list $ui_diff xview]
3463 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3464         -command [list $ui_diff yview]
3465 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3466 pack .vpane.lower.diff.body.sby -side right -fill y
3467 pack $ui_diff -side left -fill both -expand 1
3468 pack .vpane.lower.diff.header -side top -fill x
3469 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3470
3471 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3472         $ui_diff tag configure clr4$n -background $c
3473         $ui_diff tag configure clri4$n -foreground $c
3474         $ui_diff tag configure clr3$n -foreground $c
3475         $ui_diff tag configure clri3$n -background $c
3476 }
3477 $ui_diff tag configure clr1 -font font_diffbold
3478 $ui_diff tag configure clr4 -underline 1
3479
3480 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3481
3482 $ui_diff tag conf d_cr -elide true
3483 $ui_diff tag conf d_@ -font font_diffbold
3484 $ui_diff tag conf d_+ -foreground {#00a000}
3485 $ui_diff tag conf d_- -foreground red
3486
3487 $ui_diff tag conf d_++ -foreground {#00a000}
3488 $ui_diff tag conf d_-- -foreground red
3489 $ui_diff tag conf d_+s \
3490         -foreground {#00a000} \
3491         -background {#e2effa}
3492 $ui_diff tag conf d_-s \
3493         -foreground red \
3494         -background {#e2effa}
3495 $ui_diff tag conf d_s+ \
3496         -foreground {#00a000} \
3497         -background ivory1
3498 $ui_diff tag conf d_s- \
3499         -foreground red \
3500         -background ivory1
3501
3502 $ui_diff tag conf d< \
3503         -foreground orange \
3504         -font font_diffbold
3505 $ui_diff tag conf d= \
3506         -foreground orange \
3507         -font font_diffbold
3508 $ui_diff tag conf d> \
3509         -foreground orange \
3510         -font font_diffbold
3511
3512 $ui_diff tag raise sel
3513
3514 # -- Diff Body Context Menu
3515 #
3516
3517 proc create_common_diff_popup {ctxm} {
3518         $ctxm add command \
3519                 -label [mc Refresh] \
3520                 -command reshow_diff
3521         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3522         $ctxm add command \
3523                 -label [mc Copy] \
3524                 -command {tk_textCopy $ui_diff}
3525         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3526         $ctxm add command \
3527                 -label [mc "Select All"] \
3528                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3529         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3530         $ctxm add command \
3531                 -label [mc "Copy All"] \
3532                 -command {
3533                         $ui_diff tag add sel 0.0 end
3534                         tk_textCopy $ui_diff
3535                         $ui_diff tag remove sel 0.0 end
3536                 }
3537         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3538         $ctxm add separator
3539         $ctxm add command \
3540                 -label [mc "Decrease Font Size"] \
3541                 -command {incr_font_size font_diff -1}
3542         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3543         $ctxm add command \
3544                 -label [mc "Increase Font Size"] \
3545                 -command {incr_font_size font_diff 1}
3546         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3547         $ctxm add separator
3548         set emenu $ctxm.enc
3549         menu $emenu
3550         build_encoding_menu $emenu [list force_diff_encoding]
3551         $ctxm add cascade \
3552                 -label [mc "Encoding"] \
3553                 -menu $emenu
3554         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3555         $ctxm add separator
3556         $ctxm add command -label [mc "Options..."] \
3557                 -command do_options
3558 }
3559
3560 set ctxm .vpane.lower.diff.body.ctxm
3561 menu $ctxm -tearoff 0
3562 $ctxm add command \
3563         -label [mc "Apply/Reverse Hunk"] \
3564         -command {apply_hunk $cursorX $cursorY}
3565 set ui_diff_applyhunk [$ctxm index last]
3566 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3567 $ctxm add command \
3568         -label [mc "Apply/Reverse Line"] \
3569         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3570 set ui_diff_applyline [$ctxm index last]
3571 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3572 $ctxm add separator
3573 $ctxm add command \
3574         -label [mc "Show Less Context"] \
3575         -command show_less_context
3576 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3577 $ctxm add command \
3578         -label [mc "Show More Context"] \
3579         -command show_more_context
3580 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3581 $ctxm add separator
3582 create_common_diff_popup $ctxm
3583
3584 set ctxmmg .vpane.lower.diff.body.ctxmmg
3585 menu $ctxmmg -tearoff 0
3586 $ctxmmg add command \
3587         -label [mc "Run Merge Tool"] \
3588         -command {merge_resolve_tool}
3589 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3590 $ctxmmg add separator
3591 $ctxmmg add command \
3592         -label [mc "Use Remote Version"] \
3593         -command {merge_resolve_one 3}
3594 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3595 $ctxmmg add command \
3596         -label [mc "Use Local Version"] \
3597         -command {merge_resolve_one 2}
3598 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3599 $ctxmmg add command \
3600         -label [mc "Revert To Base"] \
3601         -command {merge_resolve_one 1}
3602 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3603 $ctxmmg add separator
3604 $ctxmmg add command \
3605         -label [mc "Show Less Context"] \
3606         -command show_less_context
3607 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3608 $ctxmmg add command \
3609         -label [mc "Show More Context"] \
3610         -command show_more_context
3611 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3612 $ctxmmg add separator
3613 create_common_diff_popup $ctxmmg
3614
3615 set ctxmsm .vpane.lower.diff.body.ctxmsm
3616 menu $ctxmsm -tearoff 0
3617 $ctxmsm add command \
3618         -label [mc "Visualize These Changes In The Submodule"] \
3619         -command {do_gitk -- true}
3620 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3621 $ctxmsm add command \
3622         -label [mc "Visualize Current Branch History In The Submodule"] \
3623         -command {do_gitk {} true}
3624 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3625 $ctxmsm add command \
3626         -label [mc "Visualize All Branch History In The Submodule"] \
3627         -command {do_gitk --all true}
3628 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3629 $ctxmsm add separator
3630 $ctxmsm add command \
3631         -label [mc "Start git gui In The Submodule"] \
3632         -command {do_git_gui}
3633 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3634 $ctxmsm add separator
3635 create_common_diff_popup $ctxmsm
3636
3637 proc has_textconv {path} {
3638         if {[is_config_false gui.textconv]} {
3639                 return 0
3640         }
3641         set filter [gitattr $path diff set]
3642         set textconv [get_config [join [list diff $filter textconv] .]]
3643         if {$filter ne {set} && $textconv ne {}} {
3644                 return 1
3645         } else {
3646                 return 0
3647         }
3648 }
3649
3650 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3651         global current_diff_path file_states
3652         set ::cursorX $x
3653         set ::cursorY $y
3654         if {[info exists file_states($current_diff_path)]} {
3655                 set state [lindex $file_states($current_diff_path) 0]
3656         } else {
3657                 set state {__}
3658         }
3659         if {[string first {U} $state] >= 0} {
3660                 tk_popup $ctxmmg $X $Y
3661         } elseif {$::is_submodule_diff} {
3662                 tk_popup $ctxmsm $X $Y
3663         } else {
3664                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3665                 if {$::ui_index eq $::current_diff_side} {
3666                         set l [mc "Unstage Hunk From Commit"]
3667                         if {$has_range} {
3668                                 set t [mc "Unstage Lines From Commit"]
3669                         } else {
3670                                 set t [mc "Unstage Line From Commit"]
3671                         }
3672                 } else {
3673                         set l [mc "Stage Hunk For Commit"]
3674                         if {$has_range} {
3675                                 set t [mc "Stage Lines For Commit"]
3676                         } else {
3677                                 set t [mc "Stage Line For Commit"]
3678                         }
3679                 }
3680                 if {$::is_3way_diff
3681                         || $current_diff_path eq {}
3682                         || {__} eq $state
3683                         || {_O} eq $state
3684                         || [string match {?T} $state]
3685                         || [string match {T?} $state]
3686                         || [has_textconv $current_diff_path]} {
3687                         set s disabled
3688                 } else {
3689                         set s normal
3690                 }
3691                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3692                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3693                 tk_popup $ctxm $X $Y
3694         }
3695 }
3696 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3697
3698 # -- Status Bar
3699 #
3700 set main_status [::status_bar::new .status]
3701 pack .status -anchor w -side bottom -fill x
3702 $main_status show [mc "Initializing..."]
3703
3704 # -- Load geometry
3705 #
3706 proc on_ttk_pane_mapped {w pane pos} {
3707         bind $w <Map> {}
3708         after 0 [list after idle [list $w sashpos $pane $pos]]
3709 }
3710 proc on_tk_pane_mapped {w pane x y} {
3711         bind $w <Map> {}
3712         after 0 [list after idle [list $w sash place $pane $x $y]]
3713 }
3714 proc on_application_mapped {} {
3715         global repo_config use_ttk
3716         bind . <Map> {}
3717         set gm $repo_config(gui.geometry)
3718         if {$use_ttk} {
3719                 bind .vpane <Map> \
3720                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3721                 bind .vpane.files <Map> \
3722                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3723         } else {
3724                 bind .vpane <Map> \
3725                     [list on_tk_pane_mapped %W 0 \
3726                          [lindex $gm 1] \
3727                          [lindex [.vpane sash coord 0] 1]]
3728                 bind .vpane.files <Map> \
3729                     [list on_tk_pane_mapped %W 0 \
3730                          [lindex [.vpane.files sash coord 0] 0] \
3731                          [lindex $gm 2]]
3732         }
3733         wm geometry . [lindex $gm 0]
3734 }
3735 if {[info exists repo_config(gui.geometry)]} {
3736         bind . <Map> [list on_application_mapped]
3737         wm geometry . [lindex $repo_config(gui.geometry) 0]
3738 }
3739
3740 # -- Load window state
3741 #
3742 if {[info exists repo_config(gui.wmstate)]} {
3743         catch {wm state . $repo_config(gui.wmstate)}
3744 }
3745
3746 # -- Key Bindings
3747 #
3748 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3749 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3750 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3751 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3752 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3753 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3754 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3755 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3756 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3757 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3758 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3759 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3760 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3761 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3762 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3763 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3764 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3765 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3766 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3767 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3768 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3769 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3770
3771 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3772 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3773 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3774 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3775 bind $ui_diff <$M1B-Key-v> {break}
3776 bind $ui_diff <$M1B-Key-V> {break}
3777 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3778 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3779 bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3780 bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3781 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3782 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3783 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3784 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3785 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3786 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3787 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3788 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3789 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3790 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3791 bind $ui_diff <Button-1>   {focus %W}
3792
3793 if {[is_enabled branch]} {
3794         bind . <$M1B-Key-n> branch_create::dialog
3795         bind . <$M1B-Key-N> branch_create::dialog
3796         bind . <$M1B-Key-o> branch_checkout::dialog
3797         bind . <$M1B-Key-O> branch_checkout::dialog
3798         bind . <$M1B-Key-m> merge::dialog
3799         bind . <$M1B-Key-M> merge::dialog
3800 }
3801 if {[is_enabled transport]} {
3802         bind . <$M1B-Key-p> do_push_anywhere
3803         bind . <$M1B-Key-P> do_push_anywhere
3804 }
3805
3806 bind .   <Key-F5>     ui_do_rescan
3807 bind .   <$M1B-Key-r> ui_do_rescan
3808 bind .   <$M1B-Key-R> ui_do_rescan
3809 bind .   <$M1B-Key-s> do_signoff
3810 bind .   <$M1B-Key-S> do_signoff
3811 bind .   <$M1B-Key-t> do_add_selection
3812 bind .   <$M1B-Key-T> do_add_selection
3813 bind .   <$M1B-Key-u> do_unstage_selection
3814 bind .   <$M1B-Key-U> do_unstage_selection
3815 bind .   <$M1B-Key-j> do_revert_selection
3816 bind .   <$M1B-Key-J> do_revert_selection
3817 bind .   <$M1B-Key-i> do_add_all
3818 bind .   <$M1B-Key-I> do_add_all
3819 bind .   <$M1B-Key-minus> {show_less_context;break}
3820 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3821 bind .   <$M1B-Key-equal> {show_more_context;break}
3822 bind .   <$M1B-Key-plus> {show_more_context;break}
3823 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3824 bind .   <$M1B-Key-Return> do_commit
3825 foreach i [list $ui_index $ui_workdir] {
3826         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3827         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3828         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3829 }
3830 unset i
3831
3832 set file_lists($ui_index) [list]
3833 set file_lists($ui_workdir) [list]
3834
3835 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3836 focus -force $ui_comm
3837
3838 # -- Warn the user about environmental problems.  Cygwin's Tcl
3839 #    does *not* pass its env array onto any processes it spawns.
3840 #    This means that git processes get none of our environment.
3841 #
3842 if {[is_Cygwin]} {
3843         set ignored_env 0
3844         set suggest_user {}
3845         set msg [mc "Possible environment issues exist.
3846
3847 The following environment variables are probably
3848 going to be ignored by any Git subprocess run
3849 by %s:
3850
3851 " [appname]]
3852         foreach name [array names env] {
3853                 switch -regexp -- $name {
3854                 {^GIT_INDEX_FILE$} -
3855                 {^GIT_OBJECT_DIRECTORY$} -
3856                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3857                 {^GIT_DIFF_OPTS$} -
3858                 {^GIT_EXTERNAL_DIFF$} -
3859                 {^GIT_PAGER$} -
3860                 {^GIT_TRACE$} -
3861                 {^GIT_CONFIG$} -
3862                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3863                         append msg " - $name\n"
3864                         incr ignored_env
3865                 }
3866                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3867                         append msg " - $name\n"
3868                         incr ignored_env
3869                         set suggest_user $name
3870                 }
3871                 }
3872         }
3873         if {$ignored_env > 0} {
3874                 append msg [mc "
3875 This is due to a known issue with the
3876 Tcl binary distributed by Cygwin."]
3877
3878                 if {$suggest_user ne {}} {
3879                         append msg [mc "
3880
3881 A good replacement for %s
3882 is placing values for the user.name and
3883 user.email settings into your personal
3884 ~/.gitconfig file.
3885 " $suggest_user]
3886                 }
3887                 warn_popup $msg
3888         }
3889         unset ignored_env msg suggest_user name
3890 }
3891
3892 # -- Only initialize complex UI if we are going to stay running.
3893 #
3894 if {[is_enabled transport]} {
3895         load_all_remotes
3896
3897         set n [.mbar.remote index end]
3898         populate_remotes_menu
3899         set n [expr {[.mbar.remote index end] - $n}]
3900         if {$n > 0} {
3901                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3902                 .mbar.remote insert $n separator
3903         }
3904         unset n
3905 }
3906
3907 if {[winfo exists $ui_comm]} {
3908         set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
3909
3910         # -- If both our backup and message files exist use the
3911         #    newer of the two files to initialize the buffer.
3912         #
3913         if {$GITGUI_BCK_exists} {
3914                 set m [gitdir GITGUI_MSG]
3915                 if {[file isfile $m]} {
3916                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3917                                 catch {file delete [gitdir GITGUI_MSG]}
3918                         } else {
3919                                 $ui_comm delete 0.0 end
3920                                 $ui_comm edit reset
3921                                 $ui_comm edit modified false
3922                                 catch {file delete [gitdir GITGUI_BCK]}
3923                                 set GITGUI_BCK_exists 0
3924                         }
3925                 }
3926                 unset m
3927         }
3928
3929         proc backup_commit_buffer {} {
3930                 global ui_comm GITGUI_BCK_exists
3931
3932                 set m [$ui_comm edit modified]
3933                 if {$m || $GITGUI_BCK_exists} {
3934                         set msg [string trim [$ui_comm get 0.0 end]]
3935                         regsub -all -line {[ \r\t]+$} $msg {} msg
3936
3937                         if {$msg eq {}} {
3938                                 if {$GITGUI_BCK_exists} {
3939                                         catch {file delete [gitdir GITGUI_BCK]}
3940                                         set GITGUI_BCK_exists 0
3941                                 }
3942                         } elseif {$m} {
3943                                 catch {
3944                                         set fd [open [gitdir GITGUI_BCK] w]
3945                                         fconfigure $fd -encoding utf-8
3946                                         puts -nonewline $fd $msg
3947                                         close $fd
3948                                         set GITGUI_BCK_exists 1
3949                                 }
3950                         }
3951
3952                         $ui_comm edit modified false
3953                 }
3954
3955                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3956         }
3957
3958         backup_commit_buffer
3959
3960         # -- If the user has aspell available we can drive it
3961         #    in pipe mode to spellcheck the commit message.
3962         #
3963         set spell_cmd [list |]
3964         set spell_dict [get_config gui.spellingdictionary]
3965         lappend spell_cmd aspell
3966         if {$spell_dict ne {}} {
3967                 lappend spell_cmd --master=$spell_dict
3968         }
3969         lappend spell_cmd --mode=none
3970         lappend spell_cmd --encoding=utf-8
3971         lappend spell_cmd pipe
3972         if {$spell_dict eq {none}
3973          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3974                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3975         } else {
3976                 set ui_comm_spell [spellcheck::init \
3977                         $spell_fd \
3978                         $ui_comm \
3979                         $ui_comm_ctxm \
3980                 ]
3981         }
3982         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3983 }
3984
3985 lock_index begin-read
3986 if {![winfo ismapped .]} {
3987         wm deiconify .
3988 }
3989 after 1 {
3990         if {[is_enabled initialamend]} {
3991                 force_amend
3992         } else {
3993                 do_rescan
3994         }
3995
3996         if {[is_enabled nocommitmsg]} {
3997                 $ui_comm configure -state disabled -background gray
3998         }
3999 }
4000 if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
4001         after 1000 hint_gc
4002 }
4003 if {[is_enabled retcode]} {
4004         bind . <Destroy> {+terminate_me %W}
4005 }
4006 if {$picked && [is_config_true gui.autoexplore]} {
4007         do_explore
4008 }
4009
4010 # Local variables:
4011 # mode: tcl
4012 # indent-tabs-mode: t
4013 # tab-width: 4
4014 # End: